SQL Serverでのトランザクションの正しい使用

私には2つのコマンドがあり、両方を正しく実行するか、どれも実行しないようにする必要があります。トランザクションが必要だと思いますが、正しく使用する方法がわかりません。

次のスクリプトの何が問題になっていますか？

BEGIN TRANSACTION [Tran1]

INSERT INTO [Test].[dbo].[T1]
    ([Title], [AVG])
VALUES ('Tidd130', 130), ('Tidd230', 230)

UPDATE [Test].[dbo].[T1]
  SET [Title] = N'az2' ,[AVG] = 1
  WHERE [dbo].[T1].[Title] = N'az'

COMMIT TRANSACTION [Tran1]
GO

INSERTコマンドが実行されますが、UPDATEコマンドに問題があります。

これを実装して、実行中にエラーが発生した場合に両方のコマンドをロールバックするにはどうすればよいですか？

try / catchブロックを追加します。トランザクションが成功すると変更がコミットされ、トランザクションが失敗するとトランザクションがロールバックされます。

BEGIN TRANSACTION [Tran1]

  BEGIN TRY

      INSERT INTO [Test].[dbo].[T1] ([Title], [AVG])
      VALUES ('Tidd130', 130), ('Tidd230', 230)

      UPDATE [Test].[dbo].[T1]
      SET [Title] = N'az2' ,[AVG] = 1
      WHERE [dbo].[T1].[Title] = N'az'

      COMMIT TRANSACTION [Tran1]

  END TRY

  BEGIN CATCH

      ROLLBACK TRANSACTION [Tran1]

  END CATCH  

ストアドプロシージャの最初に、SET XACT_ABORT ONを設定して、エラーの場合にトランザクションを自動的にロールバックするようにSQL Serverに指示する必要があります。省略するか、OFFに設定した場合は、各ステートメントの後に@@ ERRORをテストするか、TRY ... CATCHロールバックブロックを使用する必要があります。

簡単なアプローチ：

CREATE TABLE T
(
    C [nvarchar](100) NOT NULL UNIQUE,
);

SET XACT_ABORT ON -- Turns on rollback if T-SQL statement raises a run-time error.
SELECT * FROM T; -- Check before.
BEGIN TRAN
    INSERT INTO T VALUES ('A');
    INSERT INTO T VALUES ('B');
    INSERT INTO T VALUES ('B');
    INSERT INTO T VALUES ('C');
COMMIT TRAN
SELECT * FROM T; -- Check after.
DELETE T;