複数の列をコピーして貼り付けたいことがよくあります。たとえば、1つの列を貼り付けます

line one
line two
line three

次に、その後ろにある別の列をヤンクできるようにしたいと思います。私のキルバッファが次のものであると仮定します：

added to one
added to two
added to three

次を取得するには、どのコマンドを呼び出す必要がありますか。

line one added to one
line two added to two
line three added to three

更新

Emacsの四角形の機能を使用するとかなり役立ちますが、それでも最適ではありません。たとえば、グラフィカルモードでEmacsを使用していて、外部プログラムからヤンクしている場合、つまりOSからコピーアンドペースト機能を使用している場合、キルバッファには長方形のメタ情報がないため、長方形のヤンクは機能しません。もう1つの問題は、さまざまな内部幅を持つ列がある場合です。

short line                        *
a much larger line which goes on
short line again

長方形のヤンクをしたい場合は、マークされたスポット（*）にポインターを置く必要があります。これは3行で簡単ですが、最初の列の最も外側の端にポインターを配置していることを確認するのは非常に面倒な場合があります。

以下は、現在の行から開始して、後続の各行の終わりに現在のキルの各行をヤンクするために使用できる1回限りのコマンドです。

(defun yank-append-lines (&optional without-space)
  "Yank each line of the current kill at the end of each subsequent line.

A space will be added between each line unless WITHOUT-SPACE which can
be passed in via a prefix arg."
  (interactive "P")
  (save-excursion
    (let ((lines (split-string (current-kill 0) "\n")))
      (dolist (line lines)
        (goto-char (line-end-position))
        (unless without-space
          (just-one-space))
        (insert line)
        (unless (zerop (forward-line))
          (insert "\n"))))))

実装はかなり簡単です。を取り、current-kill行ごとに分割します。次に、分割線ごとに、分割線の最後に移動し、スペースを挿入し、線を挿入して、1行前に移動します。

これは、行をバッファー内のある場所からバッファーの別の部分の行の終わりに移動する繰り返し可能なマクロでも実行できます。