Windowsのコマンドプロンプトで特定のディレクトリのファイル/サブフォルダーを削除する方法

たとえば、%pathtofolder%フォルダのフルパスであることを明確にするため、という変数があります。

このディレクトリ内のすべてのファイルとサブフォルダを削除しますが、ディレクトリ自体は削除しません。

ただし、「このファイル/フォルダーはすでに使用されています」などのエラーが発生する可能性があります...その場合、続行してそのファイル/フォルダーをスキップする必要があります。

このためのコマンドはありますか？

このシェルスクリプトを使用して、C:\Temp source内のフォルダーとファイルをクリーンアップできます。

del /q "C:\Temp\*"
FOR /D %%p IN ("C:\Temp\*.*") DO rmdir "%%p" /s /q

上記のコマンドを含むバッチファイル（たとえば、delete.bat）を作成します。delete.batファイルがある場所に移動し、次のコマンドを実行します：delete.bat

rmdir 仕事で一番好きなコマンドです。それはサブフォルダーを持つ巨大なファイルやフォルダーを削除するために動作します。バックアップは作成されないため、このコマンドを実行する前にファイルを安全にコピーしたことを確認してください。

RMDIR "FOLDERNAME" /S /Q

これにより、フォルダーとすべてのファイルおよびサブフォルダーがサイレントに削除されます。

私が考えることができる最も簡単な解決策は、ディレクトリ全体を削除することです

RD /S /Q folderPath

次に、このディレクトリをもう一度作成します。

MD folderPath

これにより、フォルダーとファイルが削除され、フォルダーが残ります。

pushd "%pathtofolder%" && (rd /s /q "%pathtofolder%" 2>nul & popd)

@ECHO OFF

SET THEDIR=path-to-folder

Echo Deleting all files from %THEDIR%
DEL "%THEDIR%\*" /F /Q /A

Echo Deleting all folders from %THEDIR%
FOR /F "eol=| delims=" %%I in ('dir "%THEDIR%\*" /AD /B 2^>nul') do rd /Q /S "%THEDIR%\%%I"
@ECHO Folder deleted.

EXIT

...指定されたディレクトリの下にあるすべてのファイルとフォルダを削除しますが、ディレクトリ自体は削除しません。

CD [Your_Folder]
RMDIR /S /Q .

エラーメッセージが表示され、RMDIRコマンドは現在のフォルダーにアクセスできないため、削除できません。

更新：

この有用なコメントから（Moritz Bothに感謝）、&&間に追加してもかまいRMDIRません。そのため、CDコマンドが失敗した場合（たとえば、ディレクトリ名の入力ミス）は実行されません。

CD [Your_Folder] && RMDIR /S /Q .

Windowsのコマンドラインリファレンス：

/ S：ディレクトリツリー（すべてのファイルを含む、指定されたディレクトリとそのすべてのサブディレクトリ）を削除します。

/ Q：クワイエットモードを指定します。ディレクトリツリーを削除するときに確認を求めません。（/ qは/ sが指定されている場合にのみ機能することに注意してください。）

RDはREMOVE Directoryの略です。

/ S：フォルダー自体に加えて、すべてのファイルとサブフォルダーを削除します。これを使用して、フォルダーツリー全体を削除します。

/ Q：静か-YN確認を表示しません

例：

RD /S /Q C:/folder_path/here

私はPowershellを使用しています

Remove-Item c:\scripts\* -recurse

フォルダー自体ではなく、フォルダーの内容が削除されます。

2018年6月1日に掲載さと回答のいずれも、例外とによって投稿単一のコマンドラインのfoxidrive、実際にすべてのファイルとすべてのフォルダ/ディレクトリを削除しません%PathToFolder%。それが、フォルダーのすべてのファイルとサブフォルダーを削除する非常にシンプルな単一のコマンドラインでさらに1つの回答を投稿する理由であり、DELを使用して他のすべての回答が2018-06-01に投稿された理由を説明するより複雑なソリューションを持つバッチファイルも同様ですそしてFORとRDは、完全にフォルダをクリーンアップできませんでした。

もちろん、バッチファイルでも使用できる単純な単一のコマンドラインソリューション：

pushd "%PathToFolder%" 2>nul && ( rd /Q /S "%PathToFolder%" 2>nul & popd )

このコマンドラインには、3つのコマンドが順番に実行されます。

最初のコマンドPUSHDはスタック上の現在のディレクトリパスをプッシュし、次に%PathToFolder%コマンドプロセスを実行するための現在のディレクトリを作成します。

コマンド拡張はデフォルトで有効になっているため、これはデフォルトでUNCパスでも機能します。この場合、PUSHDは指定されたネットワークリソースを指す一時的なドライブ文字を作成し、新しく定義されたドライブ文字を使用して現在のドライブとディレクトリを変更します。

指定されたディレクトリがまったく存在しない場合、PUSHDはSTDERRを処理するために次のエラーメッセージを出力します。

指定されたパスが見つかりません。

このエラーメッセージは2>nul、デバイスNULにリダイレクトすることで抑制されます。

次のコマンドRDは、現在のコマンドプロセスの現在のディレクトリを指定されたディレクトリに変更できた場合、つまり指定されたディレクトリが存在する場合にのみ実行されます。

オプション付きのコマンドRDは、指定されたディレクトリーに隠し属性または読み取り専用属性が設定されたファイルまたはフォルダーが含まれている場合でも、すべてのサブディレクトリーとともに静かにディレクトリー/Qを/S削除します。システム属性は、ファイルまたはフォルダーの削除を決して防ぎません。

削除されないもの：

1. 実行中のプロセスの現在のディレクトリとして使用されるフォルダ。実行中のプロセスの現在のディレクトリとしてフォルダが使用されている場合、そのようなフォルダへのフォルダツリー全体を削除することはできません。

2. 実行中のアプリケーション/プロセスによって開かれている間のファイルの削除を防ぐために、ファイルを開くときにファイルアクセス許可が設定されている実行中のプロセスによって現在開かれているファイル。このような開かれたファイルは、開かれたファイルへのフォルダツリー全体の削除も防ぎます。

3. 現在のユーザーがファイル/フォルダーを削除するために必要な（NTFS）権限を持っていないファイル/フォルダー。これにより、このファイル/フォルダーへのフォルダーツリーも削除されなくなります。

フォルダーを削除しない最初の理由は、このコマンドラインで、フォルダー自体ではなく、指定したフォルダーのすべてのファイルとサブフォルダーを削除するために使用されます。このフォルダーは、コマンドプロセスを実行するために一時的に現在のディレクトリになり、フォルダー自体の削除が防止されます。もちろんこれにより、コマンドRDによってエラーメッセージが出力されます。

別のプロセスによって使用されているため、プロセスはファイルにアクセスできません。

ファイルはここでは間違った用語です。実際には、フォルダーは別のプロセス（コマンドRDを実行した現在のコマンドプロセス）によって使用されているためです。まあ、実際には、フォルダーはファイルシステムの特別なファイルで、このエラーメッセージを説明するファイル属性ディレクトリがあります。しかし、ファイルシステム管理に深く入り込みたくありません。

このエラーメッセージは、上記の3つの理由により発生する可能性のある他のすべてのエラーメッセージと同様に2>nul、ハンドルSTDERRからデバイスNULにリダイレクトすることで抑制されます。

3番目のコマンドPOPDは、コマンドRDの終了値とは関係なく実行されます。

POPDは、PUSHDによってプッシュされたディレクトリパスをスタックからポップし、コマンドプロセスを実行するための現在のディレクトリをこのディレクトリに変更します。つまり、初期の現在のディレクトリを復元します。POPDはによって作成された一時的なドライブ文字を削除PUSHD UNCフォルダパスの場合を。

注： 初期の現在のディレクトリが、削除するディレクトリのサブディレクトリで、存在しないものである場合、POPDは警告なしに初期の現在のディレクトリを復元できません。この特別なケースで%PathToFolder%は、現在のディレクトリのままです。したがって、のサブディレクトリからではなく、上記のコマンドラインを実行することをお勧めします%PathToFolder%。

もう一つの興味深い事実： 私はまた、ローカルディレクトリを共有することにより、UNCパスを使用してコマンドラインを試みたC:\Temp共有名とTempし、UNCパス使用して\\%COMPUTERNAME%\Temp\CleanTest環境変数に割り当てられたPathToFolderコマンドラインを実行している上、現在のディレクトリが共有ローカルのサブディレクトリがある場合は、Windows 7上をフォルダは、UNCパスを使用してアクセス、すなわちC:\Temp\CleanTest\Subfolder1、Subfolder1によって削除されるRD、次のPOPDは、製造中に静かに失敗しC:\Temp\CleanTest\Subfolder1、再度、その結果、現在のディレクトリZ:\CleanTest実行コマンド処理のための現在のディレクトリとして残りを。したがって、この非常に特殊なケースでは、一時ディレクトリは、現在のディレクトリが次のように変更されるまで残ります。cd /D %SystemRoot%実際に存在するローカルディレクトリに。残念ながら、POPDは、初期の現在のディレクトリの復元に失敗した場合、0より大きい値で終了せず、POPDの終了コードだけを使用してこの非常に特殊なエラー状態を検出できません。ただし、UNCパスは通常ローカルファイルやフォルダーへのアクセスには使用されないため、この非常に特殊なエラーが発生することはないと考えられます。

使用するコマンドをさらに理解するには、コマンドプロンプトウィンドウを開き、そこで次のコマンドを実行し、各コマンドに表示されるヘルプを非常に注意深く読んでください。

• pushd /?
• popd /?
• rd /?

Windowsバッチファイルを使用して複数のコマンドを含む1行で、ここ&&で&使用される演算子について説明します。

次は、私たちがコマンドを使用して、バッチファイルソリューションに見てみましょうDELを内のファイルを削除する%PathToFolder%と、FORとRDの中にサブフォルダを削除します%PathToFolder%。

@echo off
setlocal EnableExtensions DisableDelayedExpansion

rem Clean the folder for temporary files if environment variable
rem PathToFolder is not defined already outside this batch file.
if not defined PathToFolder set "PathToFolder=%TEMP%"

rem Remove all double quotes from folder path.
set "PathToFolder=%PathToFolder:"=%"

rem Consisted the folder path only of double quotes?
if not defined PathToFolder goto EndCleanFolder

rem Remove a backslash at end of folder path.
if "%PathToFolder:~-1%" == "\" set "PathToFolder=%PathToFolder:~0,-1%"

rem Consisted folder path only of a backslash (with one or more double quotes)?
if not defined PathToFolder goto EndCleanFolder

rem Delete all files in specified folder including files with hidden
rem or read-only attribute set, except the files currently opened by
rem a running process which prevents deletion of the file while being
rem opened by the application, or on which the current user has not
rem the required permissions to delete the file.
del /A /F /Q "%PathToFolder%\*" >nul 2>nul

rem Delete all subfolders in specified folder including those with hidden
rem attribute set recursive with all files and subfolders, except folders
rem being the current directory of any running process which prevents the
rem deletion of the folder and all folders above, folders containing a file
rem opened by the application which prevents deletion of the file and the
rem entire folder structure to this file, or on which the current user has
rem not the required permissions to delete a folder or file in folder tree
rem to delete.
for /F "eol=| delims=" %%I in ('dir "%PathToFolder%\*" /AD /B 2^>nul') do rd /Q /S "%PathToFolder%\%%I" 2>nul

:EndCleanFolder
endlocal

バッチファイルは、最初に、PathToFolder二重引用符のないフォルダーパスと最後にバックスラッシュのない環境変数が実際に定義されていることを確認します。最後のバックスラッシュは問題にはなりませんが、PathToFolderバッチファイルの実行中にの値が他の文字列と連結されるため、フォルダーパスの二重引用符は問題になる可能性があります。

重要なのは次の2行です。

del /A /F /Q "%PathToFolder%\*" >nul 2>nul
for /F "eol=| delims=" %%I in ('dir "%PathToFolder%\*" /AD /B 2^>nul') do rd /Q /S "%PathToFolder%\%%I" 2>nul

コマンドDELは、指定されたディレクトリ内のすべてのファイルを削除するために使用されます。

• オプション/Aは、DELがオプションを使用せずに無視する隠し属性を持つファイルを含む実際にすべてのファイルを処理するために必要/Aです。
• このオプション/Fは、読み取り専用属性が設定されているファイルを強制的に削除するために必要です。
• このオプション /Qは、複数のファイルを本当に削除する必要がある場合に、ユーザーにプロンプ​​トを表示せずに複数のファイルを静かに削除するために必要です。
• >nulSTDOUTを処理するために記述されたファイル名の出力を、ファイルが現在開かれているか、ユーザーがファイルを削除する権限を持っていないため削除できないデバイスNULにリダイレクトする必要があります。
• 2>nul削除できない各ファイルのエラーメッセージ出力をハンドルSTDERRからデバイスNULにリダイレクトする必要があります。

コマンドFORおよびRDは、指定されたディレクトリー内のすべてのサブディレクトリーを削除するために使用されます。ただし、この場合for /D、FORは非表示の属性が設定されたサブディレクトリを無視するため、使用されません。そのため、for /Fを使用してバックグラウンドで開始された別のコマンドプロセスで次のコマンドラインを実行します%ComSpec% /c。

dir "%PathToFolder%\*" /AD /B 2>nul

dirは/B、attributeのあるディレクトリエントリD、つまり、パスのない隠し属性のような他の属性に依存しない、指定されたディレクトリ内のすべてのサブディレクトリの名前のため、ベアフォーマットで出力します。ハンドルSTDERRからディレクトリが見つからない2>nul場合にDIRが出力するエラーメッセージをデバイスNULにリダイレクトするために使用されます。

リダイレクト演算子には>、キャレット文字でエスケープする必要があります^に、FORの Windowsコマンド・インタプリタは、コマンドを実行する前に、このコマンドラインを処理するときにリテラル文字として解釈されるコマンドラインFOR埋め込ま実行するdir開始した別のコマンド・プロセスにコマンドラインをバックグラウンドで。

FORは、開始されたコマンドプロセスのSTDOUTを処理するために書き込まれたキャプチャされた出力を処理します。これは、パスなしのサブディレクトリの名前であり、二重引用符で囲まれていません。

オプション付きのFORは、オプション付きのDIRが空行を出力/Fしないため、ここでは発生しない空行を無視します。/B

FORは、デフォルトの行末文字であるセミコロンで始まる行も無視します。ディレクトリ名はセミコロンで始めることができます。そのためeol=|、縦棒文字を行末文字として定義するために使用されます。これは、ディレクトリまたはファイルがその名前に持つことはできません。

FORは、スペースと水平タブを区切り文字として使用して行を部分文字列に分割し、最初のスペース/タブ区切りの文字列のみを指定されたループ変数に割り当てますI。ディレクトリ名には1つ以上のスペースを含めることができるため、この分割動作はここでは不要です。したがってdelims=、区切り記号の空のリストを定義して、行分割動作を無効にし、ループ変数に割り当てられます。これはI、常に完全なディレクトリ名です。

コマンドFORは、パスなしで各ディレクトリ名に対してコマンドRDを実行します。これが、RDコマンドラインでフォルダーパスをもう一度指定する必要がある理由であり、サブフォルダー名と連結されます。

使用するコマンドとその機能を理解するには、コマンドプロンプトウィンドウを開いて次のコマンドを実行し、各コマンドに対して表示されるすべてのヘルプページをよく読みます。

• del /?
• dir /?
• echo /?
• endlocal /?
• for /?
• goto /?
• if /?
• rd /?
• rem /?
• set /?
• setlocal /?

使用メモ帳はテキストドキュメントを作成してコピーする/これを貼り付けます。

rmdir /s/q "%temp%"
mkdir "%temp%"

[ 名前を付けて保存]とファイル名を選択：

delete_temp.bat

ファイルの種類：すべてのファイルを保存してSaveボタンをクリックします。

あらゆる種類のアカウント（管理者または標準ユーザー）で機能します。実行するだけ！

この例では一時変数を使用していますが、他の変数も使用できます。PS：Windows OSのみ！

ファイルを削除するには：

del PATH_TO_FILE

すべてのファイルを含むフォルダーを削除するには：

rmdir /s /q PATH_TO_FOLDER

特定のフォルダーからすべてのファイルを削除する（フォルダー自体を削除するのではない）ことは少し複雑です。del /s *.*フォルダを削除することはできませんが、すべてのサブフォルダからファイルを削除します。したがって、2つのコマンドが必要です。

del /q PATH_TO_FOLDER\*.*
for /d %i in (PATH_TO_FOLDER\*.*) do @rmdir /s /q "%i"

次のコマンドを使用して、すべてのコンテンツと親フォルダー自体を削除することにより、これを実行できます。

RMDIR [/S] [/Q] [drive:]path            

私はこれらのアプローチのいくつかを試しましたが、どれも正しく機能しませんでした。

私は、サイトのWindowsコマンドラインでこの2段階のアプローチを見つけました。

forfiles /P %pathtofolder% /M * /C "cmd /c if @isdir==FALSE del @file"

forfiles /P %pathtofolder%  /M * /C "cmd /c if @isdir==TRUE rmdir /S /Q @file"

それは私が必要とし、OPによって指定されたとおりに機能しました。

@ECHO OFF
rem next line removes all files in temp folder
DEL /A /F /Q /S "%temp%\*.*"
rem next line cleans up the folder's content
FOR /D %%p IN ("%temp%\*.*") DO RD "%%p" /S /Q

使用する：

del %pathtofolder%\*.*   /s /f  /q

これにより%pathtofolder%、読み取り専用ファイルを含む、のすべてのファイルとサブフォルダが削除され、確認のプロンプトは表示されません。