変数が設定されているかどうかをテストする必要があります。私はいくつかの技術を試してみたが、彼らはいつでも失敗するようで%1、このような場合のように引用符で囲まれて%1います"c:\some path with spaces"。

IF NOT %1 GOTO MyLabel // This is invalid syntax
IF "%1" == "" GOTO MyLabel // Works unless %1 has double quotes which fatally kills bat execution
IF %1 == GOTO MyLabel // Gives an unexpected GOTO error.

このサイトによると、これらはサポートされているIF構文タイプです。だから、私はそれを行う方法がわかりません。

IF [NOT] ERRORLEVEL number command
IF [NOT] string1==string2 command
IF [NOT] EXIST filename command

引用符の代わりに角括弧を使用します。

IF [%1] == [] GOTO MyLabel

括弧は安全ではありません。角括弧のみを使用してください。

以下を使用できます。

IF "%~1" == "" GOTO MyLabel

引用符の外側のセットを削除します。一般的に、変数にスペースが含まれている場合でも機能するため、角かっこを使用するよりも信頼性の高い方法です。

最良の半解決策の1つは、%1変数にコピーしてから、delayedExpとして遅延拡張を使用することです。コンテンツに対して常に安全です。

set "param1=%~1"
setlocal EnableDelayedExpansion
if "!param1!"=="" ( echo it is empty )
rem ... or use the DEFINED keyword now
if defined param1 echo There is something

これの利点は、param1の処理が絶対に安全であることです。

そして、param1の設定は多くの場合に機能します。

test.bat hello"this is"a"test
test.bat you^&me

しかし、それでも次のような奇妙な内容で失敗します

test.bat ^&"&

存在について100％正しい答えを得ることができる

%1空かどうかを検出しますが、一部のコンテンツではコンテンツをフェッチできません。
これは、空%1と空の区別にも役立ち""ます。コマンド
の機能を使用してCALL、バッチファイルを中止せずに失敗します。

@echo off
setlocal EnableDelayedExpansion
set "arg1="
call set "arg1=%%1"

if defined arg1 goto :arg_exists

set "arg1=#"
call set "arg1=%%1"
if "!arg1!" EQU "#" (
    echo arg1 exists, but can't assigned to a variable
    REM Try to fetch it a second time without quotes
    (call set arg1=%%1)
    goto :arg_exists
)

echo arg1 is missing
exit /b

:arg_exists
echo arg1 exists, perhaps the content is '!arg1!'

コンテンツを取得するために100％防弾になりたい場合は、最も奇妙なコマンドラインパラメーターを受け取る方法をお読みください。

IF /？から：

コマンド拡張が有効になっている場合、IFは次のように変更されます。

IF [/I] string1 compare-op string2 command
IF CMDEXTVERSION number command
IF DEFINED variable command

……

DEFINED条件は、環境変数名を受け取り、環境変数が定義されている場合にtrueを返すことを除いて、EXISTSと同じように機能します。

残念ながら、私は自分で書く必要があった現在の回答にコメントしたり投票したりするのに十分な評判がありません。

もともとOPの質問は「パラメータ」ではなく「変数」と言っていましたが、これは特に、空白の変数をテストする方法を検索するためのgoogleの一番のリンクだったため、非常に混乱しました。私の元の回答以来、Stephanは正しい用語を使用するように元の質問を編集しましたが、特にGoogleが変数のためにここでも人々を送信している場合は、私の回答を削除するのではなく、混乱を解消するためにそのままにしておくことにしました。

％1は変数ではありません！これはコマンドラインパラメータです。

非常に重要な区別。変数ではなくコマンドラインパラメータを参照する単一のパーセント記号とその後に番号を付けます。

変数は、setコマンドを使用して設定され、2つのパーセント記号を使用して呼び出されます（1つは前と1つ後）。たとえば、％myvar％

空の変数をテストするには、「if not defined」構文を使用します（変数を明示的に指定するコマンドにはパーセント記号は必要ありません）。次に例を示します。

set myvar1=foo  
if not defined myvar1 echo You won't see this because %myvar1% is defined.  
if not defined myvar2 echo You will see this because %myvar2% isn't defined.

（コマンドラインパラメーターをテストする場合は、jamesdlinの回答を参照することをお勧めします。）

「IF DEFINED変数コマンド」を使用して、バッチファイル内の変数をテストします。

ただし、バッチパラメータをテストする場合は、以下のコードを試して、トリッキーな入力（「1 2」やab ^> cdなど）を避けてください。

set tmp="%1"
if "%tmp:"=.%"==".." (
    echo empty
) else (
    echo not empty
)

以下のコードでテストしましたが、問題ありません。

@echo off

set varEmpty=
if not "%varEmpty%"=="" (
    echo varEmpty is not empty
) else (
    echo varEmpty is empty
)
set varNotEmpty=hasValue
if not "%varNotEmpty%"=="" (
    echo varNotEmpty is not empty
) else (
    echo varNotEmpty is empty
)

私は通常これを使用します：

IF "%1."=="." GOTO MyLabel

％1が空の場合、IFは "。"を比較します。「。」に これはtrueと評価されます。

有効なスクリプトが多数あるため、ここでの回答に基づいてこの小さなバッチスクリプトを作成しました。同じ形式に従っている限り、これに追加してかまいません。

REM Parameter-testing

Setlocal EnableDelayedExpansion EnableExtensions

IF NOT "%~1"=="" (echo Percent Tilde 1 failed with quotes) ELSE (echo SUCCESS)
IF NOT [%~1]==[] (echo Percent Tilde 1 failed with brackets) ELSE (echo SUCCESS)
IF NOT  "%1"=="" (echo Quotes one failed) ELSE (echo SUCCESS)
IF NOT [%1]==[] (echo Brackets one failed) ELSE (echo SUCCESS)
IF NOT "%1."=="." (echo Appended dot quotes one failed) ELSE (echo SUCCESS)
IF NOT [%1.]==[.] (echo Appended dot brackets one failed) ELSE (echo SUCCESS)

pause

空の文字列はdouble-quotes/のペアです。""長さをテストするだけです。

set ARG=%1
if not defined ARG goto nomore

set CHAR=%ARG:~2,1%
if defined CHAR goto goon

次に、それが2文字であることをテストしdouble-quotesます。

if ^%ARG:~1,1% == ^" if ^%ARG:~0,1% == ^" goto blank
::else
goto goon

これがあなたが遊ぶことができるバッチスクリプトです。空の文字列を正しくキャッチすると思います。

これは単なる例であり、スクリプトに従って上記の2（または3？）ステップをカスタマイズする必要があるだけです。

@echo off
if not "%OS%"=="Windows_NT" goto EOF
:: I guess we need enableExtensions, CMIIW
setLocal enableExtensions
set i=0
set script=%0

:LOOP
set /a i=%i%+1

set A1=%1
if not defined A1 goto nomore

:: Assumption:
:: Empty string is (exactly) a pair of double-quotes ("")

:: Step out if str length is more than 2
set C3=%A1:~2,1%
if defined C3 goto goon

:: Check the first and second char for double-quotes
:: Any characters will do fine since we test it *literally*
if ^%A1:~1,1% == ^" if ^%A1:~0,1% == ^" goto blank
goto goon

:goon
echo.args[%i%]: [%1]
shift
goto LOOP

:blank
echo.args[%i%]: [%1] is empty string
shift
goto LOOP

:nomore
echo.
echo.command line:
echo.%script% %*

:EOF

この拷問のテスト結果：

.test.bat :: ""  ">"""bl" " "< "">"  (")(") "" :: ""-"  " "( )"">\>" ""
args[1]: [::]
args[2]: [""] is empty string
args[3]: [">"""bl" "]
args[4]: ["< "">"]
args[5]: [(")(")]
args[6]: [""] is empty string
args[7]: [::]
args[8]: [""-"  "]
args[9]: ["( )"">\>"]
args[10]: [""] is empty string

command line:
.test.bat :: ""  ">"""bl" " "< "">"  (")(") "" :: ""-"  " "( )"">\>" ""

使用できます

if defined (variable) echo That's defined!
if not defined (variable) echo Nope. Undefined.

スクリプト1：

入力（ "Remove Quotes.cmd" "This is a Test"）

@ECHO OFF

REM Set "string" variable to "first" command line parameter
SET STRING=%1

REM Remove Quotes [Only Remove Quotes if NOT Null]
IF DEFINED STRING SET STRING=%STRING:"=%

REM IF %1 [or String] is NULL GOTO MyLabel
IF NOT DEFINED STRING GOTO MyLabel


REM   OR   IF "." equals "." GOTO MyLabel
IF "%STRING%." == "." GOTO MyLabel

REM GOTO End of File
GOTO :EOF

:MyLabel
ECHO Welcome!

PAUSE

出力（なし、％1は空白、空、またはNULLではありませんでした）：

上記のスクリプトを使用して、パラメーターなしで（ "Remove Quotes.cmd"）を実行します1

出力（％1は空白、空、またはNULL）：

Welcome!

Press any key to continue . . .

注：変数を IF ( ) ELSE ( )ステートメント、「IF」ステートメントを終了するまでを定義できません（「遅延変数拡張」が有効になっていない限り、有効になったら、代わりに感嘆符「！」を使用してください。パーセント「％」記号}。

例えば：

スクリプト2：

入力（ "Remove Quotes.cmd" "This is a Test"）

@ECHO OFF

SETLOCAL EnableDelayedExpansion

SET STRING=%0
IF 1==1 (
  SET STRING=%1
  ECHO String in IF Statement='%STRING%'
  ECHO String in IF Statement [delayed expansion]='!STRING!'
) 

ECHO String out of IF Statement='%STRING%'

REM Remove Quotes [Only Remove Quotes if NOT Null]
IF DEFINED STRING SET STRING=%STRING:"=%

ECHO String without Quotes=%STRING% 

REM IF %1 is NULL GOTO MyLabel
IF NOT DEFINED STRING GOTO MyLabel

REM GOTO End of File
GOTO :EOF

:MyLabel
ECHO Welcome!

ENDLOCAL
PAUSE

出力：

C:\Users\Test>"C:\Users\Test\Documents\Batch Files\Remove Quotes.cmd" "This is a Test"  
String in IF Statement='"C:\Users\Test\Documents\Batch Files\Remove Quotes.cmd"'  
String in IF Statement [delayed expansion]='"This is a Test"'  
String out of IF Statement='"This is a Test"'  
String without Quotes=This is a Test  

C:\Users\Test>  

注：文字列内の引用符も削除されます。

例（スクリプト1または2を使用）：C：\ Users \ Test \ Documents \ Batch Files> "Remove Quotes.cmd" "This is" a "Test"

出力（スクリプト2）：

String in IF Statement='"C:\Users\Test\Documents\Batch Files\Remove Quotes.cmd"'  
String in IF Statement [delayed expansion]='"This is "a" Test"'  
String out of IF Statement='"This is "a" Test"'  
String without Quotes=This is a Test  

スクリプト2でパラメーターなしで実行（ "Remove Quotes.cmd"）します。

出力：

Welcome!

Press any key to continue . . .

まとめると：

set str=%~1
if not defined str ( echo Empty string )

％1が ""または "または空の場合、このコードは"空の文字列 "を出力します。現在正しくない受け入れられた回答に追加しました。

私はネットで多くの答えを出して多くの問題を抱えてきました。ほとんどはほとんどのことで機能しますが、常にそれぞれを壊すコーナーケースがあります。
引用符がある場合は機能しない可能性があります。引用符がない場合は破損する可能性があります。varにスペースがある場合は構文エラー、一部は環境変数ではなくパラメータでのみ機能し、他の手法では空を許可します「定義済み」として渡す引用符のセット。一部のトリッキーな引用符では、チェーンを作成できません。else後から。

これが私が満足している解決策です、それがうまくいかないコーナーケースを見つけたら私に知らせてください。

:ifSet
if "%~1"=="" (Exit /B 1) else (Exit /B 0)

あなたのスクリプトまたはそれ自身のの中にそのサブルーチンが.batあればうまくいくはずです。
したがって、（疑似で）書き込みたい場合：

if (var)
then something
else somethingElse

あなたは書ける：

(Call :ifSet %var% && (
    Echo something
)) || (
    Echo something else
)

それは私のすべてのテストでうまくいきました：

(Call :ifSet && ECHO y) || ECHO n
(Call :ifSet a && ECHO y) || ECHO n
(Call :ifSet "" && ECHO y) || ECHO n
(Call :ifSet "a" && ECHO y) || ECHO n
(Call :ifSet "a a" && ECHO y) || ECHO n

Echo'd n、y、n、y、y

その他の例：

• 確認したいだけifですか？Call :ifSet %var% && Echo set
• そうでない場合でも（他の人だけ）？ Call :ifSet %var% || Echo set
• 渡された引数を確認します。正常に動作します。Call :ifSet %1 && Echo set
• スクリプト/重複コードを詰まらせたくなかったので、それを独自のものに入れifSet.batますか？問題ない：((Call ifSet.bat %var%) && Echo set) || (Echo not set)

を使用して 空の文字列をチェックする場合は "の代わりに

@echo off
SET a=
SET b=Hello
IF !%a%! == !! echo String a is empty
IF !%b%! == !! echo String b is empty

私は1か月足らずで入ってきました（8年前に尋ねられた場合でも）...彼/彼女がバッチファイルを超えて移動したことを願っています。;-)私はいつもこれをやっていました。しかし、最終的な目標が何かはわかりません。私のように怠け者の場合、私のgo.batはそのようなもので機能します。（下記参照）しかし、1は、入力を直接コマンドとして使用している場合、OPのコマンドが無効になる可能性があります。つまり、

"C:/Users/Me"

は無効なコマンドです（または、別のドライブにいた場合に使用されていました）。2つの部分に分割する必要があります。

C:
cd /Users/Me

そして、2、「定義済み」または「未定義」はどういう意味ですか？ギゴ。デフォルトを使用してエラーをキャッチします。入力がキャッチされない場合は、ヘルプ（またはデフォルトのコマンド）にドロップされます。したがって、入力がないことはエラーではありません。入力にcdして、エラーがある場合はエラーをキャッチできます。（さて、go "downloads（1つの括弧のみ）を使用すると、DOSによってキャッチされます。（厳しい！））

cd "%1"
if %errorlevel% neq 0 goto :error

そして、3、引用符は、パスではなく、コマンドではなく必要です。つまり、

"cd C:\Users" 

別のドライブを使用しているのでない限り、それは悪かった（または昔は慣れていた）。

cd "\Users" 

機能しています。

cd "\Users\Dr Whos infinite storage space"

パスにスペースがある場合に機能します。

@REM go.bat
@REM The @ sigh prevents echo on the current command
@REM The echo on/off turns on/off the echo command. Turn on for debugging
@REM You can't see this.
@echo off
if "help" == "%1" goto :help

if "c" == "%1" C:
if "c" == "%1" goto :done

if "d" == "%1" D:
if "d" == "%1" goto :done

if "home"=="%1" %homedrive%
if "home"=="%1" cd %homepath%
if "home"=="%1" if %errorlevel% neq 0 goto :error
if "home"=="%1" goto :done

if "docs" == "%1" goto :docs

@REM goto :help
echo Default command
cd %1
if %errorlevel% neq 0 goto :error
goto :done

:help
echo "Type go and a code for a location/directory
echo For example
echo go D
echo will change disks (D:)
echo go home
echo will change directories to the users home directory (%homepath%)
echo go pictures
echo will change directories to %homepath%\pictures
echo Notes
echo @ sigh prevents echo on the current command
echo The echo on/off turns on/off the echo command. Turn on for debugging
echo Paths (only) with folder names with spaces need to be inclosed in         quotes (not the ommand)
goto :done

:docs
echo executing "%homedrive%%homepath%\Documents"
%homedrive%
cd "%homepath%\Documents"\test error\
if %errorlevel% neq 0 goto :error
goto :done

:error
echo Error: Input (%1 %2 %3 %4 %5 %6 %7 %8 %9) or command is invalid
echo go help for help
goto :done

:done