大きなドキュメントを編集するとき、アウトライン（コンテンツなし）を別のバッファーに表示することで、現在の場所を確認したいと思います。PDFファイルを読むときのように、左側に目次があります。（下記参照）

組織モードでは、アウトラインを展開/縮小することができます。しかし、別のバッファーの左（または右）に静的なアウトラインを設定して、見出しをクリックすると、他のバッファーがその位置に移動することは可能ですか？

ちょっとこのようなが、組織モードのために？

[編集]非常に近い私が何をしたいのです。パズルの欠けている部分は、見出し/（または実際に任意のポイント）をクリックしたときに同じ場所にジャンプすることです。
clone-indirect-buffer

このために、私はいくつかのコードを書き込もうとしました：他のクローンされたバッファを同じポイントに移動しますか？（間接バッファの同期位置）（組織モード）

ただし、コンテンツが折りたたまれている場合は機能しません。これを機能させることができる場合、clone-inderect-bufferはこれに対する完全なソリューションです。

[Edit2 Solution]
上記のリンクと以下の回答のコードは、niceleyを組み合わせて、前後のジャンプを解決します。

;first call 'clone-indirect-buffer'. Then...

;This function works between buffer and it's clone.
(defun my/goto-same-spot-in-other-buffer () 
  "Go to the same location in the other buffer. Useful for when you have cloned indirect buffers"
  (interactive)
  (let ((my/goto-current-point (point)))
       (other-window 1)
       (goto-char my/goto-current-point)
       (when (invisible-p (point))
        (org-reveal)))
)

;This function is a clone-to-buffer jump only:
; It does find the other buffer first thou instead of just jumping to the other 
; window as does the function above.
(defun my/jump-to-point-and-show ()
  "Switch to a cloned buffer's base buffer and move point to the
cursor position in the clone."
  (interactive)
  (let ((buf (buffer-base-buffer)))
    (unless buf
      (error "You need to be in a cloned buffer!"))
    (let ((pos (point))
          (win (car (get-buffer-window-list buf))))
      (if win
          (select-window win)
        (other-window 1)
        (switch-to-buffer buf))
      (goto-char pos)
      (when (invisible-p (point))
        (show-branches)))))


(global-set-key (kbd "<s-mouse-1>") 'my/goto-same-spot-in-other-buffer)
(global-set-key (kbd "s-m") 'my/goto-same-spot-in-other-buffer)
(global-set-key (kbd "<C-s-mouse-1>") 'my/jump-to-point-and-show)
(global-set-key (kbd "C-s-m") 'my/jump-to-point-and-show)

いくつかのオプションが思い浮かびます。最初の2つはspeedbar、と言われていますが、、とorg-mode、をminimap使用していませんが、個人的に保証することはできません。

最も単純なオプション（および最も柔軟なオプション）は、間接バッファを使用することです。

実際にはorg、アウトラインが必要なバッファに移動し、ヒットM-x clone-indirect-buffer（C-u M-x clone-indirect-bufferクローンの名前を制御したい場合に使用）してから、使用するバッファのコピーがもう1つあります。そのクローンを元のバッファと並べてウィンドウまたはフレームに配置し、クローンでアウトラインを好みに合わせて調整します。

あなたが言及した「アウトラインの見出しをクリックする」機能は使用できませんが、サイドバーの精神は使用できます。

編集：コメントへの応答として、バッファクローンから呼び出されたときにベースバッファに切り替え、カーソルがバッファクローン内のどこにあったとしてもポイントを移動する簡単なコマンドを次に示します。

(defun jump-to-point-and-show ()
  "Switch to a cloned buffer's base buffer and move point to the
cursor position in the clone."
  (interactive)
  (let ((buf (buffer-base-buffer)))
    (unless buf
      (error "You need to be in a cloned buffer!"))
    (let ((pos (point))
          (win (car (get-buffer-window-list buf))))
      (if win
          (select-window win)
        (other-window 1)
        (switch-to-buffer buf))
      (goto-char pos)
      (when (invisible-p (point))
        (show-branches)))))

方法：（M-x occur RET ^*+ RET正規表現の最後にスペースがあることに注意してください）。

ダンの答えとそれに基づいた解決策を読んだ後、これをまとめました。現在のバッファの左にある新しい、読み取り専用の狭いクローンを開き、クローン内<mouse-1>でRETローカルにバインドして、ベースバッファ内のその位置にジャンプします。

(defun my/open-tree-view ()
  "Open a clone of the current buffer to the left, resize it to 30 columns, and bind <mouse-1> to jump to the same position in the base buffer."
  (interactive)
  (let ((new-buffer-name (concat "<tree>" (buffer-name))))
    ;; Create tree buffer
    (split-window-right 30)
    (if (get-buffer new-buffer-name)
        (switch-to-buffer new-buffer-name)  ; Use existing tree buffer
      ;; Make new tree buffer
      (progn  (clone-indirect-buffer new-buffer-name nil t)
              (switch-to-buffer new-buffer-name)
              (read-only-mode)
              (hide-body)
              (toggle-truncate-lines)

              ;; Do this twice in case the point is in a hidden line
              (dotimes (_ 2 (forward-line 0)))

              ;; Map keys
              (use-local-map (copy-keymap outline-mode-map))
              (local-set-key (kbd "q") 'delete-window)
              (mapc (lambda (key) (local-set-key (kbd key) 'my/jump-to-point-and-show))
                    '("<mouse-1>" "RET"))))))

(defun my/jump-to-point-and-show ()
  "Switch to a cloned buffer's base buffer and move point to the cursor position in the clone."
  (interactive)
  (let ((buf (buffer-base-buffer)))
    (unless buf
      (error "You need to be in a cloned buffer!"))
    (let ((pos (point))
          (win (car (get-buffer-window-list buf))))
      (if win
          (select-window win)
        (other-window 1)
        (switch-to-buffer buf))
      (goto-char pos)
      (when (invisible-p (point))
        (show-branches)))))

これは、outline-modeおよびoutline-minor-modeに加えて、に基づいて構築されたモードで動作しますorg-mode。ローカルキーマップの取得に関する情報を見つけましたが、コピーするキーマップを選択する方法がわかりません。このページには、バッファローカルキーを設定するためのバッファ固有のマイナーモードを自動的に作成する機能もありますが、この問題では範囲外のようです。

最後に、これはパッケージに実装されましたorg-sidebar：

テキストエディタにaquamacsを使用するのが好きな非プログラマからの2つの低賃料の提案（私が行うこと）：

1. インバッファコマンドで前後に切り替えます。

STARTUP：インデント（ウォーターフォールタイプのアウトラインを全体として見やすくするため）

これは、バッファーのタブ駆動の表示用です

そして

+オプション：H：N、N = = htmlエクスポートで表示したいレベルの数、これは提案＃2です

参照：https : //emacsclub.github.io/html/org_tutorial.html

2. 目次を表示するには、html（CC CE hh）としてエクスポートします。インデントするHTMLまたはテキスト（CC CE ta）のテキスト出力を簡単に取得できる人は見つかりません

同様のものが必要だったので、outline-tocmodeをまとめました。組織モードのドキュメントで機能するはずです。