バッファ内のすべての正規表現の一致をリストとして取得します

今日のCode Golf Stack Exchangeサイトで、「Webページ上のすべてのリンクを取得する」という質問に対するClojureのこの回答を見つけました。

(->> (slurp "http://www.stroustrup.com")
     (re-seq #"(?:http://)?www(?:[./#\+-]\w*)+"))

派手なマクロなしで、それはちょうどこれです：

(re-seq #"(?:http://)?www(?:[./#\+-]\w*)+" (slurp "http://www.stroustrup.com"))

これはリストを返します：

("http://www.morganstanley.com/" "http://www.cs.columbia.edu/" "http://www.cse.tamu.edu" ...)

Emacs Lispで同様のことができますか？

おそらくそのような関数(re-seq regexp (buffer-string))は返します'(firstmatch secondmatch thirdmatch ...)か？

要求に応じて、文字列に基づいてそれを行う方法を次に示します。

(defun re-seq (regexp string)
  "Get a list of all regexp matches in a string"
  (save-match-data
    (let ((pos 0)
          matches)
      (while (string-match regexp string pos)
        (push (match-string 0 string) matches)
        (setq pos (match-end 0)))
      matches)))

; Sample URL
(setq urlreg "\\(?:http://\\)?www\\(?:[./#\+-]\\w*\\)+")
; Sample invocation
(re-seq urlreg (buffer-string))

occur普遍的な引数で呼び出すと、*Occur*ファイル名、行番号、ヘッダー情報なしで一致するものだけがバッファに読み込まれることに注意してください。キャプチャグループと組み合わせると、必要なパターンを抽出できます。

たとえば、次のC-u M-x occurコマンドを実行する\"\(.*\)\"と、収集するキャプチャグループを求めるプロンプトが表示され（デフォルト\1）、引用符で囲まれたすべての文字列のコンテンツが*Occur*バッファーに配置されます。

私はその質問に対するemacs lispの回答を投稿しています：https : //codegolf.stackexchange.com/a/44319/18848

同じ（while（検索）（印刷））構造を使用して、バッファ内の一致をリストにプッシュし、次のように返す関数に変更できます。

(defun matches-in-buffer (regexp &optional buffer)
  "return a list of matches of REGEXP in BUFFER or the current buffer if not given."
  (let ((matches))
    (save-match-data
      (save-excursion
        (with-current-buffer (or buffer (current-buffer))
          (save-restriction
            (widen)
            (goto-char 1)
            (while (search-forward-regexp regexp nil t 1)
              (push (match-string 0) matches)))))
      matches)))

s.elこれを使用すると短くなりますが、残念ながら、あまりにも多くの一致が得られます。

(defun all-urls-in-buffer ()
  (s-match-strings-all
   "\\(?:http://\\)?www\\(?:[./#+-]\\w*\\)+"
   (buffer-string)))

これで問題ない場合（URLの正規表現はとにかく完璧ではありません）、これは短くなる可能性があります。

なぜこれがコアに実装されていないと思うのかを言及させてください。単に効率上の理由で：コピー、リストの作成、リストの受け渡し、ガベージコレクションの必要はありません。代わりに、文字列全体をバッファとして保存し、整数の一致境界で動作します。occurたとえば、次のように 動作します。一度に1つの文字列に一致し、その一致をに挿入し*occur*ます。一度にすべての文字列に一致するわけではありません。それらをリストに入れ、リストをループして挿入し *occur*、リストとその文字列をガベージコレクションします。

(do (def x 1) (def x (+ 2 x)))Clojureで書かないのと同じように、デフォルトではElispを関数型言語のように振る舞わせるべきではありません。それがあったらそれが大好きですが、私たちは現時点で持っているものを正当化する必要があります。

プラグが許可される場合は、「m-buffer」ライブラリをご覧ください。

(m-buffer-match buffer "foo")

に一致するマーカーのリストを返しますfoo。