テキストファイルから最初の行を読み取るWindowsバッチコマンド

Windowsバッチファイルを使用してテキストファイルから最初の行を読み取るにはどうすればよいですか？ファイルが大きいので、最初の行だけを扱いたいと思います。

これnは、GNUheadユーティリティのようなファイルから、1行だけでなく、一番上の行を印刷するための汎用バッチファイルです。

@echo off

if [%1] == [] goto usage
if [%2] == [] goto usage

call :print_head %1 %2
goto :eof

REM
REM print_head
REM Prints the first non-blank %1 lines in the file %2.
REM
:print_head
setlocal EnableDelayedExpansion
set /a counter=0

for /f ^"usebackq^ eol^=^

^ delims^=^" %%a in (%2) do (
        if "!counter!"=="%1" goto :eof
        echo %%a
        set /a counter+=1
)

goto :eof

:usage
echo Usage: head.bat COUNT FILENAME

例えば：

Z:\>head 1 "test file.c"
; this is line 1

Z:\>head 3 "test file.c"
; this is line 1
    this is line 2
line 3 right here

現在、空白行はカウントされません。また、8KBのバッチファイルの行の長さの制限も適用されます。

え？imoこれははるかに簡単です

  set /p texte=< file.txt  
  echo %texte%

ええと、皆さん...

C:\>findstr /n . c:\boot.ini | findstr ^1:

1:[boot loader]

C:\>findstr /n . c:\boot.ini | findstr ^3:

3:default=multi(0)disk(0)rdisk(0)partition(1)\WINNT

C:\>

あなたはこれを試してみるかもしれません：

@echo off

for /f %%a in (sample.txt) do (
  echo %%a
  exit /b
)

編集 または、4列のデータがあり、5行目から下に向かって必要な場合は、次のようにします。

@echo off

for /f "skip=4 tokens=1-4" %%a in (junkl.txt) do (
  echo %%a %%b %%c %%d
)

テキストファイルから最初の行を読み取るためのWindowsバッチコマンドの回答を含むthetalkingwalnutのおかげで、次の解決策を思いつきました。

@echo off
for /f "delims=" %%a in ('type sample.txt') do (
echo %%a
exit /b
)

他の人の答えに少し基づいて構築します。これで、読み取りたいファイルと結果を入れる変数を指定できるようになりました。

@echo off
for /f "delims=" %%x in (%2) do (
set %1=%%x
exit /b
)

これは、上記のように使用できることを意味します（getline.batと呼んだと仮定します）

c:\> dir > test-file
c:\> getline variable test-file
c:\> set variable  
variable= Volume in drive C has no label.

">"を使用したstdoutリダイレクトに役立つ1つのライナー：

@for /f %%i in ('type yourfile.txt') do @echo %%i & exit

これを試して

@echo off
setlocal enableextensions enabledelayedexpansion
set firstLine=1
for /f "delims=" %%i in (yourfilename.txt) do (
    if !firstLine!==1 echo %%i
    set firstLine=0
)
endlocal

EXIT /Bバッチファイルの一部としてより現実的には、ソリューションの問題は次のとおりです。その後、上記のバッチファイル内で後続の処理はありませんEXIT /B。通常、バッチには1つの限られたタスクよりもはるかに多くのものがあります。

その問題に対処するには：

@echo off & setlocal enableextensions enabledelayedexpansion
set myfile_=C:\_D\TEST\My test file.txt
set FirstLine=
for /f "delims=" %%i in ('type "%myfile_%"') do (
  if not defined FirstLine set FirstLine=%%i)
echo FirstLine=%FirstLine%
endlocal & goto :EOF

（ただし、いわゆる毒キャラクターは依然として問題になります。）

バッチコマンドで特定の行を取得することについての詳細：

テキストファイルのn番目、最初、最後の行を取得するにはどうすればよいですか？」 http://www.netikka.net/tsneti/info/tscmd023.htm

[2012年8月28日追加]次のこともできます。

@echo off & setlocal enableextensions
set myfile_=C:\_D\TEST\My test file.txt
for /f "tokens=* delims=" %%a in (
  'type "%myfile_%"') do (
    set FirstLine=%%a& goto _ExitForLoop)
:_ExitForLoop
echo FirstLine=%FirstLine%
endlocal & goto :EOF

（ファイルをcicleするにはfile1.txt、file1[1].txt、file1[2].txt、など）：

START/WAIT C:\LAERCIO\DELPHI\CICLADOR\dprCiclador.exe C:\LAERCIUM\Ciclavel.txt

rem set/p ciclo=< C:\LAERCIUM\Ciclavel.txt:
set/p ciclo=< C:\LAERCIUM\Ciclavel.txt

rem echo %ciclo%:
echo %ciclo%

そして、それは実行されています。

バッチファイルのアプローチは、DOSコマンドプロセッサの行制限に制限されることに注意してください。コマンド行の長さの制限とは何ですか？を参照してください。。

したがって、それ以上の行があるファイルを処理しようとすると、 8192文字をすると、値を保持できないため、スクリプトはそれらをスキップします。

別の方法

setlocal enabledelayedexpansion
@echo off
for /f "delims=" %%i in (filename.txt) do (
if 1==1 (
set first_line=%%i
echo !first_line!
goto :eof
))

以下を使用した回避策を次に示しますpowershell。

powershell (Get-Content file.txt)[0]

（で行の範囲も簡単に読むことができますpowershell (Get-Content file.txt)[0..3]）

バッチスクリプト内で変数を設定する必要がある場合は、次の行をfile.txt使用できます。

for /f "usebackq delims=" %%a in (`powershell ^(Get-Content file.txt^)[0]`) do (set "head=%%a")

for /f "delims=" %a in (downing.txt) do echo %a & pause>nul

1行目を印刷し、ユーザーがキーを押して次の行を印刷するのを待ちます。必要な行を印刷したら、Ctrl + Cを押して停止します。

@Ross Presser：このメソッドは、行番号を付加するのではなく、行のみを印刷します。