バッチファイルに引数を渡すにはどうすればよいですか？

ファイルにハードコードするのではなく、実行時にIDとパスワードをバッチファイルに渡す必要があります。

コマンドラインは次のようになります。

test.cmd admin P@55w0rd > test-log.txt

別の便利なヒントは、%*「すべて」を意味するために使用することです。例えば：

echo off
set arg1=%1
set arg2=%2
shift
shift
fake-command /u %arg1% /p %arg2% %*

実行すると：

test-command admin password foo bar

上記のバッチファイルが実行されます。

fake-command /u admin /p password admin password foo bar

構文が少し間違っているかもしれませんが、これは一般的な考えです。

ここに私がそれをした方法があります：

@fake-command /u %1 /p %2

コマンドは次のようになります。

test.cmd admin P@55w0rd > test-log.txt

%1最初のパラメータに適用されます%2（ここでトリッキーな部分です）第二に適用されます。この方法で渡されるパラメーターは最大9つです。

欠落しているパラメーターをインテリジェントに処理したい場合は、次のようにします。

IF %1.==. GOTO No1
IF %2.==. GOTO No2
... do stuff...
GOTO End1

:No1
  ECHO No param 1
GOTO End1
:No2
  ECHO No param 2
GOTO End1

:End1

バッチパラメータへのアクセスは、％1、％2、...％9または％*を使用して簡単にすることができますが
、内容が簡単な場合のみです。

"&"^&エラーを生成せずに％1にアクセスすることはできないため、などの複雑なコンテンツを簡単に作成する方法はありません。

set  var=%1
set "var=%1"
set  var=%~1
set "var=%~1"

ラインはに拡大します

set  var="&"&
set "var="&"&"
set  var="&"&
set "var="&"&"

そして、それぞれの行は失敗&します。

これは、一時ファイルから注釈付きバージョンのパラメーターを読み取ることで解決できます。

@echo off
SETLOCAL DisableDelayedExpansion

SETLOCAL
for %%a in (1) do (
    set "prompt="
    echo on
    for %%b in (1) do rem * #%1#
    @echo off
) > param.txt
ENDLOCAL

for /F "delims=" %%L in (param.txt) do (
  set "param1=%%L"
)
SETLOCAL EnableDelayedExpansion
set "param1=!param1:*#=!"
set "param1=!param1:~0,-2!"
echo %%1 is '!param1!'

コツはecho on、remステートメントの後に％1 を有効にして展開することです（でも機能します%2 .. %*）。
その"&"&ため、コメントされているように、エラーを生成せずにエコーすることもできます。

ただし、の出力をリダイレクトできるようにするにはecho on、2つのforループが必要です。

余分な文字* #は/?（のヘルプを表示するREM）などのコンテンツに対して安全にするために使用されます。
または、行末のキャレット^は、の後でも複数行文字として機能する可能性がありremます。

次に、ファイルからremパラメータ出力を読み取りますが、慎重に行ってください。
FOR / Fは遅延拡張をオフにして動作するはずです。それ以外の場合は「！」破壊されます。
で余分な文字を削除した後param1、あなたはそれを手に入れました。

param1安全に使用するには、遅延拡張を有効にします。

はい、そしてand とgang を使用する%%1ときのように変数を使用することを忘れないでください。iffor

doubleを忘れた場合は、%コマンドライン引数（nullの可能性があります）に置き換えられ、かなり紛らわしいエラーメッセージが表示されます。

それを複雑にする必要はありません。これは単にコマンド％1％2パラメータです。たとえば、

@echo off

xcopy %1 %2 /D /E /C /Q /H /R /K /Y /Z

echo copied %1 to %2

pause

「一時停止」は、バッチファイルの処理内容を表示し、ANYキーが押されるのを待ちます。これをxx.batという名前でWindowsフォルダに保存します。

これを使用するには、たとえば次のように入力します。

xx c:\f\30\*.* f:\sites\30

このバッチファイルは、ファイルのみのコピーや新しいファイルなど、必要なすべてのパラメーターを処理します。Windowsの前から使用しています。コピーされているファイルの名前を確認する場合は、Qパラメーターを省略します。

最近、この件について友人から質問があったので、バッチファイルでコマンドライン引数を処理する方法を投稿したいと思いました。

ご覧のとおり、この手法には多少のオーバーヘッドがありますが、これにより、バッチファイルを非常に理解しやすく、すばやく実装できます。次の構造をサポートするだけでなく、

>template.bat [-f] [--flag] [/f] [--namedvalue value] arg1 [arg2][arg3][...]

それのJISTを持っている:init、:parseと:main機能を。

使用例

>template.bat /?
test v1.23
This is a sample batch file template,
providing command-line arguments and flags.

USAGE:
test.bat [flags] "required argument" "optional argument"

/?, --help           shows this help
/v, --version        shows the version
/e, --verbose        shows detailed output
-f, --flag value     specifies a named parameter value

>template.bat          <- throws missing argument error
(same as /?, plus..)
****                                   ****
****    MISSING "REQUIRED ARGUMENT"    ****
****                                   ****

>template.bat -v
1.23

>template.bat --version
test v1.23
This is a sample batch file template,
providing command-line arguments and flags.

>template.bat -e arg1
**** DEBUG IS ON
UnNamedArgument:    "arg1"
UnNamedOptionalArg: not provided
NamedFlag:          not provided

>template.bat --flag "my flag" arg1 arg2
UnNamedArgument:    "arg1"
UnNamedOptionalArg: "arg2"
NamedFlag:          "my flag"

>template.bat --verbose "argument #1" --flag "my flag" second
**** DEBUG IS ON
UnNamedArgument:    "argument #1"
UnNamedOptionalArg: "second"
NamedFlag:          "my flag"

template.bat

@::!/dos/rocks
@echo off
goto :init

:header
    echo %__NAME% v%__VERSION%
    echo This is a sample batch file template,
    echo providing command-line arguments and flags.
    echo.
    goto :eof

:usage
    echo USAGE:
    echo   %__BAT_NAME% [flags] "required argument" "optional argument" 
    echo.
    echo.  /?, --help           shows this help
    echo.  /v, --version        shows the version
    echo.  /e, --verbose        shows detailed output
    echo.  -f, --flag value     specifies a named parameter value
    goto :eof

:version
    if "%~1"=="full" call :header & goto :eof
    echo %__VERSION%
    goto :eof

:missing_argument
    call :header
    call :usage
    echo.
    echo ****                                   ****
    echo ****    MISSING "REQUIRED ARGUMENT"    ****
    echo ****                                   ****
    echo.
    goto :eof

:init
    set "__NAME=%~n0"
    set "__VERSION=1.23"
    set "__YEAR=2017"

    set "__BAT_FILE=%~0"
    set "__BAT_PATH=%~dp0"
    set "__BAT_NAME=%~nx0"

    set "OptHelp="
    set "OptVersion="
    set "OptVerbose="

    set "UnNamedArgument="
    set "UnNamedOptionalArg="
    set "NamedFlag="

:parse
    if "%~1"=="" goto :validate

    if /i "%~1"=="/?"         call :header & call :usage "%~2" & goto :end
    if /i "%~1"=="-?"         call :header & call :usage "%~2" & goto :end
    if /i "%~1"=="--help"     call :header & call :usage "%~2" & goto :end

    if /i "%~1"=="/v"         call :version      & goto :end
    if /i "%~1"=="-v"         call :version      & goto :end
    if /i "%~1"=="--version"  call :version full & goto :end

    if /i "%~1"=="/e"         set "OptVerbose=yes"  & shift & goto :parse
    if /i "%~1"=="-e"         set "OptVerbose=yes"  & shift & goto :parse
    if /i "%~1"=="--verbose"  set "OptVerbose=yes"  & shift & goto :parse

    if /i "%~1"=="--flag"     set "NamedFlag=%~2"   & shift & shift & goto :parse

    if not defined UnNamedArgument     set "UnNamedArgument=%~1"     & shift & goto :parse
    if not defined UnNamedOptionalArg  set "UnNamedOptionalArg=%~1"  & shift & goto :parse

    shift
    goto :parse

:validate
    if not defined UnNamedArgument call :missing_argument & goto :end

:main
    if defined OptVerbose (
        echo **** DEBUG IS ON
    )

    echo UnNamedArgument:    "%UnNamedArgument%"

    if defined UnNamedOptionalArg      echo UnNamedOptionalArg: "%UnNamedOptionalArg%"
    if not defined UnNamedOptionalArg  echo UnNamedOptionalArg: not provided

    if defined NamedFlag               echo NamedFlag:          "%NamedFlag%"
    if not defined NamedFlag           echo NamedFlag:          not provided

:end
    call :cleanup
    exit /B

:cleanup
    REM The cleanup function is only really necessary if you
    REM are _not_ using SETLOCAL.
    set "__NAME="
    set "__VERSION="
    set "__YEAR="

    set "__BAT_FILE="
    set "__BAT_PATH="
    set "__BAT_NAME="

    set "OptHelp="
    set "OptVersion="
    set "OptVerbose="

    set "UnNamedArgument="
    set "UnNamedArgument2="
    set "NamedFlag="

    goto :eof

@ECHO OFF
:Loop
IF "%1"=="" GOTO Continue
SHIFT
GOTO Loop
:Continue

注：引用符で囲まれている"%1"==""場合、IF は問題を引き起こし%1ます。

その場合はIF [%1]==[]、IF "%~1"==""代わりにまたはNT 4（SP6）以降のみを使用してください。

これを単純にしてみましょう。

これが.cmdファイルです。

@echo off
rem this file is named echo_3params.cmd
echo %1
echo %2
echo %3
set v1=%1
set v2=%2
set v3=%3
echo v1 equals %v1%
echo v2 equals %v2%
echo v3 equals %v3%

コマンドラインからの3つの呼び出しを次に示します。

C:\Users\joeco>echo_3params 1abc 2 def  3 ghi
1abc
2
def
v1 equals 1abc
v2 equals 2
v3 equals def

C:\Users\joeco>echo_3params 1abc "2 def"  "3 ghi"
1abc
"2 def"
"3 ghi"
v1 equals 1abc
v2 equals "2 def"
v3 equals "3 ghi"

C:\Users\joeco>echo_3params 1abc '2 def'  "3 ghi"
1abc
'2
def'
v1 equals 1abc
v2 equals '2
v3 equals def'

C:\Users\joeco>

FOR %%A IN (%*) DO (
    REM Now your batch file handles %%A instead of %1
    REM No need to use SHIFT anymore.
    ECHO %%A
)

これは、引用符で囲まれているかどうかに関係なく、バッチパラメータ（％*）をループしてから、各パラメータをエコーし​​ます。

関数（または外部.bat）として呼び出すことができる単純なread_paramsスクリプトを作成し、すべての変数を現在の環境に配置します。関数はcall元のパラメーターのコピーで編集されるため、元のパラメーターは変更されません。

たとえば、次のコマンドがあるとします。

myscript.bat some -random=43 extra -greeting="hello world" fluff

myscript.bat 関数を呼び出した後、変数を使用できます。

call :read_params %*

echo %random%
echo %greeting%

これが関数です：

:read_params
if not %1/==/ (
    if not "%__var%"=="" (
        if not "%__var:~0,1%"=="-" (
            endlocal
            goto read_params
        )
        endlocal & set %__var:~1%=%~1
    ) else (
        setlocal & set __var=%~1
    )
    shift
    goto read_params
)
exit /B

制限事項

• などの値のない引数は読み込めません-force。使用できます-force=trueが、値を持たないパラメーターのリストを事前に知らなければ、空白の値を許可する方法は考えられません。

変更ログ

• 2016年2月18日
  • 拡張の遅延は不要
  • -パラメータの前を探すことにより、他のコマンドライン引数で動作するようになりました。

バッチファイル

set argument1=%1
set argument2=%2
echo %argument1%
echo %argument2%

％1と％2は、それぞれ最初と2番目の引数値を返します。

そしてコマンドラインで、引数を渡します

Directory> batchFileName admin P@55w0rd 

出力は

admin
P@55w0rd

コマンドラインでセット変数を参照するには、次の%a%ように使用する必要があります。

set a=100 
echo %a%  
rem output = 100 

注：これはWindows 7 proで機能します。

@Jonによる他の回答に触発されて、名前付きパラメーター、オプションの値、およびスイッチを抽出するためのより一般的なアルゴリズムを作成しました。

ユーティリティを実装したいとしましょうfoobar。初期コマンドが必要です。これはオプションのパラメータ有する--fooかかるオプション（もちろん、他のパラメータとすることができません）の値を、値がない場合、デフォルトでになりdefaultます。また--bar、必須の値を取るオプションのパラメーターもあります。最後に--baz、値が許可されていないフラグを取ることができます。ああ、これらのパラメーターはどのような順序でもかまいません。

つまり、次のようになります。

foobar <command> [--foo [<fooval>]] [--bar <barval>] [--baz]

これが解決策です：

@ECHO OFF
SETLOCAL
REM FooBar parameter demo
REM By Garret Wilson

SET CMD=%~1

IF "%CMD%" == "" (
  GOTO usage
)
SET FOO=
SET DEFAULT_FOO=default
SET BAR=
SET BAZ=

SHIFT
:args
SET PARAM=%~1
SET ARG=%~2
IF "%PARAM%" == "--foo" (
  SHIFT
  IF NOT "%ARG%" == "" (
    IF NOT "%ARG:~0,2%" == "--" (
      SET FOO=%ARG%
      SHIFT
    ) ELSE (
      SET FOO=%DEFAULT_FOO%
    )
  ) ELSE (
    SET FOO=%DEFAULT_FOO%
  )
) ELSE IF "%PARAM%" == "--bar" (
  SHIFT
  IF NOT "%ARG%" == "" (
    SET BAR=%ARG%
    SHIFT
  ) ELSE (
    ECHO Missing bar value. 1>&2
    ECHO:
    GOTO usage
  )
) ELSE IF "%PARAM%" == "--baz" (
  SHIFT
  SET BAZ=true
) ELSE IF "%PARAM%" == "" (
  GOTO endargs
) ELSE (
  ECHO Unrecognized option %1. 1>&2
  ECHO:
  GOTO usage
)
GOTO args
:endargs

ECHO Command: %CMD%
IF NOT "%FOO%" == "" (
  ECHO Foo: %FOO%
)
IF NOT "%BAR%" == "" (
  ECHO Bar: %BAR%
)
IF "%BAZ%" == "true" (
  ECHO Baz
)

REM TODO do something with FOO, BAR, and/or BAZ
GOTO :eof

:usage
ECHO FooBar
ECHO Usage: foobar ^<command^> [--foo [^<fooval^>]] [--bar ^<barval^>] [--baz]
EXIT /B 1

• SETLOCAL変数が呼び出し環境にエスケープしないように使用します。
• SET FOO=誰かが呼び出し環境でそれらを定義した場合に備えて、変数などを初期化することを忘れないでください。
• %~1引用符を削除するために使用します。
• 使用IF "%ARG%" == ""していないIF [%ARG%] == []ため[と]スペースで終わる値を持つすべての意志を再生できません。
• ブロックSHIFT内であっても、IFなどの現在の引数は解析%~1時に決定されるため、更新されませんIF。あなたは使用することができます%~1し、%~2内部のIFブロックが、あなたが持っていたので、それが混乱することでしょうSHIFT。SHIFT明確にするためにブロックの最後にを配置することもできますが、それによって失われたり、人々を混乱させたりする可能性があります。したがって、「キャプチャ」%~1し%~1、ブロックの外側が最良のようです。
• 別のパラメーターのオプション値の代わりにパラメーターを使用したくないので、を確認する必要がありIF NOT "%ARG:~0,2%" == "--"ます。
• パラメータの1つSHIFTを使用する場合にのみ注意してください。
• 重複したコードSET FOO=%DEFAULT_FOO%は残念ですが、代わりIF "%FOO%" == "" SET FOO=%DEFAULT_FOO%にIF NOT "%ARG%" == ""ブロックの外側を追加することもできます。ただし、これはまだIF "%PARAM%" == "--foo"ブロック内にある%FOO%ため、ブロックに入る前に値が評価および設定されているため、パラメーターが存在することと値が欠落していることの両方を検出することはできません。--foo%FOO%
• ECHO Missing bar value. 1>&2がエラーメッセージをstderrに送信することに注意してください。
• Windowsバッチファイルに空白行が必要ですか？使用するECHO:か、バリエーションの1つです。

新しいバッチファイル（例：openclass.bat）を作成し、ファイルに次の行を書き込みます。

java %~n1

次に、system32フォルダーにバッチファイルを配置し、Javaクラスファイルに移動して、右クリックし、[プロパティ]、[アプリケーションから開く...]を選択し、バッチファイルを見つけて選択します。

わたしにはできる。

PS：Javaクラスを閉じるときにcmdウィンドウを閉じる方法が見つかりません。今のところ...

簡単な解決策（質問が古い場合でも）

Test1.bat

echo off
echo "Batch started"
set arg1=%1
echo "arg1 is %arg1%"
echo on
pause

CallTest1.bat

call "C:\Temp\Test1.bat" pass123

出力

YourLocalPath>call "C:\Temp\test.bat" pass123

YourLocalPath>echo off
"Batch started"
"arg1 is pass123"

YourLocalPath>pause
Press any key to continue . . .

YourLocalPathは現在のディレクトリパスです。

シンプルにするために、コマンドparamを変数に格納し、変数を比較に使用します。

書くのは簡単なだけでなく、メンテナンスも簡単なので、後で他の人やあなたがスクリプトを長期間読んだ場合、理解とメンテナンスが簡単になります。

コードをインラインで作成するには：他の回答を参照してください。

ループを使用するには、すべての引数を取得し、純粋なバッチで取得します。

Obs：なしで使用する場合：?*&<>

@echo off && setlocal EnableDelayedExpansion

 for %%Z in (%*)do set "_arg_=%%Z" && set/a "_cnt+=1+0" && (
     call set "_arg_[!_cnt!]=!_arg_!" && for /l %%l in (!_cnt! 1 !_cnt!
     )do echo/ The argument n:%%l is: !_arg_[%%l]!
 )

goto :eof 

あなたのコードはそれが必要とする引数番号で何かをする準備ができています...

 @echo off && setlocal EnableDelayedExpansion

 for %%Z in (%*)do set "_arg_=%%Z" && set/a "_cnt+=1+0" && call set "_arg_[!_cnt!]=!_arg_!"
 )

 fake-command /u !_arg_[1]! /p !_arg_[2]! > test-log.txt