CMakeファイルにリンカーまたはコンパイルフラグを追加するにはどうすればよいですか？

arm-linux-androideabi-g++コンパイラを使用しています。簡単な「Hello、World！」をコンパイルしようとすると うまくコンパイルするプログラム。そのコードに単純な例外処理を追加してテストすると、それも機能します（追加した後-fexceptionsは、デフォルトで無効になっていると思います）。

これはAndroidデバイス用であり、CMakeのみを使用し、は使用しませんndk-build。

例えば ​​- first.cpp

#include <iostream>

using namespace std;

int main()
{
   try
   {
   }
   catch (...)
   {
   }
   return 0;
}

./arm-linux-androideadi-g++ -o first-test first.cpp -fexceptions

問題なく動作します...

問題 ... CMakeファイルでファイルをコンパイルしようとしています。

-fexceptionsフラグとして追加したい。私が試した

set (CMAKE_EXE_LINKER_FLAGS -fexceptions ) or set (CMAKE_EXE_LINKER_FLAGS "fexceptions" )

そして

set ( CMAKE_C_FLAGS "fexceptions")

それでもエラーが表示されます。

これらのフラグを追加するとします（定数で宣言する方がよいでしょう）。

SET(GCC_COVERAGE_COMPILE_FLAGS "-fprofile-arcs -ftest-coverage")
SET(GCC_COVERAGE_LINK_FLAGS    "-lgcov")

それらを追加するにはいくつかの方法があります。

1. 最も簡単な方法（クリーンではありませんが、簡単で便利で、コンパイルフラグ、CとC ++でのみ機能します）：

   add_definitions(${GCC_COVERAGE_COMPILE_FLAGS})

2. 対応するCMake変数に追加する：

   SET(CMAKE_CXX_FLAGS  "${CMAKE_CXX_FLAGS} ${GCC_COVERAGE_COMPILE_FLAGS}")
   SET(CMAKE_EXE_LINKER_FLAGS  "${CMAKE_EXE_LINKER_FLAGS} ${GCC_COVERAGE_LINK_FLAGS}")

3. ターゲットプロパティを使用する場合は、cf。doc CMakeコンパイルフラグのターゲットプロパティであり、ターゲット名を知っている必要があります。

   get_target_property(TEMP ${THE_TARGET} COMPILE_FLAGS)
   if(TEMP STREQUAL "TEMP-NOTFOUND")
     SET(TEMP "") # Set to empty string
   else()
     SET(TEMP "${TEMP} ") # A space to cleanly separate from existing content
   endif()
   # Append our values
   SET(TEMP "${TEMP}${GCC_COVERAGE_COMPILE_FLAGS}" )
   set_target_properties(${THE_TARGET} PROPERTIES COMPILE_FLAGS ${TEMP} )

現在、方法2を使用しています。

CMakeの新しいバージョンでは、単一でターゲットのコンパイラとリンカのフラグを設定することができますtarget_compile_optionsし、target_link_librariesそれぞれ（はい、オプションリンカ後者のセットすぎ）：

target_compile_options(first-test PRIVATE -fexceptions)

この方法の利点は、PUBLICおよびを介して、このターゲットに依存する他のターゲットへのオプションの伝播を制御できることですPRIVATE。

CMake 3.13以降では、次も使用できます target_link_optionsでは、意図をより明確にするリンカーオプションを追加ためにます。

CMAKE_CXX_FLAGS代わりに変数を設定してみてくださいCMAKE_C_FLAGS：

set (CMAKE_CXX_FLAGS "-fexceptions")

変数CMAKE_C_FLAGSはCコンパイラにのみ影響しますが、C ++コードをコンパイルしています。

へのフラグの追加CMAKE_EXE_LINKER_FLAGSは冗長です。

LINK_FLAGSプロパティを使用して、特定のターゲットにリンカーフラグを追加することもできます。

set_property(TARGET ${target} APPEND_STRING PROPERTY LINK_FLAGS " ${flag}")

この変更を他のターゲットに伝播したい場合は、リンク先のダミーターゲットを作成できます。

チェックアウトucm_add_flagsとucm_add_linker_flagsのマクロUCM（便利CMakeのマクロの私のセット） -彼らは、コンパイラ/リンカのフラグを追加するに対処します。