XSLT文字列置換

私はXSLを本当に知りませんが、このコードを修正する必要があります。簡単にするためにコードを減らしました。
このエラーが発生します

無効なXSLT / XPath関数

この行に

<xsl:variable name="text" select="replace($text,'a','b')"/>

これはXSLです

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:inm="http://www.inmagic.com/webpublisher/query" version="1.0">
    <xsl:output method="text" encoding="UTF-8" />

    <xsl:preserve-space elements="*" />
    <xsl:template match="text()" />

    <xsl:template match="mos">
        <xsl:apply-templates />

        <xsl:for-each select="mosObj">
          'Notes or subject' 
           <xsl:call-template
                name="rem-html">
                <xsl:with-param name="text" select="SBS_ABSTRACT" />
            </xsl:call-template>
        </xsl:for-each>
    </xsl:template>

    <xsl:template name="rem-html">
        <xsl:param name="text" />
        <xsl:variable name="text" select="replace($text, 'a', 'b')" />
    </xsl:template>
</xsl:stylesheet>

誰かがそれの何が問題なのか教えてもらえますか？

replace XSLT1.0では使用できません。

Codeslingには、関数の代わりに使用できる文字列置換のテンプレートがあります。

<xsl:template name="string-replace-all">
    <xsl:param name="text" />
    <xsl:param name="replace" />
    <xsl:param name="by" />
    <xsl:choose>
        <xsl:when test="$text = '' or $replace = ''or not($replace)" >
            <!-- Prevent this routine from hanging -->
            <xsl:value-of select="$text" />
        </xsl:when>
        <xsl:when test="contains($text, $replace)">
            <xsl:value-of select="substring-before($text,$replace)" />
            <xsl:value-of select="$by" />
            <xsl:call-template name="string-replace-all">
                <xsl:with-param name="text" select="substring-after($text,$replace)" />
                <xsl:with-param name="replace" select="$replace" />
                <xsl:with-param name="by" select="$by" />
            </xsl:call-template>
        </xsl:when>
        <xsl:otherwise>
            <xsl:value-of select="$text" />
        </xsl:otherwise>
    </xsl:choose>
</xsl:template>

として呼び出されます：

<xsl:variable name="newtext">
    <xsl:call-template name="string-replace-all">
        <xsl:with-param name="text" select="$text" />
        <xsl:with-param name="replace" select="a" />
        <xsl:with-param name="by" select="b" />
    </xsl:call-template>
</xsl:variable>

一方、文字通り1つの文字を別の文字に置き換えるだけでよい場合translateは、同様の署名を持つ呼び出しを行うことができます。このようなものはうまくいくはずです：

<xsl:variable name="newtext" select="translate($text,'a','b')"/>

また、この例では、変数名を「newtext」に変更しました。XSLT変数は不変であるため$foo = $foo、元のコードと同じことはできません。

これは、C＃のString.Replace（）関数と同様に機能するXSLT関数です。

このテンプレートには、以下の3つのパラメータがあります

テキスト：-メインの文字列

置換：-置換する文字列

by：-新しい文字列で応答する文字列

以下はテンプレートです

<xsl:template name="string-replace-all">
  <xsl:param name="text" />
  <xsl:param name="replace" />
  <xsl:param name="by" />
  <xsl:choose>
    <xsl:when test="contains($text, $replace)">
      <xsl:value-of select="substring-before($text,$replace)" />
      <xsl:value-of select="$by" />
      <xsl:call-template name="string-replace-all">
        <xsl:with-param name="text" select="substring-after($text,$replace)" />
        <xsl:with-param name="replace" select="$replace" />
        <xsl:with-param name="by" select="$by" />
      </xsl:call-template>
    </xsl:when>
    <xsl:otherwise>
      <xsl:value-of select="$text" />
    </xsl:otherwise>
  </xsl:choose>
</xsl:template>

以下のサンプルは、それを呼び出す方法を示しています

<xsl:variable name="myVariable ">
  <xsl:call-template name="string-replace-all">
    <xsl:with-param name="text" select="'This is a {old} text'" />
    <xsl:with-param name="replace" select="'{old}'" />
    <xsl:with-param name="by" select="'New'" />
  </xsl:call-template>
</xsl:variable>

詳しくは下記URLをご覧ください。

注：ソース文字列内の膨大な数のインスタンス（長いテキストの新しい行など）を置き換える必要がある場合に前述のアルゴリズムを使用する場合は、再帰的であるために終了する可能性が高くなりますStackOverflowExceptionコール。

Xalan（Saxonでそれを行う方法を調べていませんでした）の組み込みJava型埋め込みのおかげでこの問題を解決しました：

<xsl:stylesheet version="1.0" exclude-result-prefixes="xalan str"
                xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
                xmlns:xalan="http://xml.apache.org/xalan"
                xmlns:str="xalan://java.lang.String"
        >
...
<xsl:value-of select="str:replaceAll(
    str:new(text()),
    $search_string,
    $replace_string)"/>
...
</xsl:stylesheet>

プロセッサが.NETで実行されている場合、またはMSXMLを使用している場合（Javaベースまたは他のネイティブプロセッサとは対照的に）、次のコードを使用できます。を使用しmsxsl:scriptます。

必ず名前空間xmlns:msxsl="urn:schemas-microsoft-com:xslt"をルートxsl:stylesheetまたはxsl:transform要素に追加してください。

さらに、outletたとえば、任意の名前空間にバインドしますxmlns:outlet = "http://my.functions"。

<msxsl:script implements-prefix="outlet" language="javascript">
function replace_str(str_text,str_replace,str_by)
{
     return str_text.replace(str_replace,str_by);
}
</msxsl:script>


<xsl:variable name="newtext" select="outlet:replace_str(string(@oldstring),'me','you')" />

私はこの答えを打ち続けます。しかし、それらのどれもxsltproc（そしておそらくほとんどのXSLT 1.0プロセッサ）の最も簡単な解決策をリストしていません：

1. exslt文字列名をスタイルシートに追加します。

<xsl:stylesheet
  version="1.0"
  xmlns:str="http://exslt.org/strings"
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

2. 次に、次のように使用します。

<xsl:value-of select="str:replace(., ' ', '')"/>

ルーチンはかなり良いですが、アプリがハングする原因になるため、ケースを追加する必要がありました。

  <xsl:when test="$text = '' or $replace = ''or not($replace)" >
    <xsl:value-of select="$text" />
    <!-- Prevent thsi routine from hanging -->
  </xsl:when>

関数が再帰的に呼び出される前。

私はここから答えを得ました： 無限ループにぶら下がっているテストのとき

ありがとうございました！