ベクトル内のアイテムのインデックスを見つけるにはどうすればよいですか？

ある????べきアイデアはありますか？ビルトインはありますか？このタスクを達成するための最良の方法は何でしょうか？

(def v ["one" "two" "three" "two"])

(defn find-thing [ thing vectr ]
  (????))

(find-thing "two" v) ; ? maybe 1, maybe '(1,3), actually probably a lazy-seq

ビルトイン：

user> (def v ["one" "two" "three" "two"])
#'user/v
user> (.indexOf v "two")
1
user> (.indexOf v "foo")
-1

すべての一致のインデックスの遅延シーケンスが必要な場合：

user> (map-indexed vector v)
([0 "one"] [1 "two"] [2 "three"] [3 "two"])
user> (filter #(= "two" (second %)) *1)
([1 "two"] [3 "two"])
user> (map first *1)
(1 3)
user> (map first 
           (filter #(= (second %) "two")
                   (map-indexed vector v)))
(1 3)

Stuart Hallowayは、この投稿http://www.mail-archive.com/clojure@googlegroups.com/msg34159.htmlで本当に素晴らしい答えを出しました。

(use '[clojure.contrib.seq :only (positions)])
(def v ["one" "two" "three" "two"])
(positions #{"two"} v) ; -> (1 3)

最初の値を取得したい場合firstは、結果に使用してください。

(first (positions #{"two"} v)) ; -> 1

編集：clojure.contrib.seq消えたので、私は簡単な実装の例で私の答えを更新しました：

(defn positions
  [pred coll]
  (keep-indexed (fn [idx x]
                  (when (pred x)
                    idx))
                coll))

(defn find-thing [needle haystack]
  (keep-indexed #(when (= %2 needle) %1) haystack))

ただし、インデックスをいじらないように警告したいと思います。ほとんどの場合、慣用的で扱いにくいClojureが生成されることはほとんどありません。

Clojure 1.4の時点では、メンテナーが不足しているため、clojure.contrib.seq（したがってpositions関数）は使用できません：http： //dev.clojure.org/display/design/Where+Did+Clojure.Contrib+Go

ソースclojure.contrib.seq/positionsとその依存関係clojure.contrib.seq/indexedは次のとおりです。

(defn indexed
  "Returns a lazy sequence of [index, item] pairs, where items come
  from 's' and indexes count up from zero.

  (indexed '(a b c d))  =>  ([0 a] [1 b] [2 c] [3 d])"
  [s]
  (map vector (iterate inc 0) s))

(defn positions
  "Returns a lazy sequence containing the positions at which pred
   is true for items in coll."
  [pred coll]
  (for [[idx elt] (indexed coll) :when (pred elt)] idx))

(positions #{2} [1 2 3 4 1 2 3 4]) => (1 5)

ここで入手可能：http：//clojuredocs.org/clojure_contrib/clojure.contrib.seq/positions

私は自分の質問に答えようとしていましたが、ブライアンはもっと良い答えで私を打ち負かしました！

(defn indices-of [f coll]
  (keep-indexed #(if (f %2) %1 nil) coll))

(defn first-index-of [f coll]
  (first (indices-of f coll)))

(defn find-thing [value coll]
  (first-index-of #(= % value) coll))

(find-thing "two" ["one" "two" "three" "two"]) ; 1
(find-thing "two" '("one" "two" "three")) ; 1

;; these answers are a bit silly
(find-thing "two" #{"one" "two" "three"}) ; 1
(find-thing "two" {"one" "two" "two" "three"}) ; nil

これが私の貢献ですloop。ing構造を使用し、nil失敗時に戻ります。

できる限りループを避けようとしますが、この問題には適しているようです。

(defn index-of [xs x]
  (loop [a (first xs)
         r (rest xs)
         i 0]
    (cond
      (= a x)    i
      (empty? r) nil
      :else      (recur (first r) (rest r) (inc i)))))

最近、インデックスを数回見つける必要がありました。問題に取り組む別の方法を見つけるよりも簡単だったので、そうすることを選択しました。途中で、Clojureリストに.indexOf（Object object、int start）メソッドがないことを発見しました。私はそのように問題に対処しました：

(defn index-of
"Returns the index of item. If start is given indexes prior to
 start are skipped."
([coll item] (.indexOf coll item))
([coll item start]
  (let [unadjusted-index (.indexOf (drop start coll) item)]
    (if (= -1 unadjusted-index)
  unadjusted-index
  (+ unadjusted-index start)))))

私はreduce-kvで行きます

(defn find-index [pred vec]
  (reduce-kv
    (fn [_ k v]
      (if (pred v)
        (reduced k)))
    nil
    vec))