org-modeで*をエスケープして太字のフォント化を防ぐにはどうすればよいですか

*shrug*組織モードのように書くと、太字のテキストとして自動的にフォント化されます。どうすればそれを防ぐことができ*shrug*ますか。つまり、エクスポート時に実際に逐語的に表示されますか？

編集：

私はまだ太字フォントを使用できるようにしたい（太字テキストのデフォルトのスター構文を変更する必要はありません）、そして組織ファイルがどのファイル形式にエクスポートされるかは問題ではありません。例えば、HTMLだけでなくMarkdownでも動作します書き出す。

これはいくつかの重要な要素であるため、太字で書かれています。しかし、何か他のもののために、私はアイデア* shrug *を持っていません。

この答えは、emacs-org-mode GNUリストでのゼロ幅のスペース文字の代わりにorg-entity（C-h i g (org) Special symbols）を使用するという集合的な提案の後、インスピレーションを得ています（他の答えはこちらで提案しました）。\ast{}

以下は、ユーザーがさまざまなシンボルの組織エンティティを覚える必要のない一般的なソリューションです。ユーザーが行うと、組織エンティティー（使用可能な場合）を挿入しC-u SYMBOLます。作品のためC-u *、C-u /、C-u =、など

(defun modi/org-entity-get-name (char)
  "Return the entity name for CHAR. For example, return \"ast\" for *."
  (let ((ll (append org-entities-user
                    org-entities))
        e name utf8)
    (catch 'break
      (while ll
        (setq e (pop ll))
        (when (not (stringp e))
          (setq utf8 (nth 6 e))
          (when (string= char utf8)
            (setq name (car e))
            (throw 'break name)))))))

(defun modi/org-insert-org-entity-maybe (&rest args)
  "When the universal prefix C-u is used before entering any character,
    insert the character's `org-entity' name if available.

    If C-u prefix is not used and if `org-entity' name is not available, the
    returned value `entity-name' will be nil."
  ;; It would be fine to use just (this-command-keys) instead of
  ;; (substring (this-command-keys) -1) below in emacs 25+.
  ;; But if the user pressed "C-u *", then
  ;;  - in emacs 24.5, (this-command-keys) would return "^U*", and
  ;;  - in emacs 25.x, (this-command-keys) would return "*".
  ;; But in both versions, (substring (this-command-keys) -1) will return
  ;; "*", which is what we want.
  ;; http://thread.gmane.org/gmane.emacs.orgmode/106974/focus=106996
  (let ((pressed-key (substring (this-command-keys) -1))
        entity-name)
    (when (and (listp args) (eq 4 (car args)))
      (setq entity-name (modi/org-entity-get-name pressed-key))
      (when entity-name
        (setq entity-name (concat "\\" entity-name "{}"))
        (insert entity-name)
        (message (concat "Inserted `org-entity' "
                         (propertize entity-name
                                     'face 'font-lock-function-name-face)
                         " for the symbol "
                         (propertize pressed-key
                                     'face 'font-lock-function-name-face)
                         "."))))
    entity-name))

;; Run `org-self-insert-command' only if `modi/org-insert-org-entity-maybe'
;; returns nil.
(advice-add 'org-self-insert-command :before-until #'modi/org-insert-org-entity-maybe)

ユーザタイプは、ときにC-u *、\ast{}挿入され、メッセージ下エコー領域に表示され、

シンボル*に 'org-entity' \ ast {}を挿入しました。

場合org-pretty-entitiesに設定されているt、上記挿入\ast{}される表示として*。

がorg-entity文字Xに存在せず、ユーザーがC-u Xを実行する場合、Xは単純に4回挿入されます（C-u通常のように）。

ZERO WIDTH SPACE unicode charを使用する

最初のアスタリスクの前または2番目のアスタリスクの後にゼロ幅のスペース文字（以下のスニペットで[ZWS]で示される）を追加することにより、太字の強調解析に失敗する可能性があります。

私のテストでは、以下のスニペットの両方がHTMLに正常にエクスポートされました。

• [ZWS] 最初のアスタリスクの前

  This is some *bold* test and this is ​[ZWS]*not bold*.
  

• [ZWS] 2番目のアスタリスクの後

  This is some *bold* test and this is *not bold*​[ZWS].
  

を実行すると、ZERO WIDTH SPACE（ユニコード名）を入力できますC-x 8 RET 200b RET。
私はこれを非常に頻繁に使用するため、これをにバインドしましたC-x 8 0。

更新

emacs-org-modeメーリングリストの議論によると、エスケープに非ASCII文字を使用することは推奨されていません。代わりにorg-entities、該当する場合に使用する必要があります。私もそれに同意し、挿入を非常に簡単にするこの別のソリューションを考え出しましたorg-entities（C-u *この場合）。

逐語的に言えば、エクスポートされたLaTeXで実際にマークアップを使用することを意味する場合は、単にを使用できます=*shrug*=。ただし、としてエクスポートするだけで*shrug*、これを常に実行する場合は、filtersをお勧めします。ただし、の一部のインスタンスでのみこれが必要な場合は、*shrug*@ wvxvwによって提案された代替手段を使用する必要があります。マクロを使用してこれをきれいに行うことができます。次に例を示します。

フィルター

(defun my-bold (contents backend info)
  (when (org-export-derived-backend-p backend 'latex)
    (replace-regexp-in-string "\\`\\\\textbf{\\(.+\\)}"
                              "\\\\ast{}\\1\\\\ast{}" contents)))

(add-to-list 'org-export-filter-bold-functions 'my-bold)

本質的に、上記のフィルターは\textbf{..}トランスコードされた文字列内のマークアップを探し、\ast{}..\ast{}内部でラップされたものを変更せずにそれをに置き換え{..}ます。正規表現と置換文字列のテストは行っていないため、間違いがある可能性がありますが、アイデアは得られます。同様に、他のバックエンドをカバーするために、次のような追加のスニペットを含めることができます。

(when (org-export-derived-backend-p backend 'html)
   (replace-regexp-in-string "<b>\\(.+\\)</b>" "\&#2a;\\1\&#2a;" contents))

上記の正規表現についても同じ注意が必要です。

マクロ

組織ソース：

#+macro: nobold @@latex:\ast{}$1\ast{}@@ @@html:&#2a;$1&#2a;@@

This text is *bold* this is nobold{{{not}}}

次のようにLaTeXにエクスポートします。

This text is \textbf{bold} this is \ast{}not\ast{}

およびHTMLとして：

This text is <b>bold</b> this is  &#2a;not&#2a;

もちろん、必要な数のバックエンドをマクロに追加できます。

編集： Kaushalがコメントで指摘しているように、この場合、ラテックスのエクスポートスニペットはオプションです。ただしorg-entities、Orgソースでベアラテックスを識別するためのリストと特定のルールを追跡するのはかなり難しいので、ベアラテックスが関係する場合は常に使用することを好みます。

注意：

• フィルタの例はテストされていませんが、
• 私は知らないHTMLので、それぞれのビットにいくつかの間違いがあるかもしれません。

これは変数org-emphasis-alistによって制御され、簡単に変更できます。

• 太字のテキストの上にポイントを置き、コマンドwhat-c​​ursor-position C-u C-x =を使用して顔を見つけますorg-emphasis。プロパティがあることに注意してください。
• customize-grouporg-emphasisの呼び出しと検索
• org-emphasis-alistが表示され、テキストをマークするためのさまざまなオプションが表示されます。
• *に対応するエントリを削除します
• 変更を適用し、org-modeまたはemacsを再起動します