defvarの再評価を強制するにはどうすればよいですか？

次を含むEmacs lispバッファーがあるとします。

(defvar foo 1)

eval-last-sexpまたはを呼び出すとeval-buffer、foo1にバインドされます。その後、このバッファーを編集して次のようにします。

(defvar foo 2)

eval-last-sexpまたeval-buffer、この行を再実行しないでくださいfoo。まだ1です。

このようなステートメントが複数あり、再評価されていない行を追跡する必要がある場合、これは特に困難です。

Emacsを再起動するだけ(require 'foo)で、それからを見てみましたが、古い.elcファイルをロードしないように注意する必要があります。

現在のファイルで定義されている変数と関数が、新しいEmacsインスタンスにコードを新たにロードするのと同じ状態にあることを、絶対に確実に確認するにはどうすればよいですか？

他の回答で説明したdefvarように、を使用eval-last-sexpしてフォームを評価してもデフォルト値はリセットされません。

代わりに、eval-defun（デフォルトC-M-xでinにバインドされemacs-lisp-modeた）を使用して、特別な例外として必要な動作を実装できます。

現在のdefunが実際にdefvarorの呼び出しである場合defcustom、この方法で評価すると、変数が既に他の値を持っている場合でも、初期値式を使用して変数がリセットされます。（通常、値が既に存在する場合は変更しないdefvarでdefcustomください。）

バッファの内容全体を評価する必要がある場合は、トップレベルのフォームを順番に調べeval-defun、それぞれを呼び出す関数を作成できます。このような何かが動作するはずです：

(defun my/eval-buffer ()
  "Execute the current buffer as Lisp code.
Top-level forms are evaluated with `eval-defun' so that `defvar'
and `defcustom' forms reset their default values."
  (interactive)
  (save-excursion
    (goto-char (point-min))
    (while (not (eobp))
      (forward-sexp)
      (eval-defun nil))))

他の答えが言うように、これはdefvarが機能する方法にすぎませんが、それを回避することができます、これは結局elispです。

必要に応じてdefvarの動作を一時的に再定義し、その間にリセットしたいパッケージをリロードできます。

ボディの評価中に、defvars値が常に再評価されるマクロを作成しました。

(defmacro my-fake-defvar (name value &rest _)
  "defvar impersonator that forces reeval."
  `(progn (setq ,name ,value)
          ',name))

(defmacro with-forced-defvar-eval (&rest body)
  "While evaluating, any defvars encountered are reevaluated"
  (declare (indent defun))
  (let ((dv-sym (make-symbol "old-defvar")))
    `(let ((,dv-sym (symbol-function 'defvar)))
       (unwind-protect
           (progn
             (fset 'defvar (symbol-function 'my-fake-defvar))
             ,@body)
         (fset 'defvar ,dv-sym)))))

使用例：

file_a.el

(defvar my-var 10)

file_b.el

(with-forced-defvar-eval
  (load-file "file_a.el")
  (assert (= my-var 10))
  (setq my-var 11)
  (assert (= my-var 11)
  (load-file "file_a.el")
  (assert (= my-var 10))

注：これは、defvarを再評価する目的でのみ使用する必要があります。再評価するときにdocstringを無視するだけです。マクロを変更して、docstringを適用する再評価をサポートすることもできますが、それはあなたにお任せします。

あなたの場合、あなたはできる

(with-forced-defvar-eval (require 'some-package))

しかし、elispを書く人がdefvarが指定どおりに動作することを期待していることを知っています.defvarを使用して定義し、init関数でsetqを設定して値を指定することができるため、意図しない変数をnil'ingする可能性がありますが、これはおそらくまれです。

代替実装

これを使用すると、defvarをグローバルに再定義し、新しいdefvar-always-reeval-valuesシンボルの値を変更してシンボルが定義されている場合でも、シンボルの値をINIT-VALUE引数に設定するかどうかを制御できます。

;; save the original defvar definition
(fset 'original-defvar (symbol-function 'defvar))

(defvar defvar-always-reeval-values nil
  "When non-nil, defvar will reevaluate the init-val arg even if the symbol is defined.")

(defmacro my-new-defvar (name &optional init-value docstring)
  "Like defvar, but when `defvar-always-reeval-values' is non-nil, it will set the symbol's value to INIT-VALUE even if the symbol is defined."
  `(progn
     (when defvar-always-reeval-values (makunbound ',name))
     (original-defvar ,name ,init-value ,docstring)))

;; globally redefine defvar to the new form
(fset 'defvar (symbol-function 'my-new-defvar))

defvar評価され、あなたが指定した正確に何をしてされています。ただし、defvar初期値のみを設定します。

オプションの引数INITVALUEが評価され、SYMBOLの値がvoidの場合にのみ、SYMBOLの設定に使用されます。

したがって、目的を達成するには、再評価する前に変数のバインドを解除する必要があります。たとえば、

(makunbound 'foo)

またはsetq値を設定するために使用します、例えば

(defvar foo nil "My foo variable.")
(setq foo 1)

ここでdocstringを指定する必要がない場合は、defvar完全にスキップできます。

本当にdefvarこれを使用して自動的にバインドを解除したい場合defvarは、現在のバッファー（またはリージョン、最後のsexpなど）で呼び出しを見つける関数を作成する必要があります。makunboundそれぞれを呼び出します。そして、実際の評価を行います。

次のマクロはeval-defun、特定のバッファの領域を評価する必要がなくなるように、そのサポート関数にトレースして変更することにより作成されました。関連するスレッドで式を文字列に変換するのに助けが必要だったので、@ Tobiasが助けになりました。不完全な関数をマクロに変換する方法を教えてくれました。先にeval-sexp-add-defvars進む必要はないと思いますelisp--eval-defun-1が、誰かがそれが重要だと思ったら、教えてください。

;;; EXAMPLE:
;;;   (defvar-reevaluate
;;;     (defvar undo-auto--this-command-amalgamating "hello-world"
;;;     "My new doc-string."))

(defmacro defvar-reevaluate (input)
"Force reevaluation of defvar."
  (let* ((string (prin1-to-string input))
        (form (read string))
        (form (elisp--eval-defun-1 (macroexpand form))))
    form))

問題は、回線が再評価されていないことではありません。問題はdefvar、変数とそのデフォルト値を定義することです。変数が既に存在する場合、デフォルト値を変更しても現在の値は変更されません。残念ながら、setq値を更新する変数ごとにを実行する必要があると思います。

これはやり過ぎかもしれませんがfoo、新しいデフォルト値に簡単に更新できるようにしたい場合は、このようにファイルを更新できます。

(defvar foo 2)
(setq foo 2)

ただし、コードの2つの場所でデフォルト値を維持する必要があります。これを行うこともできます：

(makunbound 'foo)
(defvar foo 2)

しかし、foo他の場所で宣言されている可能性がある場合、対処するいくつかの副作用があるかもしれません。