Inno Setup：以前にインストールしたバージョンを自動的にアンインストールする方法は？

InnoSetupを使用してインストーラーを作成しています。

インストーラーに、以前にインストールしたバージョンを上書きするのではなく、自動的にアンインストールしてもらいたい。どうやってやるの？

あなたはAPPID（あなたが使用すなわち値与えられ、レジストリからアンインストール文字列を読むことができるはずAppIDで[Setup]-section）。これは、下見つけることができるSoftware\Microsoft\Windows\CurrentVersion\Uninstall\{AppId}\（いずれかであるHKLMか、HKCUその両方をチェックするので、最高の）どこ{AppId}に使用した実際の値に置換する必要があります。UninstallStringまたはのQuietUninstallString値を探し、Exec関数を使用してInitializeSetup()イベント関数から実行します。

更新：これを指摘したすべてのコメント提供者に感謝し[Run]、{uninstallexe}-セクションエントリを使用して機能しない代替ソリューションを削除しました！

私は以下を使用しました。それが最も簡単な方法かどうかはわかりませんが、機能します。

これは{#emit SetupSetting("AppId")}、Inno SetupPreprocessorに依存するものを使用します。それを使用しない場合は、アプリIDを直接カットアンドペーストしてください。

[Code]

{ ///////////////////////////////////////////////////////////////////// }
function GetUninstallString(): String;
var
  sUnInstPath: String;
  sUnInstallString: String;
begin
  sUnInstPath := ExpandConstant('Software\Microsoft\Windows\CurrentVersion\Uninstall\{#emit SetupSetting("AppId")}_is1');
  sUnInstallString := '';
  if not RegQueryStringValue(HKLM, sUnInstPath, 'UninstallString', sUnInstallString) then
    RegQueryStringValue(HKCU, sUnInstPath, 'UninstallString', sUnInstallString);
  Result := sUnInstallString;
end;


{ ///////////////////////////////////////////////////////////////////// }
function IsUpgrade(): Boolean;
begin
  Result := (GetUninstallString() <> '');
end;


{ ///////////////////////////////////////////////////////////////////// }
function UnInstallOldVersion(): Integer;
var
  sUnInstallString: String;
  iResultCode: Integer;
begin
{ Return Values: }
{ 1 - uninstall string is empty }
{ 2 - error executing the UnInstallString }
{ 3 - successfully executed the UnInstallString }

  { default return value }
  Result := 0;

  { get the uninstall string of the old app }
  sUnInstallString := GetUninstallString();
  if sUnInstallString <> '' then begin
    sUnInstallString := RemoveQuotes(sUnInstallString);
    if Exec(sUnInstallString, '/SILENT /NORESTART /SUPPRESSMSGBOXES','', SW_HIDE, ewWaitUntilTerminated, iResultCode) then
      Result := 3
    else
      Result := 2;
  end else
    Result := 1;
end;

{ ///////////////////////////////////////////////////////////////////// }
procedure CurStepChanged(CurStep: TSetupStep);
begin
  if (CurStep=ssInstall) then
  begin
    if (IsUpgrade()) then
    begin
      UnInstallOldVersion();
    end;
  end;
end;

代替案

このブログ投稿「バージョン比較用のInnoSetupスクリプトサンプル」も参照してください。これはさらに一歩進んで、以前にインストールされたバージョンのバージョン番号を読み取り、そのバージョン番号を現在のインストールパッケージのバージョン番号と比較します。

「古いアイコンを削除したいだけ」の場合（アイコンが変更/更新されたため）、次のように使用できます。

; attempt to remove previous versions' icons
[InstallDelete]
Type: filesandordirs; Name: {group}\*;

これは「インストールの開始時に」実行されるため、基本的に古いアイコンが削除され、これが完全に完了した後も新しいアイコンがインストールされます。

これは、「何かが変更された場合に備えて」アイコンごとにインストールするたびに行います（とにかくすべてが再インストールされます）。

Inno Setupを使用する場合、そのバージョンが別のインストーラープログラムによってインストールされていない限り、以前のバージョンをアンインストールする理由はありません。それ以外の場合、アップグレードは自動的に処理されます。

クレイグマックイーンによって提供された答えは完全に実行可能です。しかし、私はそれらのコメントを追加します：

• {#emit SetupSetting("AppId")}私はちょうど私のApp IDを追加するように、コードは、私のために動作しません。
• アンインストーラーによって削除されたAppData /フォルダーにINI構成ファイルが保存されており、新しいバージョンをインストールするときにそれを消去したくないため、アンインストールプログラムを実行したくありませんでした。そこで、Craig McQueenから提供されたコードを少し変更して、プログラムがインストールされているディレクトリを、そのパスを取得した後に削除しました。

したがって、Craig McQueenのコードに関して、変更点は次のとおりです。

• InstallLocationキーの代わりにキーを取得しますUninstallString。
• のDelTree代わりに関数を使用してくださいExec(sUnInstallString, ...)

GetUninstallString()上記の提案を使用して内部のアンインストールを強制し、CurStepChanged()ディスクキャッシュの問題がある場合は、アンインストーラexeが削除されるのをアンインストール後に実際にしばらく待機する関連ソリューションについて、以下を参照してください。

inno-setupでのディスクキャッシュの問題？

[コード]セクションでアンインストーラーを実行できます。既存のアンインストーラーへのパスを取得する方法を理解する必要があります。アプリをインストールするときに簡単にするために、アンインストーラーを含むフォルダーを指すレジストリ文字列値を追加し、InitializeWizardコールバックでアンインストーラーを実行するだけです。

Inno Setupアンインストーラー名はすべてuninsnnn.exeの形式であることに注意してください。コードでは、それを考慮する必要があります。

@Crain Mc-Queenコードを編集しました。別のプロジェクトで変更する必要がないため、このコードの方が優れていると思います。

[Code]
function GetNumber(var temp: String): Integer;
var
  part: String;
  pos1: Integer;
begin
  if Length(temp) = 0 then
  begin
    Result := -1;
    Exit;
  end;
    pos1 := Pos('.', temp);
    if (pos1 = 0) then
    begin
      Result := StrToInt(temp);
    temp := '';
    end
    else
    begin
    part := Copy(temp, 1, pos1 - 1);
      temp := Copy(temp, pos1 + 1, Length(temp));
      Result := StrToInt(part);
    end;
end;

function CompareInner(var temp1, temp2: String): Integer;
var
  num1, num2: Integer;
begin
    num1 := GetNumber(temp1);
  num2 := GetNumber(temp2);
  if (num1 = -1) or (num2 = -1) then
  begin
    Result := 0;
    Exit;
  end;
      if (num1 > num2) then
      begin
        Result := 1;
      end
      else if (num1 < num2) then
      begin
        Result := -1;
      end
      else
      begin
        Result := CompareInner(temp1, temp2);
      end;
end;

function CompareVersion(str1, str2: String): Integer;
var
  temp1, temp2: String;
begin
    temp1 := str1;
    temp2 := str2;
    Result := CompareInner(temp1, temp2);
end;

function InitializeSetup(): Boolean;
var
  oldVersion: String;
  uninstaller: String;
  ErrorCode: Integer;
  vCurID      :String;
  vCurAppName :String;
begin
  vCurID:= '{#SetupSetting("AppId")}';
  vCurAppName:= '{#SetupSetting("AppName")}';
  //remove first "{" of ID
  vCurID:= Copy(vCurID, 2, Length(vCurID) - 1);
  //
  if RegKeyExists(HKEY_LOCAL_MACHINE,
    'SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\' + vCurID + '_is1') then
  begin
    RegQueryStringValue(HKEY_LOCAL_MACHINE,
      'SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\' + vCurID + '_is1',
      'DisplayVersion', oldVersion);
    if (CompareVersion(oldVersion, '{#SetupSetting("AppVersion")}') < 0) then      
    begin
      if MsgBox('Version ' + oldVersion + ' of ' + vCurAppName + ' is already installed. Continue to use this old version?',
        mbConfirmation, MB_YESNO) = IDYES then
      begin
        Result := False;
      end
      else
      begin
          RegQueryStringValue(HKEY_LOCAL_MACHINE,
            'SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\' + vCurID + '_is1',
            'UninstallString', uninstaller);
          ShellExec('runas', uninstaller, '/SILENT', '', SW_HIDE, ewWaitUntilTerminated, ErrorCode);
          Result := True;
      end;
    end
    else
    begin
      MsgBox('Version ' + oldVersion + ' of ' + vCurAppName + ' is already installed. This installer will exit.',
        mbInformation, MB_OK);
      Result := False;
    end;
  end
  else
  begin
    Result := True;
  end;
end;

私は何かが足りないに違いない。新しい古いインストールの削除が発生する前に、ファイルがターゲットディレクトリにコピーされます。 次に、アンインストーラーがそれらを削除し、ディレクトリを削除します。

[Run]セクションではなく、[UninstallRun]を使用してください。実際、[実行]の下のプログラムはインストール後に実行されるため、インストール直後にプログラムがアンインストールされます：-| 代わりに、[UninstallRun]セクションはインストール前に評価されます。

このリンクをたどってください：http：//news.jrsoftware.org/news/innosetup/msg55323.html

InitializeSetup（）関数では、ユーザープロンプトの後に「MSIEXEC / x {プログラムID}」を呼び出して、古い古いバージョンをアンインストールできます。