Groovyのリストからマップを作成するためのショートカット？

私はこれのためにいくつかの並べ替えをお願いします：

Map rowToMap(row) {
    def rowMap = [:];
    row.columns.each{ rowMap[it.name] = it.val }
    return rowMap;
}

GDKのものと同じように、私は次のようなことができると期待しています：

Map rowToMap(row) {
    row.columns.collectMap{ [it.name,it.val] }
}

しかし、ドキュメントで何も見ていません...何か不足していますか？それとも私はあまりにも怠惰ですか？

私は最近、まさにそれを行う必要性に出くわしました：リストをマップに変換します。この質問はGroovyバージョン1.7.9が出る前に投稿されたため、メソッドcollectEntriesはまだ存在していませんでした。これは、提案されたcollectMap方法とまったく同じように機能します。

Map rowToMap(row) {
    row.columns.collectEntries{[it.name, it.val]}
}

何らかの理由で古いGroovyバージョンに行き詰まっている場合は、このinject方法も使用できます（ここで提案されているとおり）。これは少し変更されたバージョンで、クロージャー内で式を1つだけ使用します（文字を節約するためです）。

Map rowToMap(row) {
    row.columns.inject([:]) {map, col -> map << [(col.name): col.val]}
}

+オペレータはまた、代わりに使用することができます<<。

「注入」をチェックしてください。実際の関数型プログラミングは、それを「フォールド」と呼びます。

columns.inject([:]) { memo, entry ->
    memo[entry.name] = entry.val
    return memo
}

そして、その間、おそらくmetaClassではなく、カテゴリとしてメソッドを定義したいと思うでしょう。これにより、すべてのコレクションに対して一度定義できます。

class PropertyMapCategory {
    static Map mapProperty(Collection c, String keyParam, String valParam) {
        return c.inject([:]) { memo, entry ->
            memo[entry[keyParam]] = entry[valParam]
            return memo
        }
    }
}

使用例：

use(PropertyMapCategory) {
    println columns.mapProperty('name', 'val')
}

たGROUPBYのこの質問を頼まれたとき、この方法は使用できませんか？

必要なのが単純なキーと値のペアである場合は、メソッドcollectEntriesで十分です。例えば

def names = ['Foo', 'Bar']
def firstAlphabetVsName = names.collectEntries {[it.charAt(0), it]} // [F:Foo, B:Bar]

しかし、キーごとに複数の値があるマルチマップに似た構造が必要な場合は、groupByメソッドを使用する必要があります

def names = ['Foo', 'Bar', 'Fooey']
def firstAlphabetVsNames = names.groupBy { it.charAt(0) } // [F:[Foo, Fooey], B:[Bar]]

また、Googleコレクション（http://code.google.com/p/google-collections/）を使用している場合は、次のようなことができます。

  map = Maps.uniqueIndex(list, Functions.identity());

わかりました...これをもう少し試してみましたが、これはかなりクールな方法だと思います...

def collectMap = {Closure callback->
    def map = [:]
    delegate.each {
        def r = callback.call(it)
        map[r[0]] = r[1]
    }
    return map
}
ExpandoMetaClass.enableGlobally()
Collection.metaClass.collectMap = collectMap
Map.metaClass.collectMap = collectMap

MapまたはCollectionのすべてのサブクラスにこのメソッドがあります...

ここでは、マップのキー/値を逆にするために使用しています

[1:2, 3:4].collectMap{[it.value, it.key]} == [2:1, 4:3]

ここでは、リストからマップを作成するために使用しています

[1,2].collectMap{[it,it]} == [1:1, 2:2]

これで、アプリの起動時に呼び出されるクラスにこれをポップするだけで、このメソッドはコード全体で使用できます。

編集：

すべての配列にメソッドを追加するには...

Object[].metaClass.collectMap = collectMap

何も組み込まれていません...しかし、ExpandoMetaClassを使用してこれを行うことができます。

ArrayList.metaClass.collectMap = {Closure callback->
    def map = [:]
    delegate.each {
        def r = callback.call(it)
        map[r[0]] = r[1]
    }
    return map
}

これにより、collectMapメソッドがすべてのArrayListsに追加されます... ListまたはCollectionに追加できなかった理由がわかりません。これは別の質問だと思います...しかし、今、これを行うことができます...

assert ["foo":"oof", "42":"24", "bar":"rab"] ==
            ["foo", "42", "bar"].collectMap { return [it, it.reverse()] }

リストから1つのクロージャを使用して計算されたマップまで...まさに私が探していたもの。

編集：リストとコレクションのインターフェイスにメソッドを追加できなかったのは、これを行わなかったためです。

List.metaClass.enableGlobally()

そのメソッド呼び出しの後、インターフェースにメソッドを追加できます。この場合、私のcollectMapメソッドは次のような範囲で機能します。

(0..2).collectMap{[it, it*2]}

これはマップを生成します：[0：0、1：2、2：4]

このようなものはどうですか？

// setup
class Pair { 
    String k; 
    String v; 
    public Pair(def k, def v) { this.k = k ; this.v = v; }
}
def list = [ new Pair('a', 'b'), new Pair('c', 'd') ]

// the idea
def map = [:]
list.each{ it -> map.putAt(it.k, it.v) }

// verify
println map['c']