同じ値を複数の変数に割り当てますか？

時には、複数の変数に同じ値を設定する必要があります。

Pythonでは、私はできる

f_loc1 = f_loc2 = "/foo/bar"

しかし、elispでは、私は書いています

(setq f_loc1 "/foo/bar" f_loc2 "/foo/bar")

"/foo/bar"一度だけ使用してこれを達成する方法があるかどうか疑問に思っていますか？

setq 値を返すので、次のことができます。

(setq f-loc1 (setq f-loc2 "/foo/bar"))

に依存したくない場合は、次を使用します：

(setq f-loc1 "/foo/bar" f-loc2 f-loc1)

個人的に私は後者を避け、代わりに書くでしょう：

(setq f-loc1 "/foo/bar"
      f-loc2 f-loc1)

あるいは

(setq f-loc1 "/foo/bar")
(setq f-loc2 f-loc1)

そして、最初のアプローチは、実際に意図を強調するような特別な状況でのみ使用するか、代替案が2番目のアプローチを使用するなどの場合にのみ使用しますprogn。

上記があなたを幸せにするなら、ここで読むのをやめることができます。しかし、これはあなたや他の人にマクロを乱用しないよう警告する良い機会だと思います。

最後に、setq-every「これはLispであり、できるからです」のようなマクロを作成するのは魅力的ですが、そうしないことを強くお勧めします。あなたはそれをすることでほとんど利益を得ません：

(setq-every value a b)
   vs
(setq a (setq b value))

しかし同時に、他の読者がコードを読んで何が起こるかを確認することをはるかに困難にします。setq-everyさまざまな方法で実装でき、他のユーザー（未来を含む）は、それを使用するコードを見ただけでは、著者がどちらを選択したかを知ることができません。[私はもともとここでいくつかの例を作成しましたが、それらは誰かによって皮肉であり、暴言と見なされていました。]

あなたが見るたびにその精神的なオーバーヘッドに対処することができます、setq-everyまたはあなたはただ1つの余分なキャラクターと一緒に暮らすことができます。（少なくとも2つの変数のみを設定する必要がある場合ですが、一度に3つ以上の変数を同じ値に設定しなければならなかったことを思い出せません。あなたのコードで。）

一方、このマクロを本当に半ダース以上使用するのであれば、追加のインダイレクションは価値があるかもしれません。たとえば--when-let、dash.elライブラリのようなマクロを使用します。それは私のコードで最初に遭遇した人にとって難しくなりますが、それはほんの数回以上使用されるため、理解の困難を克服する価値があり、少なくとも私の意見では、コードがより読みやすくなります。

同じことがに当てはまると主張することもできますがsetq-every、この特定のマクロが数回以上使用される可能性は非常に低いと思います。経験則としては、マクロの定義（doc-stringを含む）が、マクロを使用するよりも多くのコードを追加すると、マクロが過剰になりすぎる可能性が高くなります（ただし、逆は必ずしも当てはまりません）。

やりたいことをするマクロ

ある種の演習として：

(defmacro setq-every (value &rest vars)
  "Set every variable from VARS to value VALUE."
  `(progn ,@(mapcar (lambda (x) (list 'setq x value)) vars)))

今すぐ試してください：

(setq-every "/foo/bar" f-loc1 f-loc2)

仕組み

人々は（コメントによると）どのように機能するのか興味があるので、ここに説明があります。マクロの書き方を実際に学ぶには、優れたCommon Lispの本を選んでください（そう、Common Lispは、Emacs Lispでも同じことができますが、Common Lispはもう少し強力で、より良い本があります、IMHO）。

マクロは生のコードで動作します。マクロは引数を評価しません（関数とは異なります）。ですから、ここでは未評価でvalueありvars、マクロのコレクションは単なるシンボルです。

progn複数のsetqフォームを1つにグループ化します。このこと：

(mapcar (lambda (x) (list 'setq x value)) vars)

setqOPの例を使用して、フォームのリストを生成するだけです。

((setq f-loc1 "/foo/bar") (setq f-loc2 "/foo/bar"))

ご覧のとおり、フォームはバッククォート形式の内側にあり、プレフィックスとしてカンマが付いています ,。逆引用符で囲まれたフォーム内では、すべてが通常どおり引用されますが、, 一時的に「mapcar有効化」評価されるため、マクロ展開時に全体が評価されます。

最後にsを使用して@リストから外側の括弧を削除するsetqため、次のようになります。

(progn
  (setq f-loc1 "/foo/bar")
  (setq f-loc2 "/foo/bar"))

マクロはソースコードを任意に変換できますが、素晴らしいことではありませんか？

警告

このマクロは基本的に次のように展開されるため、小さな警告があります。最初の引数は数回評価されます。

(progn
  (setq f-loc1 "/foo/bar")
  (setq f-loc2 "/foo/bar"))

ここに変数または文字列がある場合は問題ありませんが、次のように記述した場合：

(setq-every (my-function-with-side-effects) f-loc1 f-loc2)

次に、関数が複数回呼び出されます。これは望ましくない場合があります。once-only（MMTパッケージで利用可能）を使用し て修正する方法は次のとおりです。

(defmacro setq-every (value &rest vars)
  "Set every variable from VARS to value VALUE.

VALUE is only evaluated once."
  (mmt-once-only (value)
    `(progn ,@(mapcar (lambda (x) (list 'setq x value)) vars))))

そして、問題はなくなりました。

Lispでシンボルを使用および操作できるため、シンボルのリストを単純にループして使用できますset。

(dolist (var '(foo bar baz)) (set var 10))

(mapc (lambda (var) (set var 10)) '(foo bar baz))

(loop for var in '(foo bar baz) do (set var 11))

(--each '(foo bar baz) (set it 10))