メジャーモードバインディングをオーバーライドする方法

時々、私のグローバルキーバインドはメジャーモードによって上書きされます。簡単な例は、私のinitファイルの次の設定です

(global-set-key (kbd "C-j") 'newline-and-indent)

しかし、面倒なことに、このキーバインディングは、スクラッチバッファのデフォルトモードである「Lisp Interaction」メジャーモードによって隠されています。

メジャーモード（またはマイナーモード）がグローバルキーバインドを隠している状況にいるとき、どのように戻すことができますか？

注：私の質問ではありません「私はバインドすることができますどのようC-jにnewline-and-indentLispの対話で『』モード？」 クラッシュするキーマップや、メジャー/マイナーモードによって非表示になるユーザーキーバインドを処理する方法に関する、より一般的な回答に興味があります。

独自のマイナーモードを定義したくない場合は、同じソリューションに対して「ショートカット」アプローチもあります（最初の回答で説明します）。

あなたはインストールできuse-packageMelpaから利用可能なパッケージとのメーク使用bind-key*またはbind-keys*の一部だマクロbind-keyその船を持つパッケージをuse-package。

のドキュメントからbind-key.el：

;; If you want the keybinding to override all minor modes that may also bind
;; the same key, use the `bind-key*' form:
;;
;;   (bind-key* "<C-return>" 'other-window)

;; To bind multiple keys in a `bind-key*' way (to be sure that your bindings
;; will not be overridden by other modes), you may use `bind-keys*' macro:
;;
;;    (bind-keys*
;;     ("C-o" . other-window)
;;     ("C-M-n" . forward-page)
;;     ("C-M-p" . backward-page))

独自のマイナーモードとそのキーマップを定義し、他のすべてのモード（マイナー+メジャー）をオーバーライドすることができます。それがまさに私が自分のマイナーモードを書くことを選んだ理由です。

キーバインディングを使用してすべてのバインディングをオーバーライドする手順：

• 以下に示すように、独自のマイナーモードとキーマップを定義します。
• マイナーモードをグローバルにアクティブ化する
• (define-key my-mode-map (kbd "C-j") #'newline-and-indent)

同様に、マイナーモードで設定された他のキーバインディングは、他のモードのキーバインディングをオーバーライドします。

クリストファー・ウェロンズによるマイナーモードの書き方に関するブログ投稿を読むことを強くお勧めします。このブログに加えてnil、複数のメジャーモードとマイナーモードで複数のキーバインディングを設定する必要があるという煩わしさから、自分でマイナーモードを作成することになりました。

このアプローチを使用する最良の部分は、emacsのデフォルト構成でキーバインディングが何を行うかを確認する場合、マイナーモードを単にオフにすることです。その後、再び有効にすると、カスタムキーバインディングが返されます。

;; Main use is to have my key bindings have the highest priority
;; https://github.com/kaushalmodi/.emacs.d/blob/master/elisp/modi-mode.el

(defvar my-mode-map (make-sparse-keymap)
  "Keymap for `my-mode'.")

;;;###autoload
(define-minor-mode my-mode
  "A minor mode so that my key settings override annoying major modes."
  ;; If init-value is not set to t, this mode does not get enabled in
  ;; `fundamental-mode' buffers even after doing \"(global-my-mode 1)\".
  ;; More info: http://emacs.stackexchange.com/q/16693/115
  :init-value t
  :lighter " my-mode"
  :keymap my-mode-map)

;;;###autoload
(define-globalized-minor-mode global-my-mode my-mode my-mode)

;; https://github.com/jwiegley/use-package/blob/master/bind-key.el
;; The keymaps in `emulation-mode-map-alists' take precedence over
;; `minor-mode-map-alist'
(add-to-list 'emulation-mode-map-alists `((my-mode . ,my-mode-map)))

;; Turn off the minor mode in the minibuffer
(defun turn-off-my-mode ()
  "Turn off my-mode."
  (my-mode -1))
(add-hook 'minibuffer-setup-hook #'turn-off-my-mode)

(provide 'my-mode)

;; Minor mode tutorial: http://nullprogram.com/blog/2013/02/06/

グローバルバインディングでメジャーモードバインディングをオーバーライドするには、バインディングをnilメジャーモードに設定するだけです。

(define-key my-major-mode-map (kbd "C-j") nil)

グローバルバインディングを一般的なすべてのモードよりも優先させることはできません（そうでない場合はメジャーモードを使用しても意味がありません）が、最も重要なバインディングを使用して独自のマイナーモードを作成することでハッキングできます。その後、少なくともほとんどの（必ずしもすべてではない）モードよりも優先されます。

次のマクロを使用できます。

(defmacro expose-global-keybinding (binding map)
  `(define-key ,map ,binding (lookup-key (current-global-map) ,binding)))

(defmacro expose-bindings (map bindings)
  `(dolist (bnd ,bindings)
     (expose-global-keybinding (kbd bnd) ,map)))

編集：

以下の例を確認してください。

キーマップXがグローバルバインディングYをオーバーライドしている場合、次のように記述します。

(expose-bindings X '("Y"))

そして、オーバーライドは「元に戻されます」。