2つ以上開いているときに2つのウィンドウを切り替える方法

シナリオ：複数（2つ以上）のウィンドウを開いています。そのうちの2つと積極的に協力しています。1つのコマンドで、あるウィンドウから別のウィンドウに、またその逆にジャンプするにはどうすればよいですか？

私はエースウィンドウを使います。素晴らしいですが、毎回ウィンドウ番号を押したくありません。next-window/ については知ってprev-windowいますが、これらは2つの異なるコマンドです。

私が探しているのは、別のウィンドウを選択したときに以前のウィンドウが何であったかを記憶し、そのウィンドウに戻るものです。繰り返し呼び出されると、最後の2つのウィンドウを切り替えますAlt- Tabスタイル。

どこを見ますか？

独自のコマンドを作成する1つの方法は、組み込みget-mru-window関数を使用することです。

例えば：

(defun my-flip-window ()
  (interactive)
  (let ((win  (get-mru-window nil nil t)))
    (when win (select-window win))))

これにより、現在選択されているウィンドウではない、現在のフレームで最も最近使用されたウィンドウが検索されます。

以下は、可視フレーム全体で機能するバリエーションです。

(defun my-flip-window ()
  (interactive)
  (let ((win  (get-mru-window 'visible nil t)))
    (when win
      (select-frame-set-input-focus (window-frame win))
      (select-window win))))

コメントで述べたように、ウィンドウが1つしかない場合（最新のバッファーに切り替える場合）に機能するバリエーションがあります。

(defun flip-window ()
  (interactive)
  (let ((win  (get-mru-window 'visible t t)))
    (if win
        (progn
          (select-frame-set-input-focus (window-frame win))
          (select-window win))
      (mode-line-other-buffer))))

を既に使用している場合はace-window、コマンドaw-flip-windowを使用して2つのウィンドウ間を前後に切り替えることができます。デフォルトでは、これはnace-windowにバインドされていますaw-dispatch-alist。

つまりn、ウィンドウ番号の代わりにace-windowを押してヒットすると、前のウィンドウに戻ります。aw-flip-window他のキーにバインドすることもできます。

これは、ace-windowで以前に選択されたウィンドウにのみ戻ることに注意してください。他のコマンドでウィンドウを頻繁に切り替える場合は、より一般的な解決策が必要になる場合があります。

簡単にテストされた、最後にアクセスしたウィンドウに切り替える簡単なコマンドを次に示します。

(defvar recent-window nil
  "The most recently visited window.")

(defun switch-to-recent-window ()
  "Switch to the most recently visited window, as stored in
`recent-window'."
  (interactive)
  (let ((current (car (window-list))))
    (if recent-window
        (select-window recent-window)
      (message (concat "No recent window selected, "
                       "so I'm setting this window "
                       "as the most recent.")))
    (setq recent-window current)))