gnuplot：複数の入力ファイルからのデータを単一のグラフにプロットする

gnuplotを使ってグラフをプロットしようとしています。6つのテキストファイルがあります。各テキストファイルには2つの列が含まれています。最初の列は秒単位の時間を表します（浮動小数点数）。2つ目はシーケンス番号です。6つのファイルすべてについて、時間とシーケンス番号のグラフを1つのグラフにプロットしたいと思います。私はそれを行うためにこのファイルを使用しています。

set terminal png
set output 'akamai.png'

set xdata time
set timefmt "%S"
set xlabel "time"

set autoscale

set ylabel "highest seq number"
set format y "%s"

set title "seq number over time"
set key reverse Left outside
set grid

set style data linespoints

plot "print_1012720" using 1:2 title "Flow 1", \
plot "print_1058167" using 1:2 title "Flow 2", \
plot "print_193548"  using 1:2 title "Flow 3", \ 
plot "print_401125"  using 1:2 title "Flow 4", \
plot "print_401275"  using 1:2 title "Flow 5", \
plot "print_401276"  using 1:2 title "Flow 6"

私のファイルはどこにありますか：

• print_1012720
• print_1058167
• print_193548
• print_401125
• print_401275
• print_401276

以下のような奇妙なエラーが発生しています。

「plot.plt」、24行目：未定義の変数：plot

私は何か間違ったことをしていますか？異なるファイルからの入力データを同じグラフにプロットすることは可能ですか？

あなたはとても近いです！

変化する

plot "print_1012720" using 1:2 title "Flow 1", \
plot "print_1058167" using 1:2 title "Flow 2", \
plot "print_193548"  using 1:2 title "Flow 3", \ 
plot "print_401125"  using 1:2 title "Flow 4", \
plot "print_401275"  using 1:2 title "Flow 5", \
plot "print_401276"  using 1:2 title "Flow 6"

に

plot "print_1012720" using 1:2 title "Flow 1", \
     "print_1058167" using 1:2 title "Flow 2", \
     "print_193548"  using 1:2 title "Flow 3", \ 
     "print_401125"  using 1:2 title "Flow 4", \
     "print_401275"  using 1:2 title "Flow 5", \
     "print_401276"  using 1:2 title "Flow 6"

gnuplotが「plot」という単語をプロットするファイル名として解釈しようとしているが、「plot」という名前の変数に文字列を割り当てていないため、エラーが発生します（これは良いことです-非常に混乱します）。

この場合、ファイル名またはグラフのタイトルを適切に調整すると、gnuplotのforループが役立つことがあります。

例えば

filenames = "first second third fourth fifth"
plot for [file in filenames] file."dat" using 1:2 with lines

そして

filename(n) = sprintf("file_%d", n)
plot for [i=1:10] filename(i) using 1:2 with lines

replot

これは、一度に複数のプロットを取得する別の方法です。

plot file1.data
replot file2.data