TStrings.SaveToFileが最後の空の行を作成しないようにするにはどうすればよいですか？

次の.\input.txtようなファイルがあります。

aaa
bbb
ccc

を使用TStrings.LoadFromFileしてそれを読み取り、それを（変更を適用せずに）を使用して書き戻すTStrings.SaveToFileと、出力ファイルの最後に空の行が作成されます。

var
  Lines : TStrings;
begin
  Lines := TStringList.Create;
  try
    Lines.LoadFromFile('.\input.txt');

    //...

    Lines.SaveToFile('.\output.txt');
  finally
    Lines.Free;
  end;
end;

同じ動作がTStrings.Text、最後に空行を含む文字列を返すプロパティを使用して観察できます。

Delphi 10.1以降には、TrailingLineBreakこの動作を制御するプロパティがあります。

TrailingLineBreakプロパティがTrue（デフォルト値）の場合、Textプロパティには最後の行の後に改行が含まれます。Falseの場合、テキスト値には最後の行の後に改行が含まれません。これは、soTrailingLineBreakオプションでも制御できます。

Delphi 10.1（ベルリン）以降の場合、最良のソリューションはUweの回答に記載されています。

古いDelphiバージョンの場合、私TStringListはTStrings.GetTextStr仮想関数の子クラスを作成してオーバーライドすることで解決策を見つけましたが、より良い解決策があるかどうか、または誰かが私の解決策で何か問題を見つけたかどうかを知りたいと思います

インターフェース：

  uses
    Classes;

  type
    TMyStringList = class(TStringList)
    private
      FIncludeLastLineBreakInText : Boolean;
    protected
      function GetTextStr: string; override;
    public
      constructor Create(AIncludeLastLineBreakInText : Boolean = False); overload;
      property IncludeLastLineBreakInText : Boolean read FIncludeLastLineBreakInText write FIncludeLastLineBreakInText;
    end;

実装：

uses
  StrUtils;      

constructor TMyStringList.Create(AIncludeLastLineBreakInText : Boolean = False);
begin
  inherited Create;

  FIncludeLastLineBreakInText := AIncludeLastLineBreakInText;
end;

function TMyStringList.GetTextStr: string;
begin
  Result := inherited;

  if(not IncludeLastLineBreakInText) and EndsStr(LineBreak, Result)
  then SetLength(Result, Length(Result) - Length(LineBreak));
end;

例：

procedure TForm1.Button1Click(Sender: TObject);
var
  Lines : TStrings;
begin
  Lines := TMyStringList.Create();
  try
    Lines.LoadFromFile('.\input.txt');
    Lines.SaveToFile('.\output.txt');
  finally
    Lines.Free;
  end;
end;