vimでタブをスペースに置き換える

gVimでタブをスペースに変換したいのですが。私は次の行をmyに追加しました_vimrc：

set tabstop=2

2つのスペースで停止するように機能しますが、1つのタブキーが挿入されているように見えます（後でスペースを数えるためにhキーを使用しようとしました）。

gVimでタブをスペースに変換するにはどうすればよいかわかりません。

IIRC、次のようなもの：

set tabstop=2 shiftwidth=2 expandtab

トリックを行う必要があります。すでにタブがある場合は、タブをダブルスペースに置き換えるための素晴らしいグローバルREをフォローアップします。

他の回答に従ってexpandtabを有効にしたら、新しい設定に従って既存のファイルを変換する非常に便利な方法は次のとおりです。

:retab

現在のバッファで動作します。

試す

set expandtab

ソフトタブ用。

既存のタブを修正するには：

:%s/\t/  /g

タブストップをすでに2スペースに設定しているため、2つのスペースを使用しました。

これは私のために働きました：

あなたは最初にこれを行うとタブを見ることができます：

:set list

次に、タブを置換できるようにするために、次のようにします。

:set expandtab

その後

:retab

これで、すべてのタブがスペースに置き換えられ、次のように通常の表示に戻ることができます。

:set nolist

gg=G ファイル全体を再インデントし、同僚からファイルに取得したすべてのタブではなくてもほとんどのタブを削除します。

次の行を.vimrcに追加します

set expandtab
set tabstop=4
set shiftwidth=4
map <F2> :retab <CR> :wq! <CR>

vimでファイルを開き、F2を押します。タブは4つのスペースに変換され、ファイルは自動的に保存されます。

\tスペースを8個に保つ場合は、次の設定を検討してください。

   set softtabstop=2 tabstop=8 shiftwidth=2

これにより<TAB>、プレスごとに2つのスペースが得られますが、実際の\tコードでは8文字として表示されます。

これでうまくいきました：

:set tabstop=2 shiftwidth=2 expandtab | retab

最初にファイル内のタブを検索します：/ ^ I：set expandtab：retab

働くでしょう。

この記事には、タブとスペースを処理し、それらの間で変換するための優れたvimrcスクリプトがあります。

次のコマンドが提供されています。

Space2Tab インデントのみで、スペースをタブに変換します。

Tab2Space インデントのみで、タブをスペースに変換します。

RetabIndent 実行Space2Tab（ 'expandtab'が設定されている場合）、またはTab2Space（それ以外の場合）。

各コマンドは、タブ列のスペースの数を指定する引数を受け入れます。デフォルトでは、「tabstop」設定が使用されます。

出典：http : //vim.wikia.com/wiki/Super_retab#Script

" Return indent (all whitespace at start of a line), converted from
" tabs to spaces if what = 1, or from spaces to tabs otherwise.
" When converting to tabs, result has no redundant spaces.
function! Indenting(indent, what, cols)
  let spccol = repeat(' ', a:cols)
  let result = substitute(a:indent, spccol, '\t', 'g')
  let result = substitute(result, ' \+\ze\t', '', 'g')
  if a:what == 1
    let result = substitute(result, '\t', spccol, 'g')
  endif
  return result
endfunction

" Convert whitespace used for indenting (before first non-whitespace).
" what = 0 (convert spaces to tabs), or 1 (convert tabs to spaces).
" cols = string with number of columns per tab, or empty to use 'tabstop'.
" The cursor position is restored, but the cursor will be in a different
" column when the number of characters in the indent of the line is changed.
function! IndentConvert(line1, line2, what, cols)
  let savepos = getpos('.')
  let cols = empty(a:cols) ? &tabstop : a:cols
  execute a:line1 . ',' . a:line2 . 's/^\s\+/\=Indenting(submatch(0), a:what, cols)/e'
  call histdel('search', -1)
  call setpos('.', savepos)
endfunction

command! -nargs=? -range=% Space2Tab call IndentConvert(<line1>,<line2>,0,<q-args>)
command! -nargs=? -range=% Tab2Space call IndentConvert(<line1>,<line2>,1,<q-args>)
command! -nargs=? -range=% RetabIndent call IndentConvert(<line1>,<line2>,&et,<q-args>)

これは私が最初に解決策を探しに行ったときのここでの答えよりも少し助けになりました。

expandタブをスペースに変換するUNIXユーティリティです。setvimで何もしたくない場合は、vimからシェルコマンドを使用できます。

:!% expand -t8