Emacsを開くと、initファイルが評価されます。これには、インターネット接続を介したパッケージアーカイブの更新が含まれます。これは、インターネットに接続していないときに問題になるため、インターネットに接続せずにEmacsを起動するときにそのコードの実行を防止する必要があります。この問題を解決するために、インターネットに接続していないときにEmacsがパッケージの更新コードを無視する方法があるのだろうか？

ここに私の最初の数行がありますinit.el：

;; Requisites: Emacs >= 24
(require 'package)
(package-initialize)

;; PACKAGE MANAGEMENT
(add-to-list 'package-archives 
  '("melpa" . "http://melpa.milkbox.net/packages/") t)

(package-refresh-contents)       

次のようにEmacsファイルをロードするコードを追加できると思います。

;; Requisites: Emacs >= 24
(when (connected-to-internet-p)   ; I need this predicate function
  (require 'package)
  (package-initialize)
  (add-to-list 'package-archives 
               '("melpa" . "http://melpa.milkbox.net/packages/") t)
  (package-refresh-contents))

(connected-to-internet)この問題を解決する機能、または同様のアプローチはありますか？

可能であれば、コンテンツを自動的に更新したい場合は、次のコードのようなことができます。

(defun can-retreive-packages ()
  (cl-loop for url in '("http://marmalade-repo.org/packages/"
                        "http://melpa.milkbox.net/packages/"
                        "http://elpa.gnu.org/packages/")
           do (condition-case e
                  (kill-buffer (url-retrieve-synchronously url))
                (error (cl-return)))
           finally (cl-return t)))

いくつかの注意事項があります：

1. これは遅く、通常の起動時には遅くなるので、私はむしろ手動で行います。
2. 一般にインターネット接続をテストする方法はありません。特定のサービスに接続できなかったのは、ある程度の時間をかけてからだとわかります。これもまた、非常に遅い理由の1つです。
3. コードは、問題へのアプローチ方法をより具体的に示しています。(ignore-errors (package-refresh-contents))成功したかどうかを気にしなければ簡単にできたはずです。

シェルスクリプトから採用した簡単なソリューションは

(defun internet-up-p (&optional host)
    (= 0 (call-process "ping" nil nil nil "-c" "1" "-W" "1" 
                       (if host host "www.google.com"))))

これは*scratch*バッファでテストできます：

(message (if (internet-up-p) "Up" "Down"))
"Up"

試すことができるのは、関数network-interface-listです。ネットワークインターフェイスとそのIPアドレスのリストを返します。

私にとって、これはイーサネットとWiFiの両方に接続したときに返されるものです：

(("en5" .
  [10 151 0 63 0])
 ("en0" .
  [10 151 2 76 0])
 ("lo0" .
  [127 0 0 1 0]))

そして、wifiをオフにするとen0消えます：

(("en5" .
  [10 151 0 63 0])
 ("lo0" .
  [127 0 0 1 0]))

それを試して、インターネットに接続していないときに何が得られるかを確認してください。たとえば、en0起動時にのみパッケージを更新するには、次のようにします。

(when (assoc "en0" (network-interface-list))
  (package-refresh-contents))

レゴシアの答えを拡大するには：

(defun test-internet ()
  (remove-if (lambda (el)
                   (string-match-p "lo.*" (car el)))
                 (network-interface-list)))

これは、（アクティブなネットワーク接続のリストを返しますlo.*いくつかのケースでは、ループバックインタフェースであるlo他でlo#。

テストがを返す場合、non-nilネットワーク接続があります（wifi /イーサネット、実際には外部のインターネットに到達する保証はありません。テストのためにどこかにpingする必要があります）、戻る場合nil、パッケージを取得する方法はありませんリスト。

以下を使用して、loopbackインターフェイスとVirtualBoxおよびDockerインターフェイスも除外します。お役に立てば幸いです。

(defun tzz-has-network ()
  (remove-if (lambda (i)
               (or (string-match-p "\\(vboxnet\\|docker\\).*" i)
                   (member 'loopback (nth 4 (network-interface-info i)))))
             (mapcar 'car (network-interface-list))))

DBusとNetworkManagerを備えた最新のLinuxシステムの場合：

(defun nm-is-connected()
  (equal 70 (dbus-get-property
             :system "org.freedesktop.NetworkManager" "/org/freedesktop/NetworkManager"
             "org.freedesktop.NetworkManager" "State")))

あなたはそれを間違った方法で見ていると思います。パッケージを本当に自動更新する場合は、起動時に同期的に実行しないでください。何らかのアイドルタイマーから実行してください。例えば

(run-with-idle-timer 10 nil
  (lambda ()
    (package-refresh-contents)
    ..etc..))