Mxコンパイルの永続的な環境

実行M-x compileすると、新しいサブシェルが生成され、コンパイルコマンドが実行されます。コンパイルコマンドが戻るとすぐに、シェルプロセスは強制終了されます。これがほとんどの場合に望ましい理由はわかりますが、現在は役に立たない状況にあります。

現在、専用のビルド環境で作業しています。コンパイラーを実行する前に、ビルドをセットアップするためにいくつかの初期手順を実行する必要があります。環境が持続する限り、セットアップ手順を1回だけ実行する必要があります。しかし、それを使用M-x compileすると、コンパイルまたは再コンパイルするたびに手順を実行する必要があることを意味します。

バックグラウンドで持続するサブシェルを生成する方法はありますか？一つM-x compileとM-x gdb彼らはシェルプロセスを実行する必要があるたびに使用することができますか？

動機：

xcc特別なプラットフォーム用のCコードをビルドするプログラム（これをと呼びます）があります。コードをビルドするには、まずプロンプトxccから始めtcshます。

$ xcc

プログラムの読み込みに10秒以上かかり、インタラクティブプロンプトでコマンドを入力できます

xcc>> add target myprogram
xcc>> set source myprogram $PROJDIR/src/
xcc>> set includes myprogram $PROJDIR/include/
xcc>> set type myprogram primitive
xcc>> set inputs myprogram int8,int8
xcc>> set outputs myprogram fix16,fix16
xcc>> build myprogram

上記の手順はカスタムマクロに組み込むことができるbuildmyprog.macroので、シェルから直接、またはemacsから実行できます。M-x compile

$ xcc buildmyprog.macro

このアプローチの主な問題は、xccコンパイルが始まるまでにプログラムのロードに10秒かかることです。私はすべての時間、私は私が実行し始めていることをコンパイルし、余分な10秒待っているの疲れ十分に得xccにansi-term別のバッファでは。コードを変更して保存した後、ansi-termバッファに切り替えて実行します

xcc>> build myprogram

これは問題なく動作しますが、そのバッファーに切り替えるたびに、「プッシュするだけでF7コンパイルコマンドが既に実行中のインスタンスに送信されたら、すばらしいと思いませんxccか？」

emacsを開始する前に、シェルでセットアップを行うことができますか？compileサブシェルは、Emacsを経由してその祖父母から環境を継承する必要があります。

次に、eshellまたはのように、Emacs内で実際のシェルを使用しansi-termます。compileコンパイルに使用する必要がありますが、任意のコマンドの実行に使用できます。

コンパイルコマンドでは可能ではないと思いますが、何か足りないことがあります。それ以外の場合は、すべてのセットアップ手順をシェルスクリプトに入れ、そのスクリプトをで実行できますM-x compile。

可能な解決策は、永続的なインタープリターを専用バッファー（バッファーのようなものです*compilation*が、基礎となるプロセスが戻らない場所）に常駐させることです。次に、recompile-likeコマンドを使用して、定義済みのコンパイルコマンドをインタープリターに送信し、結果を表示できます。

以下はそのような戦略の暫定的な実装です。このpersistent-compileコマンドは、プロセスの初期化（最初に呼び出されたとき、またはプレフィックス引数を使用したとき）と再コンパイル（インタープリタープロセスが既に稼働している場合）の両方を処理します。コンパイル結果は*persistent-compilation*バッファに表示されcompilation-shell-minor-mode、通常のcompilation-mode機能を利用してエラー間を移動できます。

次に、使用例と結果の*persistent-compilation*バッファの内容を示します。

1. M-xpersistent-compileRET /bin/bashRET FOO=barRET echo $FOORET

   $ FOO=bar
   $ echo $FOO
   bar
   $
   

2. M-xpersistent-compileRET

   $ echo $FOO
   bar
   $
   

次のコードはあまりテストされていません。たとえば、前回のコンパイルが終了する前に再コンパイルしようとするとどうなるかわかりません。

(defvar persistent-compile-interpreter "/bin/bash"
  "Interpreter to be used for persistent compilations.")

(defvar persistent-compile-init ""
  "Initialization command for persistent compilations.")

(defvar persistent-compile-command "make -k"
  "Compilation command for persistent compilations.")

;; Local variable in the persistent compilation buffer
(defvar persistent-compile--next-action)

(defun persistent-compile (&optional edit-command)
  "(Re-)run a persistent compilation.

The first time a persistent compilation is run, the user is asked
for an interpreter, an initialization command and a compilation
command.
The interpreter is started and optionally set up with the
initialization command.  The compilation command is then sent to
the interpreter.

All subsequent recompilations are sent to the same,
already-initialized interpreter, so as to keep the customized
environment.

If EDIT-COMMAND is non-nil, the user can edit the
parameters (interpreter, initialization command and compilation
command) and the interpreter is restarted."
  (interactive "P")
  (when (or edit-command
            (null (get-buffer "*persistent-compilation*"))
            (not persistent-compile-interpreter)
            (not persistent-compile-init)
            (not persistent-compile-command))
    (setq persistent-compile-interpreter (read-from-minibuffer "Interpreter: "
                                                               persistent-compile-interpreter)
          persistent-compile-init        (read-from-minibuffer "Initialization command: "
                                                               persistent-compile-init)
          persistent-compile-command     (read-from-minibuffer "Command: "
                                                               persistent-compile-command)))
  (with-current-buffer (get-buffer-create "*persistent-compilation*")
    (if (and edit-command
             (get-buffer-process (current-buffer)))
        ;; Kill an existing process and schedule for a recompilation with
        ;; the new parameters
        (progn
          (set-process-sentinel
           (get-buffer-process (current-buffer))
           (lambda (process event)
             (persistent-recompile nil)))
          (kill-process (get-buffer-process (current-buffer))))

      (if (not (get-buffer-process (current-buffer)))
          ;; Start and initialize a new process
          (progn
            (erase-buffer)
            (make-comint-in-buffer "persistent-compile" (current-buffer) persistent-compile-interpreter)
            (compilation-shell-minor-mode 1)
            (make-local-variable 'persistent-compile--next-action)
            (setq persistent-compile--next-action 'persistent-compile--initialize)
            (add-hook 'comint-output-filter-functions 'persistent-compile--at-prompt))

        ;; Run command
        (erase-buffer)
        (persistent-compile--send-command)))))

(defun persistent-compile--at-prompt (&optional output)
  (when persistent-compile--next-action
    ;; There is probably a better way of checking whether we are
    ;; just after a prompt, but I didn't find it...
    (let ((p1 (point))
          (p2 (save-excursion (comint-bol))))
      (unless (= p1 p2)
        (let ((action persistent-compile--next-action))
          (setq persistent-compile--next-action nil)
          (funcall action))))))

(defun persistent-compile--initialize ()
  (setq persistent-compile--next-action 'persistent-compile--send-command)
  (display-buffer (current-buffer))
  (insert persistent-compile-init)
  (comint-send-input nil t))

(defun persistent-compile--send-command ()
  (display-buffer (current-buffer))
  (insert persistent-compile-command)
  (comint-send-input nil t))