アジェンダビューなしで組織モードのアジェンダの生データを取得するにはどうすればよいですか？

Q：org-modeアジェンダビューを実際に作成せずに、アジェンダビューの生データを返すにはどうすればよいですか？

任意の日に自分の議題にアクセスしたいのですが。ただし、アジェンダビュー自体は作成しません。代わりに、その日org-modeのアジェンダビューに入るすべての要素を収集して並べ替え、それらを（理想的にはリストで）返して、さらに検査および操作できるようにします。

それがorg-agenda-list出発点になると思いました。ただし、その機能はもつれた獣であり、収集、並べ替え、および表示のプロセスが混在しているようです。そのため、私が求めている機能を提供する関連機能を単にどこかで見逃していると思います（希望ですか？）。

org-mode org-agenda

— ダン
ソース

以下に入るデータ抽出方法の凝縮例で*Org Agenda*正常機能を使用する場合、バッファをorg-agenda-list用いて、org-agenda-entry-typesなど:deadline、:scheduled、:timestamp、sexp、:deadline*、および:scheduled*。日付の範囲- beginおよびend-は、グレゴリオ暦のリスト形式である必要があり'(6 1 2015)ます。カスタマイズ可能なlet-boundオプションはorg-agenda-prefix-formatおよびorg-agenda-entry-typesです。この関数は、リストの形式で結果を返します。

(require 'calendar)
(require 'org)
(require 'org-agenda)
(require 'cl)

;; Portions of following code were extracted from:
;;   https://github.com/kiwanami/emacs-calfw written by Masashi Sakurai
;; Said code has been modified by @lawlist hereinbelow.
;;
(defun org-get-entries-fn (begin end)
"Return org schedule items between BEGIN and END.
USAGE:  (org-get-entries-fn '(6 1 2015) '(12 31 2020))"
  (unless
      (and
        (calendar-date-is-valid-p begin)
        (calendar-date-is-valid-p end))
    (let ((debug-on-quit nil))
      (signal 'quit '("One or both of your Gregorian dates are invalid."))))
  (let* (
      result
      (org-agenda-buffer nil) ;; prevent error from `org-compile-prefix-format'
      ;; The variable `org-agenda-only-exact-dates' is apparently not operational.
      (org-scheduled-past-days 0) ;; avoid duplicate entries for overdue items
      (org-agenda-prefix-format "• ")
      (org-agenda-entry-types '(:scheduled))
      (date-after
        (lambda (date num)
          "Return the date after NUM days from DATE."
          (calendar-gregorian-from-absolute
           (+ (calendar-absolute-from-gregorian date) num))))
      (enumerate-days
        (lambda (begin end)
          "Enumerate date objects between BEGIN and END."
          (when (> (calendar-absolute-from-gregorian begin)
                   (calendar-absolute-from-gregorian end))
            (error "Invalid period : %S - %S" begin end))
          (let ((d begin) ret (cont t))
            (while cont
              (push (copy-sequence d) ret)
              (setq cont (not (equal d end)))
              (setq d (funcall date-after d 1)))
            (nreverse ret)))) )
    (org-compile-prefix-format nil)
    (setq result
      (loop for date in (funcall enumerate-days begin end) append
        (loop for file in (org-agenda-files nil 'ifmode) append
          (progn
            (org-check-agenda-file file)
            (apply 'org-agenda-get-day-entries file date org-agenda-entry-types)))))
    result))

— 弁護士
ソース