にボタンを追加し、クリックしたDataGridViewときにコードを実行したいとします。
簡単な方法-次の手順に従ってください：
してはいけないこと：
最初に、ここではしてはいけないことです：
ここで他のいくつかの回答の提案を避け、ボタンがクリックされたかどうかを判断するために列インデックスまたは列名をハードコーディングするためにMSDNのドキュメントで提供されていました。クリックイベントはグリッド全体に登録されるので、どういうわけかボタンがクリックされたことを確認する必要がありますが、ボタンが特定の列名またはインデックスにあると想定してそうするべきではありません...簡単な方法があります...
また、どのイベントを処理するかにも注意してください。繰り返しになりますが、ドキュメントと多くの例ではこれが間違っています。ほとんどの例CellClickでは、発生するイベントを処理します。
セルの任意の部分がクリックされたとき。
...しかし、行ヘッダーがクリックされたときにも起動します。このため、e.RowIndex値が0未満かどうかを判断するためだけにコードを追加する必要があります
代わりにCellContentClick発生するのみを処理します。
セル内のコンテンツがクリックされたとき
何らかの理由で、列ヘッダーもセル内の「コンテンツ」と見なされるため、以下でそれを確認する必要があります。
Dos：
だからここにあなたが何をすべきかです：
まず、キャスト送信者を型DataGridViewに、設計時にその内部プロパティを公開します。パラメーターのタイプを変更できますが、ハンドラーの追加または削除が難しい場合があります。
次に、ボタンがクリックされたかどうかを確認するには、イベントを発生させる列のタイプがであることを確認してくださいDataGridViewButtonColumn。既に送信者をtypeにキャストしているためDataGridView、を使用してColumnsコレクションを取得し、現在の列を選択できますe.ColumnIndex。次に、そのオブジェクトがタイプかどうかを確認しますDataGridViewButtonColumn。
もちろん、グリッドごとに複数のボタンを区別する必要がある場合は、列名またはインデックスに基づいて選択できますが、これは最初のチェックではありません。常にボタンが最初にクリックされたことを確認してから、他のものを適切に処理してください。グリッドごとにボタンが1つしかないほとんどの場合、すぐにレースにジャンプできます。
すべてを一緒に入れて：
C＃：
private void dataGridView1_CellContentClick(object sender, DataGridViewCellEventArgs e)
{
var senderGrid = (DataGridView)sender;
if (senderGrid.Columns[e.ColumnIndex] is DataGridViewButtonColumn &&
e.RowIndex >= 0)
{
//TODO - Button Clicked - Execute Code Here
}
}
VB：
Private Sub DataGridView1_CellContentClick(sender As System.Object, e As DataGridViewCellEventArgs) _
Handles DataGridView1.CellContentClick
Dim senderGrid = DirectCast(sender, DataGridView)
If TypeOf senderGrid.Columns(e.ColumnIndex) Is DataGridViewButtonColumn AndAlso
e.RowIndex >= 0 Then
'TODO - Button Clicked - Execute Code Here
End If
End Sub
アップデート1-カスタムイベント
少し楽しみたい場合は、DataGridでボタンがクリックされるたびに発生する独自のイベントを追加できます。DataGrid自体にそれを追加することはできません。継承などで面倒になることはありませんが、カスタムイベントをフォームに追加して、適切なときにそれを発生させることができます。コードはもう少し多くなりますが、ボタンがクリックされたときに何をしたいかと、ボタンがクリックされたかどうかを判断する方法が分かれているという利点があります。
イベントを宣言し、適切なときにイベントを発生させて処理するだけです。次のようになります。
Event DataGridView1ButtonClick(sender As DataGridView, e As DataGridViewCellEventArgs)
Private Sub DataGridView1_CellContentClick(sender As System.Object, e As DataGridViewCellEventArgs) Handles DataGridView1.CellContentClick
Dim senderGrid = DirectCast(sender, DataGridView)
If TypeOf senderGrid.Columns(e.ColumnIndex) Is DataGridViewButtonColumn AndAlso e.RowIndex >= 0 Then
RaiseEvent DataGridView1ButtonClick(senderGrid, e)
End If
End Sub
Private Sub DataGridView1_ButtonClick(sender As DataGridView, e As DataGridViewCellEventArgs) Handles Me.DataGridView1ButtonClick
'TODO - Button Clicked - Execute Code Here
End Sub
アップデート2-拡張グリッド
これらのことを私たちのために行ったばかりのグリッドで作業していたら、すばらしいと思います。最初の質問に簡単に答えることができましたyou've added a button to your DataGridView and you want to run some code when it's clicked。を拡張するアプローチを次に示しDataGridViewます。すべてのライブラリでカスタムコントロールを提供するという面倒な価値はないかもしれませんが、少なくとも、ボタンがクリックされたかどうかを判断するために使用されるコードを最大限に再利用します。
これをアセンブリに追加するだけです：
Public Class DataGridViewExt : Inherits DataGridView
Event CellButtonClick(sender As DataGridView, e As DataGridViewCellEventArgs)
Private Sub CellContentClicked(sender As System.Object, e As DataGridViewCellEventArgs) Handles Me.CellContentClick
If TypeOf Me.Columns(e.ColumnIndex) Is DataGridViewButtonColumn AndAlso e.RowIndex >= 0 Then
RaiseEvent CellButtonClick(Me, e)
End If
End Sub
End Class
それでおしまい。二度と触れないでください。DataGridが、DataGridViewとDataGridViewExtまったく同じように機能するタイプであることを確認してください。ただし、次のように処理できる追加のイベントが発生します。
Private Sub DataGridView1_ButtonClick(sender As DataGridView, e As DataGridViewCellEventArgs) _
Handles DataGridView1.CellButtonClick
'TODO - Button Clicked - Execute Code Here
End Sub
