GLSLフラグメントシェーダーでこの種のリップルを実装する方法は？

だから私はすでに反射部分を実装しました：

uniform sampler2D texture;
uniform vec2 resolution;
uniform vec3 overlayColor;

void main()
{
vec2 uv = gl_FragCoord.xy / resolution.xy;

if (uv.y > 0.3)// is air - no reflection or effect
{
    gl_FragColor = texture2D(texture, vec2(uv.x, uv.y));
}
else
{
    // Compute the mirror effect.
    vec4 color = texture2D(texture, vec2(uv.x, 0.6 - uv.y));
    // 
    vec4 finalColor = vec4(mix(color.rgb, overlayColor, 0.25), 1.0);
    gl_FragColor = finalColor;
}
}

ソース

今問題は、これらの波紋がどのように実装されているかです。

私はテオドロンが示唆したことを実装しようとしました：

void main()
{
    vec2 uv = gl_FragCoord.xy / resolution.xy;
    float sepoffset = 0.005*cos(iGlobalTime*3.0);
    if (uv.y > 0.3 + sepoffset)// is air - no reflection or effect
    {
        gl_FragColor = texture2D(texture, vec2(uv.x, -uv.y));
    }
    else
    {
        // Compute the mirror effect.
        float xoffset = 0.005*cos(iGlobalTime*3.0+200.0*uv.y);
        //float yoffset = 0.05*(1.0+cos(iGlobalTime*3.0+50.0*uv.y));
        float yoffset = ((0.3 - uv.y)/0.3) * 0.05*(1.0+cos(iGlobalTime*3.0+50.0*uv.y));
        vec4 color = texture2D(texture, vec2(uv.x+xoffset , -1.0*(0.6 - uv.y+ yoffset)));
        // 
        //vec4 finalColor = vec4(mix(color.rgb, overlayColor, 0.25), 1.0);
        gl_FragColor = color;
    }
}

見た目はかなり似ていますが（ベースイメージがないとわかりにくいです）、パラメータを微調整できます。

あなたはそこでそれを実際に見るかもしれません：https：//www.shadertoy.com/view/Xll3R7

いくつかの備考：

• 画像を上下逆さまにしていたので、y座標を反転する必要がありましたが、それは、resolution.xyに渡す内容によって異なる場合があります。結果が反転した場合は、uv.yの反転を解除します
• Shadertoyで動作するように、ユニフォームの宣言を変更しました。これらの変更は無視できます。
• ただし、時間を提供するユニフォームを追加し、iGlobalTime（秒単位の時間）の代わりに使用する必要があります。
• 潮汐効果を追加したのは、例にあるように見えますが、わかりにくいためです（sepoffset変数を参照）。気に入らない場合は削除してください
• 見栄えが悪いのでオーバーレイの色を削除しましたが、あなたの例にはありませんでした
• 効果を好みに合わせて調整するには：
  • iGlobalTimeの係数を変更して、効果をスピードアップ/スローダウンします（必要に応じて、それぞれを個別に変更できます。たとえば、xの動きを加速し、yの動きを遅くします）。
  • cos（）係数を変更して、効果を増幅/減衰します

編集：@ceproからの変更を含めるようにyoffsetを変更しました