デーモンモード：起動時に対話型プロンプトを延期しますか？

（逆に、この質問はデーモンモードで起動して対話型ダイアログを非表示にする方法と同じではないことに注意してください。その質問は特定のプロンプトを表示させる原因を排除して提出者によって「回答」されたためです。）

まだ存在しないミニバッファに表示されるプロンプトへの回答を待って永遠にハングアップしないようにする一般的な方法があるかどうかを知りたいemacs --daemonです。

Emacsが起動シーケンスを完了するまでサーバーは起動しないため、emacsclientに接続してこれらのプロンプトに答えることはできません。（つまり、ALTERNATE_EDITORが空の文字列に設定されている場合emacsclient、サーバーが新しいデーモンを開始できないことがわかると、複数のEmacsデーモンがすべてスタックして待機killall emacsすることになります。）問題を解決する必要があります続行する前に。

Emacsを非デーモンモードで起動し、何を要求しているかを確認することで、起動時にプロンプ​​トを表示する各問題でwhack-a-moleを再生できますが、次のデーモンを停止できないため、解決策ではありません新しい理由でスタートアップにハングアップすることから。

例を挙げると、最初の再起動後のEmacsが古いEmacsからロックファイルを盗むことができるかどうかを知りたいときに、システムが再起動またはEmacsがクラッシュした後にハングする一般的な理由です。そのプロンプトが対話なしで常に「はい」と答えるようにアドバイスを作成することで、それを修正できました。ただし、前回のセッションの保存時に開いていたファイルの1つは、sudoまたはSSHパスワードを必要とするTRAMPファイルであったため、デーモンはパスワードプロンプトで待機しています。そこで、問題のあるファイルを削除するためにセッションファイルを（viまたはemacs -q！を使用して）手動で編集することで修正します。

そのため、起動時にセッションのロードを自動的に停止し、最初のemacsclientから手動で実行する必要があるコマンドに変更できます。しかし、バックグラウンドでセッションをロードしておらず、使用する準備が整うまでに準備が整っている場合、デーモンの目的はすべて失われます！

だから私が欲しいのは：

• （最良）残りの初期化を完了しながら、emacsclientを開くまでミニバッファープロンプトを延期する方法。
• （OK）noemacsclientが実行されていない限り、上記で説明したように、私がまだアドバイスしていないすべてのミニバッファープロンプトを返す方法があります。TRAMPバッファーがほとんど機能する限り、私はTRAMPバッファーでエラーが発生しても生き続けることができます。

これらの目標のいずれかを達成する方法はありますか？

私たちの議論では、これを実行しているXサーバーがないため、私の最初のソリューションは役に立たないことが明らかになりました。

以下では、テキストターミナルフレームで機能する2番目のソリューションを紹介します。

初期化にユーザー入力が必要な場合、avoid-initial-terminalEmacsで推奨される機能は、テキストターミナルフレームを開くまで待機します。そのフレームのミニバッファにプロンプ​​トが表示され、インタラクティブな応答を行うことができます。

コード関連の情報は、コード内のコメントとして提供されます。TODO独自の構成を挿入する場所を示す説明付きのマーカーがあります。現在、コードを検証するテストフォームがあります。

;; TODO: Do here configure the server if needed.

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;; Startup the server:
;; Analysis of read_from_minibuffer in src/minibuf.c and daemon_type in src/emacs.c
;; shows that daemon-initialized must have run before read-passwd / read-string
;; works on frames. Before it only works on stdin & stdout.
(server-start) ;;< early start
(let ((after-init-time before-init-time))
  (daemon-initialized)) ;; Finalize the daemon, 

(advice-add 'daemon-initialized :override #'ignore)
;;< Ignore `daemon-initialized' after initialization. It may only run once!
;; Now the background emacs is no longer marked as daemon. It just runs the server.

(defun prevent-server-start (&rest _ignore)
  "Prevent starting a server one time after `server-start' has been advised with this."
  (advice-remove 'server-start #'prevent-server-start))

(advice-add 'server-start :override #'prevent-server-start)

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;; Prepare waiting for a real terminal frame when user input is required:

(defun avoid-initial-terminal (fun &rest args)
  "Wait until we are no longer on \"intial-terminal\".
Afterwards run `fun' with frame on the other terminal selected."
  (message "Avoiding initial terminal. Terminal: %S" (get-device-terminal nil))
  (while (string-equal
      (terminal-name (get-device-terminal nil))
      "initial_terminal")
    (sleep-for 1))
  ;; (message "Selected frame: %S; Running %S with %S." (selected-frame) fun args)
  (apply fun args))

(advice-add 'read-string :around #'avoid-initial-terminal)

(advice-add 'read-passwd :around #'avoid-initial-terminal)

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;; TODO: Your initialization that is not daemon related
;; and may require user input:

;; Currently this is just a test.
(read-passwd "Passwd: ")

(read-string "String: ")

(y-or-n-p "y-or-n query")

テスト：Emacsバージョン：26.1

1）emacs --daemonコンソールで実行します。

2）emacsclient --tty別のコンソールで実行します。そこでパスワードと文字列を求められます。その後、y-or-npクエリに回答する必要もあります。

まさにあなたが求めているものではなく、おそらくあなたの元の問題の解決策：

emacs --daemonが、まだ存在しないミニバッファーに表示されるプロンプトへの応答を永遠に待つことを防ぐ一般的な方法があるかどうかを知りたいです。

デーモンが起動段階で発生する質問に答えるためのグラフィカルフレームを提供する場合、もう動けなくなることはありません。

以下のコードは、my-with-initial-frame利用可能な最初のディスプレイ（例：）でフレームを開く一般的なアドバイスを定義しています:0.0。

そのアドバイスのような照会コマンドに容易に追加することができy-or-n-p、またはread-passwdそれは、以下に示されているように、。

フレームを開くだけで、ユーザーインターフェイスでクエリに回答するかなり粗い可能性が得られます。ダイアログボックスを使用することもできますy-or-n-pが、特定のクエリコマンドに対して特別なソリューションが必要になります。それを避けたかった。

initファイルでそのコードを試す場合は、それが最初にあることを確認してください。

(when (daemonp)

  (defun my-with-initial-frame (&rest _)
    "Ensure a frame on display :0.0 and ignore args."
    (let* ((display-list (x-display-list))
           (display-re (and display-list (regexp-opt display-list)))
           (term (and display-re (cl-some (lambda (term) (and (string-match display-re (terminal-name term)) term)) (terminal-list))))
           (frame (and term (cl-some (lambda (frame) (and (frame-live-p frame) frame)) (frames-on-display-list term)))))
      (select-frame (or frame (make-frame-on-display (getenv "DISPLAY"))))))

  (message "Advising querying functions with `my-with-initial-frame'.")
  (advice-add 'y-or-n-p :before #'my-with-initial-frame)
  (advice-add 'read-passwd :before #'my-with-initial-frame))

テスト：

仮定：

DISPLAY環境変数を介してプログラムが接続できる実行中のxserverがあります。

xtermでの入力：

emacs --daemon

emacsclient --eval '(y-or-n-p "A")'

y-or-n-pクエリプロンプトでフレームが開きますA (y or n)。そのクエリに答えて、もう一度やり直してください。

emacsclient --eval '(y-or-n-p "B")'

B (y or n)同じフレームにプロンプトを表示する新しいクエリ。そのフレームを閉じます。たとえば、次のようにしC-x 5 0て再試行します。

emacsclient --eval '(y-or-n-p "C")'

クエリプロンプトで新しいフレームが開きますC (y or n)。

パスワード入力でも同じことができます。

プロンプトを延期することは一般的に難しいと思いますが、Emacsを変更してそのようなプロンプトがすぐにエラーを通知するようにするのはかなり簡単なはずです。

それだけでなく、体操をせずにこれらのプロンプトに答えることができない場合、それはバグとみなされると思うので、バグレポートを提出することをお勧めします。