発音記号やアクセント記号なしでアラビア語のテキストを検索する方法は？

アラビア語には、他のいくつかの言語と同様に、発音を強化するための発音区別符号があります。1つの単語に対していくつの発音区別符号を書く必要があるかについての規則はありません。発音を明確にするのに十分なだけ（私が好む）の最小値を使用するものもあれば、不必要に、または単に書道の美的目的で使用するものもあります。したがって、1つの単語に関連付けられている発音区別符号の内容と数には、さまざまなバリエーションがあります。をisearch-forward/backward押して実行するC-s/rと、発音区別符号なしで検索ミニバッファーに入力すると問題が発生し、発音区別符号が含まれている場合、テキスト内の同じ単語と一致しないため、発音区別符号が含まれる可能性のあるこの単語を検索するタスクが不十分になります。

分音記号を認識しない検索/正規表現検索を作成する方法はありますか？私は含むように拡張することができる答えがあるだろう願っていますregexp C-M-s/rし、grep私は、マルチファイルラテックスプロジェクト内の単語を探すために舵-発射でかなり頻繁に使用することを検索します。

更新
オンデマンドでプレフィックスによってオフにされる可能性があるデフォルトの動作としてステップを照合する前に、テキストのステップを取り除く（アクセント/発音記号/名前を付ける）ことを行うすべての検索機能でEmacsが表示されるのを見るのは素晴らしいことです手元にある言語に関係なく。通常、私が最高のエディター（Emacs）に期待しない何かを検索すると、平凡なテキストの雑用を達成するために必要になることのある発音区別符号またはアクセントがあるため、この用法で失敗することがあります。

これは、この回答の結合文字のリストに基づく（そして拡張された）大まかなスタートです。（これをコミュニティウィキとしてマークします—これを編集して改善してください！）

(defconst arabic-diacritics '(#x064b #x064c #x064d #x064e #x064f #x0650 #x0651 #x0652 #x0653 #x0654 #x0655 #x0670)
  "Unicode codepoints for Arabic combining characters.")
(defconst arabic-diacritics-regexp (regexp-opt (mapcar #'string arabic-diacritics)))

(defconst arabic-equivalents
  '(
    ;; "alef" is equivalent to "alef with hamza above" etc
    (#x0627 #x0623 #x0625 #x0622)))

;; (require 'cl-lib)    
;; (defun arabic-strip-diacritics (string)
;;   (cl-reduce (lambda (s c) (remove c s)) arabic-diacritics :initial-value string))

(defun arabic-search-without-diacritics (string)
  (interactive (list (read-string "Search for: " nil nil nil t)))
  (let ((regexp
         (apply #'concat
                (mapcar (lambda (c)
                          (let ((equivalents (assq c arabic-equivalents)))
                            (concat
                             (if equivalents
                                 (regexp-opt (mapcar #'string equivalents))
                               (regexp-quote (string c)))
                             arabic-diacritics-regexp "*")))
                        string))))
    (search-forward-regexp regexp)))

したがって、バッファに「الْحَمْدُ لِلَّهِ رَبِّ الْعَالَمِينَ」が含まれていて、を評価(arabic-search-without-diacritics "الحمد لله رب العالمين")すると、テキストが検出されます。また、インタラクティブに動作しM-x arabic-search-without-diacriticsます。

代替アプローチ：

Mn正規表現の一致で正規化された文字列から発音区別記号やその他の非スペースマーク（プロパティ）を削除する方法を示す完全なコード例を次に示します。それは与えられた例で動作し、IMOは正しいアプローチです。

(defun kill-marks (string)
  (concat (loop for c across string
                when (not (eq 'Mn (get-char-code-property c 'general-category)))
                collect c)))

(let* ((original1 "your Arabic string here")
      (normalized1 (ucs-normalize-NFKD-string original1))
      (original2 "your other Arabic string here")
      (normalized2 (ucs-normalize-NFKD-string original2)))
  (equal
   (replace-regexp-in-string "." 'kill-marks normalized1)
   (replace-regexp-in-string "." 'kill-marks normalized2)))