要約すれば
これを行うにはいくつかの方法があり、そのほとんどが提案されていますが、私はそれらを2つの追加の方法で要約すると思いました。
- ディレクトリごとのvimrc - Vimは正しいディレクトリで起動しなければならないという欠点を持っている：あなたのプロジェクトがである場合
~/project1、あなたが持っている~/project1/.vim.customと行うcd ~ ; vim project1/file.c、カスタム設定が見つかりません。
- Modelines-非常に効果的ですが、すべてのファイルに追加する必要があるという欠点があります（そして、新しいファイルに追加することを忘れないでください）
- ディレクトリ固有の自動コマンド-これは非常に効果的です
- ファイル内の特定のヘッダーをスキャンします（以下を参照）-これは、さまざまな会社や明確に名前が付けられたプロジェクトで働いている過去に私が最も使用したものです
- ファイルを開いたときにチェックされるディレクトリごとのvimrc（以下を参照）。特にプロジェクトコードがすべて1つの場所にある場合は、実装が非常に簡単です。
ヘッダーのスキャン
多くの組織では、すべてのソースファイルの上部に標準のヘッダー（著作権表示やプロジェクト名など）があります。この場合、Vimにファイルの最初の（たとえば）10行を自動的にスキャンしてキーワードを探すようにさせることができます。見つかった場合は、設定を変更できます。私が使用するフォーム（他の多くのことを行う）よりも単純になるようにこれを変更しましたが、~/.vim/after/filetype.vim（まだ持っていない場合）を作成し、次のようなものを追加します：
au FileType * call <SID>ConfigureFiletypes(expand("<amatch>"))
" List of file types to customise
let s:GROUPNAMETypes = ['c', 'cpp', 'vhdl', 'c.doxygen']
func! <SID>CheckForGROUPNAMECode()
" Check if any of the first ten lines contain "GROUPNAME".
" Read the first ten lines into a variable
let header = getline(1)
for i in range(2, 10)
let header = header . getline(i)
endfor
if header =~ '\<GROUPNAME\>'
" Change the status line to make it clear which
" group we're using
setlocal statusline=%<%f\ (GROUPNAME)\ %h%m%r%=%-14.(%l,%c%V%)\ %P
" Do other customisation here
setlocal et
" etc
endif
endfunc
func! <SID>ConfigureFiletypes(filetype)
if index(s:GROUPNAMETypes, a:filetype) != -1
call <SID>CheckForGROUPNAMECode()
endif
endfunc
任意のタイプのファイルが開かれ、ファイルタイプ（au FileType *行）が設定されるたびに、ConfigureFiletypes関数が呼び出されます。これにより、ファイルタイプが現在のグループ（GROUPNAME）に関連付けられているファイルタイプのリストに含まれているかどうかがチェックされます。この場合は、「c」、「cpp」、「vhdl」、または「c.doxygen」です。そうである場合は、CheckForGROUPNAMECode（）を呼び出します。これは、ファイルの最初の10行を読み取り、それらにGROUPNAMEが含まれている場合は、いくつかのカスタマイズを行います。エキスパンドタブなどを設定するだけでなく、ステータスバーも変更され、グループ名が明確に表示されるため、一目で機能していることがわかります。
開くときに構成を確認する
JS Bangsの提案と同じように、カスタム構成ファイルがあると便利です。ただし、vimrcにロードする代わりに、次のようなものを検討してください。これにより、.cファイルと同じディレクトリにある.vim.customに対して.cファイルが開かれたときにチェックされます。
au BufNewFile,BufRead *.c call CheckForCustomConfiguration()
function! CheckForCustomConfiguration()
" Check for .vim.custom in the directory containing the newly opened file
let custom_config_file = expand('%:p:h') . '/.vim.custom'
if filereadable(custom_config_file)
exe 'source' custom_config_file
endif
endfunction