Pythonで関数の2つの引数を転置するには？

Python関数の呼び出しで2つの引数を交換するにはどうすればよいですか？

pointこれらの2つの引数の間にスペースを置いた場合：

self.assertEqual(json.loads(some.data), json_data)

そしてM-t（transpose-words）、私は得ます：

self.assertEqual(json.loads(some.json), data_data)

一方、CMt（transpose-sexps）では、次のようになります。

self.assertEqual(json.loadsjson_data, (some.data))

私が欲しいのは：

self.assertEqual(json_data, json.loads(some.data))

それを行うコマンドはありますか？

これも私が長い間持ちたいと思っていたもので、ここに取り組む動機が見つかりました。おそらくそれほど堅牢ではありませんが、最初の試行では、私が試したケースをカバーしているようです：

(defun my/calculate-stops ()
  (save-excursion
    (let ((start
           (condition-case e
               (while t (backward-sexp))
             (error (point))))
          stops)
      (push start stops)
      (condition-case e
          (while t
            (forward-sexp)
            (when (looking-at "\\s-*,")
              (push (point) stops)))
        (error (push (point) stops)))
      (nreverse stops))))

(defun my/transpose-args ()
  (interactive)
  (when (looking-at "\\s-") (backward-sexp))
  (cl-loop with p = (point)
           with previous = nil
           for stop on (my/calculate-stops)
           for i upfrom 0
           when (<= p (car stop)) do
           (when previous
             (let* ((end (cadr stop))
                    (whole (buffer-substring previous end))
                    middle last)
               (delete-region previous end)
               (goto-char previous)
               (setf middle (if (> i 1) (- (car stop) previous)
                              (string-match "[^, \\t]" whole 
                                            (- (car stop) previous)))
                     last (if (> i 1) (substring whole 0 middle)
                            (concat (substring whole (- (car stop) previous) middle)
                                    (substring whole 0 (- (car stop) previous)))))
               (insert (substring whole middle) last)))
           (cl-return)
           end do (setf previous (car stop))))

私は、そのバリエーションを使用して、transpose-sexpsコンマで区切られたものを記述および転置する場合、または単に通常の場合を検索しますtranspose-sexps。また、カーソルを前にドラッグする代わりにそのままにします。これは少し異なりますが、個人的には好きです。

(defun my-transpose-sexps ()
  "If point is after certain chars transpose chunks around that.
Otherwise transpose sexps."
  (interactive "*")
  (if (not (looking-back "[,]\\s-*" (point-at-bol)))
      (progn (transpose-sexps 1) (forward-sexp -1))
    (let ((beg (point)) end rhs lhs)
      (while (and (not (eobp))
                  (not (looking-at "\\s-*\\([,]\\|\\s)\\)")))
        (forward-sexp 1))
      (setq rhs (buffer-substring beg (point)))
      (delete-region beg (point))
      (re-search-backward "[,]\\s-*" nil t)
      (setq beg (point))
      (while (and (not (bobp))
                  (not (looking-back "\\([,]\\|\\s(\\)\\s-*" (point-at-bol))))
        (forward-sexp -1))
      (setq lhs (buffer-substring beg (point)))
      (delete-region beg (point))
      (insert rhs)
      (re-search-forward "[,]\\s-*" nil t)
      (save-excursion
        (insert lhs)))))

SMIEを使用するモードでtranspose-sexpは、その場合は正しく動作するはずです。中置記号（別名「セパレーター」）が,（または;）ではなく単語（例：）の場合でも、失敗しandます。

だから、私の意見では、そのためのコマンドがtranspose-sexpあり、これが正しく機能しない場合は、バグと見なします（ただし、バグがあり、修正に時間がかかり、優先度が低い可能性があるため、しないでください） t息を止める）。これを修正する方法はforward-sexp-function、「カンマが表示されたら、引数全体をジャンプする」ことを知っている関数に設定することです。