Groovy実行シェルコマンド

Groovyはexecuteメソッドを追加しますStringシェルの実行をかなり簡単するためます。

println "ls".execute().text

エラーが発生した場合、結果は出力されません。 標準エラーと標準出力の両方を取得する簡単な方法はありますか？ （コードの束を作成する以外に、2つのスレッドを作成して両方の入力ストリームを読み取り、次に親ストリームを使用してそれらが完了するのを待ってから文字列をテキストに変換しますか？）

次のようなものがあると便利です。

 def x = shellDo("ls /tmp/NoFile")
 println "out: ${x.out} err:${x.err}"

OK、自分で解決しました。

def sout = new StringBuilder(), serr = new StringBuilder()
def proc = 'ls /badDir'.execute()
proc.consumeProcessOutput(sout, serr)
proc.waitForOrKill(1000)
println "out> $sout err> $serr"

表示：

out> err> ls: cannot access /badDir: No such file or directory

"ls".execute()動作するProcess理由であるオブジェクトを返します"ls".execute().text。エラーストリームを読み取って、エラーがあったかどうかを判断できるはずです。

テキストを取得ProcessするStringBufferためにを渡すことができる追加のメソッドがあります：consumeProcessErrorStream(StringBuffer error)。

例：

def proc = "ls".execute()
def b = new StringBuffer()
proc.consumeProcessErrorStream(b)

println proc.text
println b.toString()

// a wrapper closure around executing a string                                  
// can take either a string or a list of strings (for arguments with spaces)    
// prints all output, complains and halts on error                              
def runCommand = { strList ->
  assert ( strList instanceof String ||
           ( strList instanceof List && strList.each{ it instanceof String } ) \
)
  def proc = strList.execute()
  proc.in.eachLine { line -> println line }
  proc.out.close()
  proc.waitFor()

  print "[INFO] ( "
  if(strList instanceof List) {
    strList.each { print "${it} " }
  } else {
    print strList
  }
  println " )"

  if (proc.exitValue()) {
    println "gave the following error: "
    println "[ERROR] ${proc.getErrorStream()}"
  }
  assert !proc.exitValue()
}

私はこれをもっと慣用的にしています：

def proc = "ls foo.txt doesnotexist.txt".execute()
assert proc.in.text == "foo.txt\n"
assert proc.err.text == "ls: doesnotexist.txt: No such file or directory\n"

別の投稿で言及されているように、これらは呼び出しをブロックしていますが、出力を操作するため、これが必要になる場合があります。

上記の回答に重要な情報をもう1つ追加するには-

プロセスについて

def proc = command.execute();

いつも使ってみる

def outputStream = new StringBuffer();
proc.waitForProcessOutput(outputStream, System.err)
//proc.waitForProcessOutput(System.out, System.err)

のではなく

def output = proc.in.text;

後者はブロッキングコールであるため、groovyでコマンドを実行した後に出力をキャプチャします（理由はSOの質問です）。

def exec = { encoding, execPath, execStr, execCommands ->

def outputCatcher = new ByteArrayOutputStream()
def errorCatcher = new ByteArrayOutputStream()

def proc = execStr.execute(null, new File(execPath))
def inputCatcher = proc.outputStream

execCommands.each { cm ->
    inputCatcher.write(cm.getBytes(encoding))
    inputCatcher.flush()
}

proc.consumeProcessOutput(outputCatcher, errorCatcher)
proc.waitFor()

return [new String(outputCatcher.toByteArray(), encoding), new String(errorCatcher.toByteArray(), encoding)]

}

def out = exec("cp866", "C:\\Test", "cmd", ["cd..\n", "dir\n", "exit\n"])

println "OUT:\n" + out[0]
println "ERR:\n" + out[1]

command = "ls *"

def execute_state=sh(returnStdout: true, script: command)

コマンドが失敗した場合、プロセスは終了します