gnuplot内のループ構造？

複数のファイルからデータを繰り返し取得し、gnuplotの同じグラフにプロットする方法はありますか？data1.txt、data2.txt ...... data1000.txtのようなファイルがあるとします。それぞれが同じ数の列を持っています。今、私は次のようなものを書くことができます-

plot "data1.txt" using 1:2 title "Flow 1", \
     "data2.txt" using 1:2 title "Flow 2", \
      .
      .
      .
     "data1000.txt"  using 1:2 title "Flow 6"

しかし、これは本当に不便です。gnuplotのプロット部分をループする方法があるかどうか疑問に思いました。

確かにあります（gnuplot 4.4+に）：

plot for [i=1:1000] 'data'.i.'.txt' using 1:2 title 'Flow '.i

変数iは変数または文字列として解釈できるため、次のようなことができます。

plot for [i=1:1000] 'data'.i.'.txt' using 1:($2+i) title 'Flow '.i

線を互いにオフセットさせたい場合。

help iteration詳細については、gnuplotコマンドラインで入力してください。

また、do for構文に関する@DarioPの回答も必ず確認してください。これにより、従来のforループに近いものが得られます。

do { ... }gnuplot 4.6以降のコマンドは非常に強力なので、次のコマンドも確認してください。

do for [t=0:50] {
  outfile = sprintf('animation/bessel%03.0f.png',t)
  set output outfile
  splot u*sin(v),u*cos(v),bessel(u,t/50.0) w pm3d ls 1
}

http://www.gnuplating.org/gnuplot-4-6-do/

私はスクリプトall.pを持っています

set ...
...
list=system('ls -1B *.dat')
plot for [file in list] file w l u 1:2 t file

ここで、最後の2行は文字通りであり、ヒューリスティックではありません。それから私は走ります

$ gnuplot -p all.p

*.datお持ちのファイルタイプに変更するか、ファイルタイプを追加してください。

次のステップ：この行を〜/ .bashrcに追加します

alias p='gnuplot -p ~/./all.p'

ファイルall.pをホームディレクトリに入れて、出来上がり。pと入力してEnterキーを押すと、任意のディレクトリにあるすべてのファイルをプロットできます。

編集それが機能しなかったので、私はコマンドを変更しました。以前はが含まれていましたlist(i)=word(system(ls -1B *.dat),i)。

グラフにプロットする離散列がある場合は、以下を使用してください

do for [indx in "2 3 7 8"] {
  column = indx + 0
  plot ifile using 1:column ;  
}

ワイルドカードを使用して、任意のディレクトリから作業しながら、異なるディレクトリに配置されることが多い複数のファイルをプロットしたかったのです。私が見つけた解決策は、で次の関数を作成することでした~/.bashrc

plo () {
local arg="w l"
local str="set term wxt size 900,500 title 'wild plotting'
set format y '%g'
set logs
plot"
while [ $# -gt 0 ]
        do str="$str '$1' $arg,"
        shift
done
echo "$str" | gnuplot -persist
}

たとえば、のようplo *.dat ../../dir2/*.outに使用して.dat、現在のディレクトリ内のすべての.outファイルと、たまたまレベルアップして呼ばれるディレクトリ内のすべてのファイルをプロットしますdir2。

代替コマンドは次のとおりです。

gnuplot -p -e 'plot for [file in system("find . -name \\*.txt -depth 1")] file using 1:2 title file with lines'