リージョンやラインを右揃えする方法は？

私たちは、使用してテキストを中央にすることができますM-x center-regionし、M-o M-s。右揃えに似たものはありますか？

前の例：

Item 0: value                                                       |
Item 100: value                                                     |
Item 30: value                                                      |

後：

                                                       Item 0: value|
                                                     Item 100: value|
                                                      Item 30: value|
                                                       fill-column  ^

テキストを右揃えする最も簡単な方法は何ですか？

text-editing align

— マーク・カルポフ
ソース

Fillingの手動ノードによると、いくつかのfill関数はオプションのJUSTIFY引数を使用できます。したがって、たとえば、段落を右揃えで埋めるには、を使用できます(fill-paragraph 'right)。

(justify-current-line 'right)単線でも使用できます。

これらのオプションを頻繁に使用する場合は、次のような関数でそれらをラップし、これらの関数を選択したキーにバインドできます。

(defun right-justify-current-line ()
  "Right-justify this line."
  (interactive)
  (justify-current-line 'right))

(defun right-fill-paragraph ()
  "Fill paragraph with right justification."
  (interactive)
  (fill-paragraph 'right))

これは、の代わりとして使用できる関数ですfill-paragraph。さまざまな接頭辞を使用して、入力する段落で使用する正当化の種類を決定できます。

(defun fill-paragraph-dwim (&optional arg)
  "Fills the paragraph as normal with no prefix. With C-u,
right-justify.  With C-u C-u, center-justify.  With C-u C-u C-u,
full-justify."
  (interactive "p")
  (fill-paragraph (cond ((= arg 4)  'right)
                        ((= arg 16) 'center)
                        ((= arg 64) 'full))))

右揃えのときに塗りつぶしたくない場合は、次の関数を使用できます。これは、center-region関数から直接クリブされており、代わりに1行の変更で右揃えになっています。

(defun right-region (from to)
  "Right-justify each nonblank line starting in the region."
  (interactive "r")
  (if (> from to)
      (let ((tem to))
    (setq to from from tem)))
  (save-excursion
    (save-restriction
      (narrow-to-region from to)
      (goto-char from)
      (while (not (eobp))
    (or (save-excursion (skip-chars-forward " \t") (eolp))
        ;; (center-line))              ; this was the original code
        (justify-current-line 'right)) ; this is the new code
    (forward-line 1)))))

— ダン
ソース