*コンパイル*ウィンドウを隠す

20

成功したときに編集ウィンドウが表示されるのは面倒です。それを自動的に削除する方法は？

それがうまくいかない場合でも見たいです。

window compilation

— フサイン
ソース

11

数年前、＃emacs IRCチャンネルで、私はずっと使ってきたこのコードを手に入れました。値「2秒」は、成功したコンパイルウィンドウが表示される時間を設定します。

; from enberg on #emacs
(setq compilation-finish-function
  (lambda (buf str)
    (if (null (string-match ".*exited abnormally.*" str))
        ;;no errors, make the compilation window go away in a few seconds
        (progn
          (run-at-time
           "2 sec" nil 'delete-windows-on
           (get-buffer-create "*compilation*"))
          (message "No Compilation Errors!")))))

— シャープ
ソース

14

（ライブラリ内のcompile.el）コードをすばやく見ると、フックの関数を使用して、表示されたバッファを強制終了または非表示にできるはずcompilation-finish-functionsです。これを行うには、次のようなものを使用します。

 (add-hook 'compilation-finish-functions (lambda (buf strg) (kill-buffer buf))

バッファを強制終了したくない場合は、次のようなものを使用します。

 (add-hook 'compilation-finish-functions
           (lambda (buf strg)
             (let ((win  (get-buffer-window buf 'visible)))
               (when win (delete-window win)))))

一般的に、このようなものにはおそらく既にフックが提供されているため、処理のこのような重要な場所にコードを簡単に添付できると想像できます。M-x apropos通常、コードを少し参照したり使用したりすると、すぐに通知されます。フックの名前は通常、-hookまたはで終わり-functionsます。

— ドリュー
ソース

2

興味のある人のために、このスレッドも関連しています。

/programming/11043004/emacs-compile-buffer-auto-close

クレジットは元の作者jpkottaにあります。彼の答えは次のとおりです。

コンパイルには以下を使用します。警告またはエラーがある場合はコンパイルバッファを保持し、それ以外の場合（1秒後に）埋め込みます。

(defun bury-compile-buffer-if-successful (buffer string)
  "Bury a compilation buffer if succeeded without warnings "
  (if (and
       (string-match "compilation" (buffer-name buffer))
       (string-match "finished" string)
       (not
        (with-current-buffer buffer
          (search-forward "warning" nil t))))
      (run-with-timer 1 nil
                      (lambda (buf)
                        (bury-buffer buf)
                        (switch-to-prev-buffer (get-buffer-window buf) 'kill))
                      buffer)))
(add-hook 'compilation-finish-functions 'bury-compile-buffer-if-successful)

— スワレンドゥビスワス
ソース

1

リンクだけで構成される回答を投稿しないでください。あなたの投稿が質問に答えるように、回答の重要な部分を投稿に含めてください。ソースとして、および詳細情報のためにリンクを提供します。詳細については、回答の作成に関するガイドラインをご覧ください。

— ジル 'SO-悪であるのをやめる'

私の答えを更新しました。

— スワーネンドゥビスワ

注意スタック所から誰か他の人の答えを引用しても大丈夫ですが、あなたが提供しなければならない適切な帰属作者名などを、。

— ジル「SO-悪であるのをやめる」

1

私は私のスニペットを持っています.emacs.d：

    (defcustom compilation-auto-quit-window-delay 1
      "Time in seconds before auto closing the window."
      :group 'compilation
      :type 'number)  

    (defun compilation-auto-quit-window-finish-function (buffer status)
      "Quit the *compilation* window if it went well."
      (let ((window (get-buffer-window buffer)))
        (when (and (equal status "finished\n")
                   (compilation-went-super-p))
          (run-with-timer
              (or compilation-auto-quit-window-delay 0) nil
            (lambda nil
              (when (and (window-live-p window)
                         (eq (window-buffer window)
                             buffer)
                         (not (eq (selected-window)
                                  window)))
                (save-selected-window
                  (quit-window nil window))))))))

    (define-minor-mode compilation-auto-quit-window
      "Automatically close the *compilation* window if it went well."
      :global t
      (cond (compilation-auto-quit-window
             (add-hook 'compilation-finish-functions
                       'compilation-auto-quit-window-finish-function))
            (t
             (remove-hook 'compilation-finish-functions
                          'compilation-auto-quit-window-finish-function))))

    (defun compilation-went-super-p (&optional buffer)
      "Return t, if no gotoable output appeared."
      (with-current-buffer (or buffer (current-buffer))
        (save-excursion
          (goto-char (point-min))
          (let (;; (compilation-skip-threshold 1)
                )
            (not (ignore-errors
                   (compilation-next-error 1)
                   t))))))

— ポリツァ
ソース