org：見出しをTODOで並べ替えてから優先度で並べ替える方法は？

私はしばしばこのようなリストを持っています：

* Main heading
** TODO [#A] Make world better
** TODO [#B] Make Emacs better 
** TODO [#B] Customize emacs 
** DONE [#C] some task
** TODO [#A] Launch rocket to mars

最初に「TODO」タスクワードに従ってソートしたいと思います。次に、ソートされたTODO内の項目を優先度でソートします。（その後、「Effort」でさらにソートするとよいでしょう）。

そして、私は現在、メインの見出しをクリックして、優先順位またはtodoキーワードのいずれかで既に子を並べ替えることができますが、両方ではありません。

sort-strategyのように両方でソートできますか？

現在、2つの見出しがあります

* Tasks
** TODO [#A] meh
** TODO [#B] meh2
* Completed.
** DONE [#B] meh3.

しかし、このアプローチの問題は、タスクを完了するときにタスクを常にシャッフルする必要があることです。

[編集]
これは、これに似ていますが、彼の答えを理解できなかったので、それを私のニーズに転送できませんでしたか？

以下のようなものがあった場合、それは素晴らしいことだorg-agenda-sorting-stratagyと働いたことがorg-sort-entries、必須ではないようです。org-sort-entries（文字列または数字）キーを各見出しに割り当てる関数を指定する引数を取ることができるため、偽造できます。これは、?fソートタイプが指定されたときにエントリをソートするために使用されます。行う必要があるのは、TODOプロパティとPRIORITYプロパティの文字列を取得することだけです。秘Theは、TODOプロパティをorg-todo-keywordsアルファベット順ではなくの位置でソートすることです。

(require 'cl)
(require 'dash)

(defun todo-to-int (todo)
    (first (-non-nil
            (mapcar (lambda (keywords)
                      (let ((todo-seq
                             (-map (lambda (x) (first (split-string  x "(")))
                                   (rest keywords)))) 
                        (cl-position-if (lambda (x) (string= x todo)) todo-seq)))
                    org-todo-keywords))))

(defun my/org-sort-key ()
  (let* ((todo-max (apply #'max (mapcar #'length org-todo-keywords)))
         (todo (org-entry-get (point) "TODO"))
         (todo-int (if todo (todo-to-int todo) todo-max))
         (priority (org-entry-get (point) "PRIORITY"))
         (priority-int (if priority (string-to-char priority) org-default-priority)))
    (format "%03d %03d" todo-int priority-int)
    ))

(defun my/org-sort-entries ()
  (interactive)
  (org-sort-entries nil ?f #'my/org-sort-key))

M-x my/org-sort-entriesTODOキーワードでソートし、PRIORITYとの関係を解除します（org-default-priority優先順位が指定されていない場合に使用します）。1000個を超えるTODOキーワードがある場合、これは中断します。これは、それを行わない正当な理由です。

以下をファイルに追加します。

#+ARCHIVE: :: * Completed.

シャッフルはアーカイブになります

エントリをソートするのではなく、ソートされたビューはどうですか？

(setq org-agenda-custom-commands
      '(("cx" "TODOs sorted by state, priority, effort"
         todo "*"
         ((org-agenda-overriding-header "\nTODOs sorted by state, priority, effort")
          (org-agenda-sorting-strategy '(todo-state-down priority-down effort-up))))))

で現在のファイルに制限します<。ソートされたビューからDONEとアーカイブをマークできます。

org-agenda-cmp-user-defined関数を定義してに追加することもできますorg-agenda-sorting-strategy。これは例として作成したものです。

(setq org-todo-sort-order '("WAIT" "TODO" "DOING" "CANCELED" "DONE"))

(defun my:user-todo-sort (a b)
  "Sort todo based on which I want to see first"
  (when-let ((state-a (get-text-property 14 'todo-state a))
             (state-b (get-text-property 14 'todo-state b))
             (cmp (--map (cl-position-if (lambda (x)
                                           (equal x it))
                                         org-todo-sort-order)
                         (list state-a state-b))))
    (cond ((apply '> cmp) 1)
          ((apply '< cmp) -1)
          (t nil))))
(setq org-agenda-cmp-user-defined 'my:user-todo-sort)

私が作ったこのライブラリを使用できます：https : //github.com/felipelalli/org-sort-tasks

タスクAがBよりも重要かどうかをユーザーに尋ねることにより、マージソートアルゴを使用し、ソートされたリストを作成します。