Vim：保存時に親ディレクトリを作成する

呼び出してvim foo/bar/somefileもfoo/barまだ存在していない、Vimは、保存することを拒否します。

シェルに切り替えたり:!mkdir foo/barVimから実行したりできることは知っていますが、怠惰です:) Vimがバッファーを保存するときに自動的にそれを実行する方法はありますか？

augroup BWCCreateDir
    autocmd!
    autocmd BufWritePre * if expand("<afile>")!~#'^\w\+:/' && !isdirectory(expand("%:h")) | execute "silent! !mkdir -p ".shellescape(expand('%:h'), 1) | redraw! | endif
augroup END

条件に注意してください：expand("<afile>")!~#'^\w\+:/'のようなファイルのためのディレクトリを作成からvimのを防ぐことができますftp://*し、!isdirectory高価なは、mkdirコールを防ぐことができます。

更新：空ではないbuftypeもチェックして使用する、やや優れたソリューションmkdir()：

function s:MkNonExDir(file, buf)
    if empty(getbufvar(a:buf, '&buftype')) && a:file!~#'\v^\w+\:\/'
        let dir=fnamemodify(a:file, ':h')
        if !isdirectory(dir)
            call mkdir(dir, 'p')
        endif
    endif
endfunction
augroup BWCCreateDir
    autocmd!
    autocmd BufWritePre * :call s:MkNonExDir(expand('<afile>'), +expand('<abuf>'))
augroup END

私の質問への提案に基づいて、これが私が結局終わったものです：

function WriteCreatingDirs()
    execute ':silent !mkdir -p %:h'
    write
endfunction
command W call WriteCreatingDirs()

これは:Wコマンドを定義します。理想的には、私はすべてを持っているしたいのですが:w!、:wq、:wq!、:wallなどが同じように動作しますが、それは基本的にすべてのカスタム関数でそれらを再実装することなく可能だ場合、私はわかりません。

これを〜/ .vimrcに追加しました

cnoremap mk. !mkdir -p <c-r>=expand("%:h")<cr>/

私がいるディレクトリを作成する必要がある場合は:mk.、「！mkdir -p / path / to / my / file /」に置き換えて、コマンドを呼び出す前に確認できるようにします。

私が作った:saveas!行方不明場合は、ディレクトリを作成します。https://github.com/henrik/dotfiles/commit/54cc9474b345332cf54cf25b51ddb8a9bd00a0bb

このコードは、でディレクトリを作成する:wか、単にで作成するかを尋ねます:w!：

augroup vimrc-auto-mkdir
  autocmd!
  autocmd BufWritePre * call s:auto_mkdir(expand('<afile>:p:h'), v:cmdbang)
  function! s:auto_mkdir(dir, force)
    if !isdirectory(a:dir)
          \   && (a:force
          \       || input("'" . a:dir . "' does not exist. Create? [y/N]") =~? '^y\%[es]$')
      call mkdir(iconv(a:dir, &encoding, &termencoding), 'p')
    endif
  endfunction
augroup END

私はこれを3行で行うことができたと思います。他の人がこの答えで言っていることを組み合わせて。

これはトリックを行うようです：

if has("autocmd")
  autocmd BufWritePre * :silent !mkdir -p %:p:h
end

バッファを保存するときに、自動的にフォルダを作成しようとします。何か悪いことが起こった場合（つまり、権限の問題）、シャットダウンしてファイルの書き込みを失敗させます。

明らかな欠陥を見つけた場合は、コメントを投稿してください。私はvimscriptに精通していません。

編集：ZyXのおかげでメモ

• フォルダにスペースがある場合、これは機能しません（どうやら、適切にエスケープされていないなど）。
• または、疑似ファイルを実行している場合。
• または、vimrcを調達している場合。
• しかし、息子、それは短いです。