引用符内のシェル変数の強調表示

vimでは、次のドキュメントにより、$PWD2行目と3行目が2つの異なる方法で色付けされます。

#/bin/sh
echo "Current Directory: $PWD"
echo 'Current Directory: $PWD'

の最初のインスタンスは$PWD、それが含まれる文字列の残りの部分とは異なる色になります。これにより、変数がリテラルテキストとして扱われるのではなく、展開されることを明確に視覚的に示します。対照的に、の2番目のインスタンスは$PWD、文字列の残りの部分と同じ色になります。これは、単一引用符によって文字列として扱われるためです。

このタイプの「シェル引用符認識」を提供する既存のemacsモードはありますか？

以下のコードは、正規表現の代わりに関数を使用してフォントロックルールを使用し$VARます。この関数(syntax-ppss)は、これを決定するために使用されます。

フォントロックルールは、prependフラグを使用して、既存の文字列の強調表示の上に自分自身を追加します。（多くのパッケージtがこれに使用していることに注意してください。残念ながら、これは既存の強調表示のすべての側面を上書きしますprepend。

(defun sh-script-extra-font-lock-is-in-double-quoted-string ()
  "Non-nil if point in inside a double-quoted string."
  (let ((state (syntax-ppss)))
    (eq (nth 3 state) ?\")))

(defun sh-script-extra-font-lock-match-var-in-double-quoted-string (limit)
  "Search for variables in double-quoted strings."
  (let (res)
    (while
        (and (setq res
                   (re-search-forward
                    "\\$\\({#?\\)?\\([[:alpha:]_][[:alnum:]_]*\\|[-#?@!]\\)"
                    limit t))
             (not (sh-script-extra-font-lock-is-in-double-quoted-string))))
    res))

(defvar sh-script-extra-font-lock-keywords
  '((sh-script-extra-font-lock-match-var-in-double-quoted-string
     (2 font-lock-variable-name-face prepend))))

(defun sh-script-extra-font-lock-activate ()
  (interactive)
  (font-lock-add-keywords nil sh-script-extra-font-lock-keywords)
  (if (fboundp 'font-lock-flush)
      (font-lock-flush)
    (when font-lock-mode
      (with-no-warnings
        (font-lock-fontify-buffer)))))

適切なフックに最後の関数を追加することで、これを使用して呼び出すことができます。例えば：

(add-hook 'sh-mode-hook 'sh-script-extra-font-lock-activate)

次の方法で@Lindydancerの回答を改善しました。

• sh-script-extra-font-lock-is-in-double-quoted-string一度だけ使用されたため、関数をインライン化しました
• 変数のエスケープは機能します。
• 数値変数（$10、$1など）が強調表示されます。

コードを破る

(defun sh-script-extra-font-lock-match-var-in-double-quoted-string (limit)
  "Search for variables in double-quoted strings."
  (let (res)
    (while
        (and (setq res (progn (if (eq (get-byte) ?$) (backward-char))
                              (re-search-forward
                               "[^\\]\\$\\({#?\\)?\\([[:alpha:]_][[:alnum:]_]*\\|[-#?@!]\\|[[:digit:]]+\\)"
                               limit t)))
             (not (eq (nth 3 (syntax-ppss)) ?\")))) res))

(defvar sh-script-extra-font-lock-keywords
  '((sh-script-extra-font-lock-match-var-in-double-quoted-string
     (2 font-lock-variable-name-face prepend))))

(defun sh-script-extra-font-lock-activate ()
  (interactive)
  (font-lock-add-keywords nil sh-script-extra-font-lock-keywords)
  (if (fboundp 'font-lock-flush)
      (font-lock-flush)
    (when font-lock-mode (with-no-warnings (font-lock-fontify-buffer)))))