CMakeでC ++ 11をアクティブ化するにはどうすればよいですか？

CMakeで生成されたmakefileを実行してプログラムをコンパイルしようとすると、次のエラーが発生します。

範囲ベースのforループは、C ++ 98モードではサポートされていません。

にを追加add_definitions(-std=c++0x)してみましたがCMakeLists.txt、効果がありませんでした。

私もこれを試しました：

if(CMAKE_COMPILER_IS_GNUCXX)
    add_definitions(-std=gnu++0x)
endif()

私がするときg++ --version、私は得ます：

g ++（Ubuntu / Linaro 4.6.1-9ubuntu3）4.6.1

私も試しましたがSET(CMAKE_CXX_FLAGS "-std=c++0x")、これも機能しません。

CMakeを使用してC ++ 11の機能をアクティブ化する方法がわかりません。

CMake 3.1では、使用可能なCMAKE_CXX_STANDARD変数が導入されました。CMake 3.1を常に使用できることがわかっている場合は、これを最上位のCMakeLists.txtファイルに書き込むか、新しいターゲットが定義される直前に配置できます。

set (CMAKE_CXX_STANDARD 11)

古いバージョンのCMakeをサポートする必要がある場合は、次のマクロを使用して使用できます。

macro(use_cxx11)
  if (CMAKE_VERSION VERSION_LESS "3.1")
    if (CMAKE_CXX_COMPILER_ID STREQUAL "GNU")
      set (CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -std=gnu++11")
    endif ()
  else ()
    set (CMAKE_CXX_STANDARD 11)
  endif ()
endmacro(use_cxx11)

現在、マクロはGCCのみをサポートしていますが、他のコンパイラに拡張することは簡単です。

次にuse_cxx11()、C ++ 11を使用するターゲットを定義するCMakeLists.txtファイルの先頭に書き込むことができます。

macOSをターゲットとするclangユーザー向けのCMakeの問題＃15943

CMakeとclangを使用してmacOSをターゲットにしている場合、機能が単純に機能しない（コンパイラフラグを追加しない）可能性のあるバグがありCMAKE_CXX_STANDARDます。次のいずれかを実行してください。

• cmake_minimum_requiredを使用して、CMake 3.0以降を要求するか、

• projectコマンドの前にCMakeLists.txtファイルの先頭にある次のコードを使用して、ポリシーCMP0025をNEWに設定します。

  # Fix behavior of CMAKE_CXX_STANDARD when targeting macOS.
  if (POLICY CMP0025)
    cmake_policy(SET CMP0025 NEW)
  endif ()

CMakeコマンドtarget_compile_features()は、必要なC ++機能を指定するために使用されますcxx_range_for。CMakeはC ++標準を使用するように誘導します。

cmake_minimum_required(VERSION 3.1.0 FATAL_ERROR)
project(foobar CXX)
add_executable(foobar main.cc)
target_compile_features(foobar PRIVATE cxx_range_for)

CMakeは、C ++コンパイラが適切なコマンドラインフラグで呼び出されることを確認するためadd_definitions(-std=c++11)、CMake変数を使用したり変更したりする必要はありませんCMAKE_CXX_FLAGS。

たぶん、あなたのC ++プログラムは以外のC ++機能を使用していますcxx_range_for。CMakeグローバルプロパティCMAKE_CXX_KNOWN_FEATURESは、選択可能なC ++機能をリストします。

使用する代わりに target_compile_features()する、CMakeプロパティCXX_STANDARD を 設定CXX_STANDARD_REQUIREDしてCMakeターゲットにC ++標準を明示的に指定することもできます 。

こちらもご覧ください 私のより詳細な回答。

使っています

include(CheckCXXCompilerFlag)
CHECK_CXX_COMPILER_FLAG("-std=c++11" COMPILER_SUPPORTS_CXX11)
CHECK_CXX_COMPILER_FLAG("-std=c++0x" COMPILER_SUPPORTS_CXX0X)
if(COMPILER_SUPPORTS_CXX11)
    set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -std=c++11")
elseif(COMPILER_SUPPORTS_CXX0X)
    set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -std=c++0x")
else()
        message(STATUS "The compiler ${CMAKE_CXX_COMPILER} has no C++11 support. Please use a different C++ compiler.")
endif()

あなたが一緒にプレイしたい場合はしかしC++11、g++ 4.6.1かなり古いです。新しいg++バージョンを入手してください。

Cxx標準を設定する最も簡単な方法は次のとおりです。

 set_property(TARGET tgt PROPERTY CXX_STANDARD 11)

詳細については、CMakeのドキュメントを参照してください。

結局のところ、SET(CMAKE_CXX_FLAGS "-std=c++0x")アクティベート多くのC ++ 11個の機能はありません。うまくいかなかった理由は、ステートメントが次のようになったためです。

set(CMAKE_CXX_FLAGS "-std=c++0x ${CMAKE_CXX_FLAGS} -g -ftest-coverage -fprofile-arcs")

このアプローチに従って、どういうわけか-std=c++0xフラグは上書きされ、機能しませんでした。フラグを1つずつ設定するか、listメソッドを使用して機能しています。

list( APPEND CMAKE_CXX_FLAGS "-std=c++0x ${CMAKE_CXX_FLAGS} -g -ftest-coverage -fprofile-arcs")

最も簡単な方法：

add_compile_options(-std=c++11)

CMake 3.8以降では、使用できます

target_compile_features(target PUBLIC cxx_std_11)

これは、C ++ 11サポートを有効にするもう1つの方法です。

ADD_DEFINITIONS(
    -std=c++11 # Or -std=c++0x
    # Other flags
)

この方法のみが機能し、他の方法が失敗する場合があります。CMakeの最新バージョンと関係があるのか​​もしれません。

最新のCMake（> = 3.1）では、グローバル要件を設定する最良の方法は次のとおりです。

set(CMAKE_CXX_STANDARD 11)
set(CMAKE_CXX_STANDARD_REQUIRED ON)
set(CMAKE_CXX_EXTENSIONS OFF)

これは、「すべてのターゲットにC ++ 11が必要です。これはオプションではなく、GNUまたはMicrosoftの拡張機能を使用したくない」と解釈されます。C ++ 17の時点で、これはまだIMHOが最良の方法です。

ソース：CMakeでC ++ 11以降を有効にする

私にとってうまくいくのは、CMakeLists.txtに次の行を設定することです。

set (CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -std=c++11")

このコマンドを設定すると、コンパイラーのC ++ 11機能がアクティブになり、cmake ..コマンドの実行後range based for loops、コードで使用してエラーなしでコンパイルできるようになります。

この2行で十分だと思います。

set(CMAKE_CXX_STANDARD 11)

set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -std=c++11")

常に最新のC ++標準をアクティブ化したい場合は、最近の（CMake 3.8およびCMake 3.11）CMAKE_CXX_STANDARDの値17および20の追加に照らして、David Graysonの回答の私の拡張を以下に示します。

IF (CMAKE_VERSION VERSION_LESS "3.8")
    SET(CMAKE_CXX_STANDARD 14)
ELSEIF (CMAKE_VERSION VERSION_LESS "3.11")
    SET(CMAKE_CXX_STANDARD 17)
ELSE()
    SET(CMAKE_CXX_STANDARD 20)
ENDIF()

# Typically, you'll also want to turn off compiler-specific extensions:
SET(CMAKE_CXX_EXTENSIONS OFF)

（set (CMAKE_CXX_STANDARD 11)リンクされた回答の代わりにそのコードを使用してください。）

最新のcmakeは、特定のバージョンのC ++を使用するようにコンパイラーを構成するより簡単な方法を提供します。誰でも必要なことは、関連するターゲットプロパティを設定することだけです。cmakeでサポートされているプロパティのうち、特定のバージョンのC ++をサポートするようにコンパイラーを構成する方法を決定するために使用されるプロパティは次のとおりです。

• CXX_STANDARDターゲットをビルドするために機能が要求されるC ++標準を設定します。11C ++ 11をターゲットにするには、これを設定します。

• CXX_EXTENSIONS、コンパイラ固有の拡張機能が要求されるかどうかを指定するブール値。これをOffに設定すると、コンパイラ固有の拡張機能のサポートが無効になります。

実例として、これはの最小限の実用的な例ですCMakeLists.txt。

cmake_minimum_required(VERSION 3.1)

project(testproject LANGUAGES CXX )

set(testproject_SOURCES
    main.c++
    )

add_executable(testproject ${testproject_SOURCES})

set_target_properties(testproject
    PROPERTIES
    CXX_STANDARD 11
    CXX_EXTENSIONS off
    )

OS XおよびHomebrew LLVM関連：

その後にcmake_minimum_required（VERSION 3.3）とproject（）を呼び出すことを忘れないでください！

または、CMakeがproject()行1の前に暗黙的に挿入され、Clangバージョンの検出で問題が発生し、その他の種類の問題が発生する可能性があります。これが関連する問題です。