バッチファイルの文字列置換

次のコマンドを使用して、バッチファイル内の文字列を置き換えることができます

set str="jump over the chair"
set str=%str:chair=table%

これらの行は正常に機能し、文字列「jump over the chair」を「jump over the table」に変更します。ここで、文字列内の「chair」という単語を変数に置き換えたいのですが、その方法がわかりません。

set word=table
set str="jump over the chair"
??

何か案は？

！を使用できますが、ENABLEDELAYEDEXPANSIONスイッチを設定する必要があります。

setlocal ENABLEDELAYEDEXPANSION
set word=table
set str="jump over the chair"
set str=%str:chair=!word!%

次の小さなトリックを使用できます。

set word=table
set str="jump over the chair"
call set str=%%str:chair=%word%%%
echo %str%

callそこに、変数展開の別の層を引き起こし、それが必要な元引用すること%兆しをしかし、それはすべての終わりにうまくいきます。

JoeyのAnswerを使用して関数を作成できました。

次のように使用します。

@echo off
SETLOCAL ENABLEDELAYEDEXPANSION

SET "MYTEXT=jump over the chair"
echo !MYTEXT!
call:ReplaceText "!MYTEXT!" chair table RESULT
echo !RESULT!

GOTO:EOF

これらの関数は、バッチファイルの下部にあります。

:FUNCTIONS
@REM FUNCTIONS AREA
GOTO:EOF
EXIT /B

:ReplaceText
::Replace Text In String
::USE:
:: CALL:ReplaceText "!OrginalText!" OldWordToReplace NewWordToUse  Result
::Example
::SET "MYTEXT=jump over the chair"
::  echo !MYTEXT!
::  call:ReplaceText "!MYTEXT!" chair table RESULT
::  echo !RESULT!
::
:: Remember to use the "! on the input text, but NOT on the Output text.
:: The Following is Wrong: "!MYTEXT!" !chair! !table! !RESULT!
:: ^^Because it has a ! around the chair table and RESULT
:: Remember to add quotes "" around the MYTEXT Variable when calling.
:: If you don't add quotes, it won't treat it as a single string
::
set "OrginalText=%~1"
set "OldWord=%~2"
set "NewWord=%~3"
call set OrginalText=%%OrginalText:!OldWord!=!NewWord!%%
SET %4=!OrginalText!
GOTO:EOF

また、バッチファイルの先頭に「SETLOCAL ENABLEDELAYEDEXPANSION」を追加する必要があります。そうしないと、これが正しく機能しません。

SETLOCAL ENABLEDELAYEDEXPANSION
@REM # Remember to add this to the top of your batch file.

これはうまくいきます

@echo off    
set word=table    
set str=jump over the chair    
set rpl=%str:chair=%%word%    
echo %rpl%