不規則な穴タイプの解決

私は最近、タイプホールとプルーフのパターンマッチングを組み合わせることで、HaskellでAgdaのような素晴らしいエクスペリエンスが提供されることを発見しました。例えば：

{-# LANGUAGE
    DataKinds, PolyKinds, TypeFamilies, 
    UndecidableInstances, GADTs, TypeOperators #-}

data (==) :: k -> k -> * where
    Refl :: x == x

sym :: a == b -> b == a
sym Refl = Refl 

data Nat = Zero | Succ Nat

data SNat :: Nat -> * where
    SZero :: SNat Zero
    SSucc :: SNat n -> SNat (Succ n)

type family a + b where
    Zero   + b = b
    Succ a + b = Succ (a + b)

addAssoc :: SNat a -> SNat b -> SNat c -> (a + (b + c)) == ((a + b) + c)
addAssoc SZero b c = Refl
addAssoc (SSucc a) b c = case addAssoc a b c of Refl -> Refl

addComm :: SNat a -> SNat b -> (a + b) == (b + a)
addComm SZero SZero = Refl
addComm (SSucc a) SZero = case addComm a SZero of Refl -> Refl
addComm SZero (SSucc b) = case addComm SZero b of Refl -> Refl
addComm sa@(SSucc a) sb@(SSucc b) =
    case addComm a sb of
        Refl -> case addComm b sa of
            Refl -> case addComm a b of
                Refl -> Refl 

本当に素晴らしいのは、Refl -> exp構造の右側をタイプホールに置き換えることができ、ホールターゲットタイプが証明で更新さrewriteれることです。Agda のフォームとほぼ同じです。

ただし、ホールが更新に失敗することがあります。

(+.) :: SNat a -> SNat b -> SNat (a + b)
SZero   +. b = b
SSucc a +. b = SSucc (a +. b)
infixl 5 +.

type family a * b where
    Zero   * b = Zero
    Succ a * b = b + (a * b)

(*.) :: SNat a -> SNat b -> SNat (a * b)
SZero   *. b = SZero
SSucc a *. b = b +. (a *. b)
infixl 6 *.

mulDistL :: SNat a -> SNat b -> SNat c -> (a * (b + c)) == ((a * b) + (a * c))
mulDistL SZero b c = Refl
mulDistL (SSucc a) b c = 
    case sym $ addAssoc b (a *. b) (c +. a *. c) of
        -- At this point the target type is
        -- ((b + c) + (n * (b + c))) == (b + ((n * b) + (c + (n * c))))
        -- The next step would be to update the RHS of the equivalence:
        Refl -> case addAssoc (a *. b) c (a *. c) of
            Refl -> _ -- but the type of this hole remains unchanged...

また、ターゲットタイプが必ずしもプルーフ内に並ぶとは限りませんが、Agdaから全体を貼り付けても、問題はありません。

mulDistL' :: SNat a -> SNat b -> SNat c -> (a * (b + c)) == ((a * b) + (a * c))
mulDistL' SZero b c = Refl
mulDistL' (SSucc a) b c = case
    (sym $ addAssoc b (a *. b) (c +. a *. c),
    addAssoc (a *. b) c (a *. c),
    addComm (a *. b) c,
    sym $ addAssoc c (a *. b) (a *. c),
    addAssoc b c (a *. b +. a *. c),
    mulDistL' a b c
    ) of (Refl, Refl, Refl, Refl, Refl, Refl) -> Refl

これがなぜ起こるのか（または私がどのようにして堅牢な方法で証明の書き換えを行うことができるか）のアイデアはありますか？

そのようなすべての可能な値を生成したい場合は、提供された境界または指定された境界を使用して、それを行う関数を作成できます。

型レベルのChurch Numeralsなどを使用して、これらの作成を強制することは非常に可能ですが、たいていの場合、必要とするもの/必要なものに対しては、あまりにも多くの作業です。

これはあなたが望むものではないかもしれません（つまり、「z = 5-x-yなので（x、y）だけを使用することを除いて」）が、有効にするために型レベルに何らかの強制的な制限を課すよりも理にかなっています値。

これは、値が実行時に決定されるために発生します。これは、実行時に入力されたものに応じて値の変換を引き起こす可能性があるため、穴はすでに更新されていると想定しています。