WMICとTASKLISTツールは好きですが、QPROCESSWindowsのホーム/ベーシックエディションでは使用できません。別の方法は、ほぼすべてのWindowsマシンで利用できるコマンドを使用することです（ターミナルサービスを備えたものの場合-SP2なしでXPでのみ勝つと思うので、実際にはすべてのWindowsマシン）：
@echo off
:check_process
setlocal
if "%~1" equ "" echo pass the process name as forst argument && exit /b 1
:: first argument is the process you want to check if running
set process_to_check=%~1
:: QPROCESS can display only the first 12 symbols of the running process
:: If other tool is used the line bellow could be deleted
set process_to_check=%process_to_check:~0,12%
QPROCESS * | find /i "%process_to_check%" >nul 2>&1 && (
echo process %process_to_check% is running
) || (
echo process %process_to_check% is not running
)
endlocal
QPROCESSコマンドはそれほど強力ではなくTASKLIST、プロセス名の12個のシンボルしか表示されTASKLISTませんが、使用できない場合は考慮に入れる必要があります。
プロセスを引数として使用する場合、名前を使用するより簡単な使用法（.exeこの場合、実行可能ファイル名を渡す場合、サフィックスは必須です）：
@echo off
:check_process
setlocal
if "%~1" equ "" echo pass the process name as forst argument && exit /b 1
:: first argument is the process you want to check if running
:: .exe suffix is mandatory
set "process_to_check=%~1"
QPROCESS "%process_to_check%" >nul 2>&1 && (
echo process %process_to_check% is running
) || (
echo process %process_to_check% is not running
)
endlocal
2つのQPROCESS使用方法の違いは、QPROCESS *はすべてのプロセスを一覧表示QPROCESS some.exeし、現在のユーザーのプロセスのみをフィルタリングすることです。
WMI代わりにWindowsスクリプトホストexeを介してオブジェクトを使用することWMICもオプションです。すべてのWindowsマシンでも実行する必要があります（WSHがオフになっているものは除きますが、これはまれなケースです）。WMIを介してすべてのプロセスをリストするbatファイルクラスでありQPROCESS、上記のスクリプトの代わりに使用できます（これはjscript / batハイブリッドであり、として保存する必要があります.bat）：
@if (@X)==(@Y) @end /* JSCRIPT COMMENT **
@echo off
cscript //E:JScript //nologo "%~f0"
exit /b
************** end of JSCRIPT COMMENT **/
var winmgmts = GetObject("winmgmts:\\\\.\\root\\cimv2");
var colProcess = winmgmts.ExecQuery("Select * from Win32_Process");
var processes = new Enumerator(colProcess);
for (;!processes.atEnd();processes.moveNext()) {
var process=processes.item();
WScript.Echo( process.processID + " " + process.Name );
}
そして、プロセスが実行されているかどうかをチェックする変更：
@if (@X)==(@Y) @end /* JSCRIPT COMMENT **
@echo off
if "%~1" equ "" echo pass the process name as forst argument && exit /b 1
:: first argument is the process you want to check if running
set process_to_check=%~1
cscript //E:JScript //nologo "%~f0" | find /i "%process_to_check%" >nul 2>&1 && (
echo process %process_to_check% is running
) || (
echo process %process_to_check% is not running
)
exit /b
************** end of JSCRIPT COMMENT **/
var winmgmts = GetObject("winmgmts:\\\\.\\root\\cimv2");
var colProcess = winmgmts.ExecQuery("Select * from Win32_Process");
var processes = new Enumerator(colProcess);
for (;!processes.atEnd();processes.moveNext()) {
var process=processes.item();
WScript.Echo( process.processID + " " + process.Name );
}
2つのオプションは、がないマシンで使用できますTASKLIST。
究極のテクニックはを使用することMSHTAです。これは、XP以降のすべてのWindowsマシンで実行され、Windowsスクリプトホストの設定には依存しません。の呼び出しによりMSHTA、パフォーマンスが少し低下する可能性があります（ここでもバットとして保存する必要があります）。
@if (@X)==(@Y) @end /* JSCRIPT COMMENT **
@echo off
setlocal
if "%~1" equ "" echo pass the process name as forst argument && exit /b 1
:: first argument is the process you want to check if running
set process_to_check=%~1
mshta "about:<script language='javascript' src='file://%~dpnxf0'></script>" | find /i "%process_to_check%" >nul 2>&1 && (
echo process %process_to_check% is running
) || (
echo process %process_to_check% is not running
)
endlocal
exit /b
************** end of JSCRIPT COMMENT **/
var fso= new ActiveXObject('Scripting.FileSystemObject').GetStandardStream(1);
var winmgmts = GetObject("winmgmts:\\\\.\\root\\cimv2");
var colProcess = winmgmts.ExecQuery("Select * from Win32_Process");
var processes = new Enumerator(colProcess);
for (;!processes.atEnd();processes.moveNext()) {
var process=processes.item();
fso.Write( process.processID + " " + process.Name + "\n");
}
close();