区切り文字に基づいて文字列を文字列の配列に分割します

84

入力文字列を区切り文字に基づいて文字列の配列に分割するDelphi関数を見つけようとしています。私はグーグルでたくさん見つけました、しかしすべてが彼ら自身の問題を持っているようで、私はそれらのどれも動かすことができませんでした。

：のような文字列"word:doc,txt,docx"を「：」に基づいて配列に分割する必要があり ます。結果はになります ['word', 'doc,txt,docx']。

誰かが彼らが働くことを知っている機能を持っていますか？

ありがとうございました

delphi  string  split  delimiter 
— ライアン
ソース

回答:

86

TStrings.DelimitedTextプロパティを使用して文字列を分割できます

このサンプルを確認してください

program Project28;

{$APPTYPE CONSOLE}

uses
  Classes,
  SysUtils;

procedure Split(Delimiter: Char; Str: string; ListOfStrings: TStrings) ;
begin
   ListOfStrings.Clear;
   ListOfStrings.Delimiter       := Delimiter;
   ListOfStrings.StrictDelimiter := True; // Requires D2006 or newer.
   ListOfStrings.DelimitedText   := Str;
end;


var
   OutPutList: TStringList;
begin
   OutPutList := TStringList.Create;
   try
     Split(':', 'word:doc,txt,docx', OutPutList) ;
     Writeln(OutPutList.Text);
     Readln;
   finally
     OutPutList.Free;
   end;
end.

更新

の説明については、このリンクを参照してくださいStrictDelimiter。

— RRUZ
ソース
22
残念ながら、多くの「古い」Delphiバージョン（これがどのリリースで修正されたかはわかりません）にはバグがあり、スペース文字が常に区切り文字として使用されるという影響があります。だから、これは慎重に扱ってください！
— レオ
16
ええ。StrictDelimiterをtrueに設定する必要があります。また、お使いのバージョンのDelphiでStrictDelimiterプロパティが使用できない場合は、この手法を使用しないでください。しかし、そうであれば、これは非常に便利です。
— メイソンウィーラー
3
これはバグではなく、D1またはD2に戻ったときの（煩わしい）設計上の決定でした。CommaTextは、フィールドをスペースで囲み、引用符で囲むことになっています。入力のスペースが含まれるフィールドを二重引用符で囲んでいる場合、結果は正しいです。
— Gerry Coll 2010
1
私のペットのおしっこの1つは、人々が変数/パラメーター名にタイプインジケーターを不必要に入れたときです。Pascalは強く型付けされています-これは（指の運動の種類の）冗長な型付けであり、この場合のように、型インジケーターが間違っていると混乱を招きます：ArrayOfStringsは配列ではありません（したがって、提起された質問に答えることさえできません） 。
— Deltics 2010
6
この回答に賛成するすべての人にとって、質問で指定されているように、配列が生成されないことに注意してください。不完全な要件仕様はこの業界では大きな問題であり、述べられた要件を無視し、求められていないものを提供することは別の大きな問題です。どちらかを承認することは、単に悪い習慣を助長するだけです。;）
— Deltics 2010
67

Split関数を設計する必要はありません。すでに存在しますClasses.ExtractStrings。以下を参照してください。

次のように使用します。

program Project1;

{$APPTYPE CONSOLE}

uses
  Classes;

var
  List: TStrings;
begin
  List := TStringList.Create;
  try
    ExtractStrings([':'], [], PChar('word:doc,txt,docx'), List);
    WriteLn(List.Text);
    ReadLn;
  finally
    List.Free;
  end;
end.

そして、質問に完全に答えるために; List次の要素を使用して目的の配列を表します。

List[0] = 'word'
List[1] = 'doc,txt,docx'
— NGLN
ソース
14
ExtractStringsは非常に柔軟性がありません。 "キャリッジリターン、改行文字、および引用符（シングルまたはダブル）は常に区切り文字として扱われます。"; および「注：ExtractStringsは空の文字列をリストに追加しません。」
— awmross 2013年
問題は、split関数を設計することではなく、TStringsオブジェクトの必要性です。そして、柔軟性がない（@awmross）言及があるため、私はフランクのソリューションを
— Wolf
50

を使用できますStrUtils.SplitString。

function SplitString(const S, Delimiters: string): TStringDynArray;

ドキュメントからの説明：

文字列を、指定された区切り文字で区切られたさまざまな部分に分割します。

SplitStringは、文字列を、指定された区切り文字で区切られたさまざまな部分に分割します。Sは分割する文字列です。 区切り文字は、区切り文字として定義された文字を含む文字列です。

SplitStringは、元の文字列の分割部分を含むSystem.Types.TStringDynArray型の文字列の配列を返します。

— アレックス
ソース
3
うーん、私のバージョンのDelphi 2010にはありません（XMLDocと（Indyユニット）IdStringsにはSplitStringルーチンがありますが、どちらも投稿者が望むことを行わず、XMLDocルーチンはとにかくユニットインターフェイスを介して公開されません）。
— Deltics
3
関数SplitString（const S、区切り文字：文字列）：TStringDynArray; StrUtils.pasで定義
— alex
StrUtils.pasファイルをインクルードできません（存在する場合でも）。
— Truthseeker 2012
これは、文字列を「配列」に分割する例です。
— bvj 2014
最良のことは、これが他の回答の文字区切り文字ではなく文字列区切り文字を受け入れることです。
— user30478 2018
42

Delphi XE3で導入されたSysUtils.TStringHelper.Split関数の使用：

var
  MyString: String;
  Splitted: TArray<String>;
begin
  MyString := 'word:doc,txt,docx';
  Splitted := MyString.Split([':']);
end.

これにより、指定された区切り文字を含む文字列が文字列の配列に分割されます。

— LU RD
ソース
18

私はいつもこれに似たものを使います：

Uses
   StrUtils, Classes;

Var
  Str, Delimiter : String;
begin
  // Str is the input string, Delimiter is the delimiter
  With TStringList.Create Do
  try
    Text := ReplaceText(S,Delim,#13#10);

    // From here on and until "finally", your desired result strings are
    // in strings[0].. strings[Count-1)

  finally
    Free; //Clean everything up, and liberate your memory ;-)
  end;

end;
— フランク
ソース
2
古いDelphiバージョンのユーザーに最適なソリューション。
— オオカミ
C ++ Builder 6ユーザー：対応する関数はStrutils::AnsiReplaceText
— Wolf
驚くほどシンプル。Delphi 7での作業：list.Text := AnsiReplaceStr(source, delimiter, #13#10);。
— AlainD 2017年
デルファイ6でSysUtils.StringReplaceを使用することができます
— pyfyc
14

Mefが提供するExplode（）関数に似ていますが、いくつかの違いがあります（そのうちの1つはバグ修正と考えています）。

  type
    TArrayOfString = array of String;


  function SplitString(const aSeparator, aString: String; aMax: Integer = 0): TArrayOfString;
  var
    i, strt, cnt: Integer;
    sepLen: Integer;

    procedure AddString(aEnd: Integer = -1);
    var
      endPos: Integer;
    begin
      if (aEnd = -1) then
        endPos := i
      else
        endPos := aEnd + 1;

      if (strt < endPos) then
        result[cnt] := Copy(aString, strt, endPos - strt)
      else
        result[cnt] := '';

      Inc(cnt);
    end;

  begin
    if (aString = '') or (aMax < 0) then
    begin
      SetLength(result, 0);
      EXIT;
    end;

    if (aSeparator = '') then
    begin
      SetLength(result, 1);
      result[0] := aString;
      EXIT;
    end;

    sepLen := Length(aSeparator);
    SetLength(result, (Length(aString) div sepLen) + 1);

    i     := 1;
    strt  := i;
    cnt   := 0;
    while (i <= (Length(aString)- sepLen + 1)) do
    begin
      if (aString[i] = aSeparator[1]) then
        if (Copy(aString, i, sepLen) = aSeparator) then
        begin
          AddString;

          if (cnt = aMax) then
          begin
            SetLength(result, cnt);
            EXIT;
          end;

          Inc(i, sepLen - 1);
          strt := i + 1;
        end;

      Inc(i);
    end;

    AddString(Length(aString));

    SetLength(result, cnt);
  end;

違い：

  1. aMaxパラメーターは、返される文字列の数を制限します
  2. 入力文字列が区切り文字で終了している場合、名目上の「空の」最終文字列が存在すると見なされます

例：

SplitString(':', 'abc') returns      :    result[0]  = abc

SplitString(':', 'a:b:c:') returns   :    result[0]  = a
                                          result[1]  = b
                                          result[2]  = c
                                          result[3]  = <empty string>

SplitString(':', 'a:b:c:', 2) returns:    result[0]  = a
                                          result[1]  = b

バグ修正を検討しているのは、末尾の区切り文字と概念的な「空の最終要素」です。

また、提案したメモリ割り当ての変更を改良して組み込みました（入力文字列には最大で50％の区切り文字が含まれる可能性があると誤って提案しましたが、もちろん100％の区切り文字列で構成され、空の要素の配列が生成される可能性があります！）

— Deltics
ソース
7

Explodeは非常に高速な関数であり、ソースアルゴリズムはTStringsコンポーネントから取得します。explodeの次のテストを使用します：データの134217733バイトを爆発させ、19173962要素を取得し、作業時間：2984ミリ秒。

爆縮は非常に低速な機能ですが、簡単に書けます。

{ ****************************************************************************** }
{  Explode/Implode (String <> String array)                                      }
{ ****************************************************************************** }
function Explode(S: String; Delimiter: Char): Strings; overload;
var I, C: Integer; P, P1: PChar;
begin
    SetLength(Result, 0);
    if Length(S) = 0 then Exit;
    P:=PChar(S+Delimiter); C:=0;
    while P^ <> #0 do begin
       P1:=P;
       while (P^ <> Delimiter) do P:=CharNext(P);
       Inc(C);
       while P^ in [#1..' '] do P:=CharNext(P);
       if P^ = Delimiter then begin
          repeat
           P:=CharNext(P);
          until not (P^ in [#1..' ']);
       end;
    end;
    SetLength(Result, C);
    P:=PChar(S+Delimiter); I:=-1;
    while P^ <> #0 do begin
       P1:=P;
       while (P^ <> Delimiter) do P:=CharNext(P);
       Inc(I); SetString(Result[I], P1, P-P1);
       while P^ in [#1..' '] do P:=CharNext(P);
       if P^ = Delimiter then begin
          repeat
           P:=CharNext(P);
          until not (P^ in [#1..' ']);
       end;
    end;
end;

function Explode(S: String; Delimiter: Char; Index: Integer): String; overload;
var I: Integer; P, P1: PChar;
begin
    if Length(S) = 0 then Exit;
    P:=PChar(S+Delimiter); I:=1;
    while P^ <> #0 do begin
       P1:=P;
       while (P^ <> Delimiter) do P:=CharNext(P);
        SetString(Result, P1, P-P1);
        if (I <> Index) then Inc(I) else begin
           SetString(Result, P1, P-P1); Exit;
        end;
       while P^ in [#1..' '] do P:=CharNext(P);
       if P^ = Delimiter then begin
          repeat
           P:=CharNext(P);
          until not (P^ in [#1..' ']);
       end;
    end;
end;

function Implode(S: Strings; Delimiter: Char): String;
var iCount: Integer;
begin
     Result:='';
     if (Length(S) = 0) then Exit;
     for iCount:=0 to Length(S)-1 do
     Result:=Result+S[iCount]+Delimiter;
     System.Delete(Result, Length(Result), 1);
end;
— Delphi 7
ソース
3
これはコンパイルされません：Stringsタイプではありません。
— NGLN 2016年
7 
var  
    su  : string;        // What we want split
    si  : TStringList;   // Result of splitting
    Delimiter : string;
    ...
    Delimiter := ';';
    si.Text := ReplaceStr(su, Delimiter, #13#10);

siリストの行には、分割された文字列が含まれます。

— Ihor Konovalenko
ソース
6

文字列のTArrayを返す独自の関数を作成できます。

function mySplit(input: string): TArray<string>;
var
  delimiterSet: array [0 .. 0] of char; 
     // split works with char array, not a single char
begin
  delimiterSet[0] := '&'; // some character
  result := input.Split(delimiterSet);
end;
— bob_saginowski
ソース
5

ここでは、標準機能として、他の多くのプログラミング言語で提供されて爆発する機能の実装は次のとおりです。

type 
  TStringDynArray = array of String;

function Explode(const Separator, S: string; Limit: Integer = 0): TStringDynArray; 
var 
  SepLen: Integer; 
  F, P: PChar; 
  ALen, Index: Integer; 
begin 
  SetLength(Result, 0); 
  if (S = '') or (Limit < 0) then Exit; 
  if Separator = '' then 
  begin 
    SetLength(Result, 1); 
    Result[0] := S; 
    Exit; 
  end; 
  SepLen := Length(Separator); 
  ALen := Limit; 
  SetLength(Result, ALen); 

  Index := 0; 
  P := PChar(S); 
  while P^ <> #0 do 
  begin 
    F := P; 
    P := AnsiStrPos(P, PChar(Separator)); 
    if (P = nil) or ((Limit > 0) and (Index = Limit - 1)) then P := StrEnd(F); 
    if Index >= ALen then 
    begin 
      Inc(ALen, 5); 
      SetLength(Result, ALen); 
    end; 
    SetString(Result[Index], F, P - F); 
    Inc(Index); 
    if P^ <> #0 then Inc(P, SepLen); 
  end; 
  if Index < ALen then SetLength(Result, Index); 
end;

使用例：

var
  res: TStringDynArray;
begin
  res := Explode(':', yourString);
— レオ
ソース
2
結果の長さを管理/予測するために、このコードには奇妙で潜在的に非常に非効率的な選択肢がいくつかあります。結果の配列を段階的に増やすことにより、メモリの再割り当てと断片化の可能性が高まります。より効率的なのは、初期の長さを可能な限り大きく設定することです。つまり、入力文字列が50％の区切り文字列で構成されていると仮定します= Length（S）div（2 * Length（Separator）。次に、実際の数に設定します。完了し
— たら
また、Limitパラメーターの目的についても説明していません。実際には、部分文字列の検出を入力文字列の最初の「制限」文字数に制限しているように見えるときに、返される部分文字列の最大数を設定することを直感的に期待していました。これを行う必要がある場合は、必要な部分文字列のCopy（）に対してExplode（）を操作するだけでよいため、これは無意味に思えます。Limitを使用して部分文字列の最大数を設定すると、はるかに便利です。
— Deltics 2010
@Deltics：これが高度に最適化された機能であると誰も主張しておらず、誰もそれを求めていなかったので、私はあなたの不満を幾分理解していません。しかし、多分あなたは...それが必要であるかどうかにかかわらず場合、すべてを最適化する選手の一人です
— レオ
1
私は、不必要に非効率的なコードを記述せず、後で最適化することを心配するような人です。これは、コードを詳細に分析して、ごくわずかな最適化の可能性を見つける場合ではありませんでした。それは、単純に明白で簡単に対処できる非効率性でした。代わりに、事前に割り当てて後で簡単に切り捨てることができる連続メモリの増分増加です。
— Deltics 2010
また@Mef：それは苦情ではなく、コメント、観察でした。しかし、もっと重要なことに、あなたのコードには、私がバグと見なすものも含まれていました（説明については私の代替案を参照してください）。
— Deltics 2010
5

特定の区切り文字で区切られた文字列のリンクリストを返すこの関数を作成しました。モジュールなしの純粋な無料Pascal。

Program split_f;

type
    PTItem = ^TItem;
    TItem = record
        str : string;
        next : PTItem;
    end;

var
    s : string;
    strs : PTItem;

procedure split(str : string;delim : char;var list : PTItem);
var
    i : integer;
    buff : PTItem;
begin
    new(list);
    buff:= list;
    buff^.str:='';
    buff^.next:=nil;

    for i:=1 to length(str) do begin
        if (str[i] = delim) then begin
            new(buff^.next);
            buff:=buff^.next;
            buff^.str := '';
            buff^.next := nil;
        end
        else
        buff^.str:= buff^.str+str[i];
    end;
end;

procedure print(var list:PTItem);
var
    buff : PTItem;
begin
    buff := list;
    while buff<>nil do begin
        writeln(buff^.str);
        buff:= buff^.next;
    end;
end;

begin

    s := 'Hi;how;are;you?';

    split(s, ';', strs);
    print(strs);


end.
— AlešOskarKocur
ソース
3

Jediコードライブラリは、既存のテキストの追加と置換の両方が可能な、組み込みのSplit関数を備えた拡張StringListを提供します。また、参照カウントインターフェイスも提供します。したがって、これは、SplitStringsがなく、指定された区切り文字のみを使用するようにストックTStringListを注意深く少し面倒にカスタマイズすることなく、古いDelphiバージョンでも使用できます。

たとえば、次のような行のテキストファイルを指定すると、次のようにDog 5 4 7解析できます。

var slF, slR: IJclStringList; ai: TList<integer>; s: string; i: integer;
    action: procedure(const Name: string; Const Data: array of integer);

slF := TJclStringList.Create; slF.LoadFromFile('some.txt');
slR := TJclStringList.Create;
for s in slF do begin
    slR.Split(s, ' ', true);
    ai := TList<Integer>.Create;
    try
       for i := 1 to slR.Count - 1 do
           ai.Add(StrToInt(slR[i]));
       action(slR[0], ai.ToArray);
    finally ai.Free; end;
end;

http://wiki.delphi-jedi.org/wiki/JCL_Help:IJclStringList.Split @ string @ string @ Boolean

— アリオク '
ソース
3

これはあなたの問題を解決します

interface
   TArrayStr = Array Of string;

implementation

function SplitString(Text: String): TArrayStr;
var
   intIdx: Integer;
   intIdxOutput: Integer;
const
   Delimiter = ';';
begin
   intIdxOutput := 0;
   SetLength(Result, 1);
   Result[0] := ''; 

   for intIdx := 1 to Length(Text) do
   begin
      if Text[intIdx] = Delimiter then
      begin
         intIdxOutput := intIdxOutput + 1;
         SetLength(Result, Length(Result) + 1);
      end
      else
         Result[intIdxOutput] := Result[intIdxOutput] + Text[intIdx];
   end;
end;
— デニス
ソース
コードの機能について説明していただけますか？ありがとう
— Paco 2015年
渡された文字列を実行して区切り文字constを探します。見つからない場合は、配列の現在の位置と連結します。見つかった場合は、動的配列の次の位置にジャンプします
— Dennis
1

分割のための私のお気に入りの関数：

procedure splitString(delim: char; s: string; ListOfStrings: TStrings);
var temp: string;
    i: integer;
begin
   ListOfStrings.Clear;
   for i:=1 to length(s) do
    begin
      if s[i] = delim then
        begin
          ListOfStrings.add(temp);
          temp := '';
        end
      else
        begin
          temp := temp + s[i];
          if i=length(s) then
             ListOfStrings.add(temp);
        end;
    end;
    ListOfStrings.add(temp);
end;
— ジョン・ボー
ソース
1
あなたの関数で最後の要素が欠落していました
— alijunior 2018年
1
ListOfStrings.add(temp);最後のアイテムを追加するには、ループの後に追加する必要があります。
— rnso
メモをありがとう、elseブロックのコードを編集しました。
— JohnBoe19年
0

*

//Basic functionality of a TStringList solves this:


uses Classes  //TStringList 
    ,types    //TStringDynArray
    ,SysUtils //StringReplace()
    ;

....

 //--------------------------------------------------------------------------
 function _SplitString(const s:string; const delimiter:Char):TStringDynArray;
  var sl:TStringList;
      i:integer;
  begin
  sl:=TStringList.Create;

  //separete delimited items by sLineBreak;TStringlist will do the job:
  sl.Text:=StringReplace(s,delimiter,sLineBreak,[rfReplaceAll]);

  //return the splitted string as an array:
  setlength(Result,sl.count);
  for i:=0 to sl.Count-1
   do Result[i]:=sl[i];

  sl.Free;
  end;



//To split a FileName (last item will be the pure filename itselfs):

 function _SplitPath(const fn:TFileName):TStringDynArray;
  begin
  result:=_SplitString(fn,'\');
  end;

*

— デビッド・ウルブリッヒ
ソース
0

NGLG回答のベースhttps://stackoverflow.com/a/8811242/6619626次の関数を使用できます。

type
OurArrayStr=array of string;

function SplitString(DelimeterChars:char;Str:string):OurArrayStr;
var
seg: TStringList;
i:integer;
ret:OurArrayStr;
begin
    seg := TStringList.Create;
    ExtractStrings([DelimeterChars],[], PChar(Str), seg);
    for i:=0 to seg.Count-1 do
    begin
         SetLength(ret,length(ret)+1);
         ret[length(ret)-1]:=seg.Strings[i];
    end;
    SplitString:=ret;
    seg.Free;
end;

すべてのDelphiバージョンで動作します。

— レザ・ムサビ
ソース
0

delphi 2010の場合、独自の分割関数を作成する必要があります。 

function Split(const Texto, Delimitador: string): TStringArray;
var
  i: integer;
  Len: integer;
  PosStart: integer;
  PosDel: integer;
  TempText:string;
begin
  i := 0;
  SetLength(Result, 1);
  Len := Length(Delimitador);
  PosStart := 1;
  PosDel := Pos(Delimitador, Texto);
  TempText:=  Texto;
  while PosDel > 0 do
    begin
      Result[i] := Copy(TempText, PosStart, PosDel - PosStart);
      PosStart := PosDel + Len;
      TempText:=Copy(TempText, PosStart, Length(TempText));
      PosDel := Pos(Delimitador, TempText);
      PosStart := 1;
      inc(i);
      SetLength(Result, i + 1);
    end;
  Result[i] := Copy(TempText, PosStart, Length(TempText));
end;

あなたはそれをそのように参照することができます

type
  TStringArray = array of string;
var Temp2:TStringArray;
Temp1="hello:world";
Temp2=Split(Temp1,':')
— user3609960
ソース
0 
procedure SplitCSV(S:STRING;out SL:TStringList);
var c,commatext:string;
  a,b,up:integer;
begin
   c:=s.Replace(' ','<SPACE>');   //curate spaces

   //first ocurrence of "
   a:=pos('"',c);
   b:=pos('"',c,a+1);
   if (a>0) and (b>0) then
   begin
     commatext:=commatext+copy(c,0,a-1);
     commatext:=commatext+copy(c,a,b-a+1).Replace(',','<COMMA>');   //curate commas
     up:=b+1;
   end
   else
     commatext:=c;

   //while continue discovering "
   while (a>0) and (b>0) do
   begin
     a:=Pos('"',c,b+1);
     b:=pos('"',c,a+1);
     if (a>0) and (b>0) then
     begin
       commatext:=commatext+copy(c,up,a-up);
       commatext:=commatext+copy(c,a,b-a+1).Replace(',','<COMMA>'); //curate commas
       up:=b+1;
     end;
   end;
   //last piece of text end  
   if up<c.Length then
     commatext:=commatext+copy(c,up,c.Length-up+1);

   //split text using CommaText
   sl.CommaText:=commatext;

   sl.Text:=sl.Text.Replace('<COMMA>',',');   //curate commas
   sl.Text:=sl.Text.Replace('<SPACE>',' ');   //curate spaces
end;
— ネリボッキ
ソース
ソリューションを明確かつ簡潔に説明する回答は、コードのみの回答よりもはるかに役立ちます。
— MartynA
0 
interface

uses
  Classes;

type
  TStringArray = array of string;

  TUtilStr = class
    class function Split(const AValue: string; const ADelimiter: Char = ';'; const AQuoteChar: Char = '"'): TStringArray; static;
  end;


implementation

{ TUtilStr }

class function TUtilStr.Split(const AValue: string; const ADelimiter: Char; const AQuoteChar: Char): TStringArray;
var
  LSplited: TStringList;
  LText: string;
  LIndex: Integer;
begin
  LSplited := TStringList.Create;
  try
    LSplited.StrictDelimiter := True;
    LSplited.Delimiter := ADelimiter;
    LSplited.QuoteChar := AQuoteChar;
    LSplited.DelimitedText := AValue;

    SetLength(Result, LSplited.Count);
    for LIndex := 0 to LSplited.Count - 1 do
    begin
      Result[LIndex] := LSplited[LIndex];
    end;
  finally
    LSplited.Free;
  end;
end;

end.
— marvinbraga
ソース
弊社のサイトを使用することにより、あなたは弊社のクッキーポリシーおよびプライバシーポリシーを読み、理解したものとみなされます。
Licensed under cc by-sa 3.0 with attribution required.