mu4e-複数のアカウント

私はmu4eEmacsの電子メールに使用していますが、現在は1つのメールアカウントに対してのみ構成されており、異なる受信トレイを表示するようにキーを設定しています。mu4eを使用して複数の電子メールアカウントを管理する方法を疑問に思いますか？

2つのアカウントでmu4eを使用しています。各アカウントには独自のmaildirがあります。

~/Mail
|
+---- work
|
`---- private

マニュアルには、アカウントを選択するためのサンプル関数が付属しています。

(defun my-mu4e-set-account ()
  "Set the account for composing a message."
  (let* ((account
          (if mu4e-compose-parent-message
              (let ((maildir (mu4e-message-field mu4e-compose-parent-message :maildir)))
                (string-match "/\\(.*?\\)/" maildir)
                (match-string 1 maildir))
            (completing-read (format "Compose with account: (%s) "
                                     (mapconcat #'(lambda (var) (car var))
                                                my-mu4e-account-alist "/"))
                             (mapcar #'(lambda (var) (car var)) my-mu4e-account-alist)
                             nil t nil nil (caar my-mu4e-account-alist))))
         (account-vars (cdr (assoc account my-mu4e-account-alist))))
    (if account-vars
        (mapc #'(lambda (var)
                  (set (car var) (cadr var)))
              account-vars)
      (error "No email account found"))))

;; ask for account when composing mail
(add-hook 'mu4e-compose-pre-hook 'my-mu4e-set-account)

それが機能するには、my-mu4e-account-alist次のものも必要です。

(defvar my-mu4e-account-alist
  '(("private"
     (user-mail-address  "private@domain.net")
     (user-full-name     "My Name")
     (mu4e-sent-folder   "/private/Sent Items")
     (mu4e-drafts-folder "/private/Drafts")
     (mu4e-trash-folder  "/private/Deleted Items")
     (mu4e-refile-folder "/private/Archive"))
    ("work"
     (user-mail-address  "work@domain.net")
     (mu4e-sent-folder   "/work/Sent Items")
     (mu4e-drafts-folder "/work/Drafts")
     (mu4e-trash-folder  "/work/Deleted Items")
     (mu4e-refile-folder "/work/Archives"))))

(setq mu4e-user-mail-address-list
      (mapcar (lambda (account) (cadr (assq 'user-mail-address account)))
              my-mu4e-account-alist))

jすべてのmaildirがのサブディレクトリである限り、メールフォルダー間で簡単に切り替えることができますmu4e-maildir。

私は実際にのために、より複雑な機能を使用していますmu4e-trash-folderし、mu4e-refile-folder別の上に1つのmaildirからのメールを移動避けるために、しかし、上記の情報は、複数のアカウントを使用するのに十分であるべきです。

私は、できる限り少なくしたい2つの異なるアカウントを使用しています。

offlineimapは2つのアカウントで構成され、1つはメールを~/.maildir-workもう1 つに配信し~/.maildir-homeます。

mu4eの私の構成では、新しいコンテキストメカニズムを使用しています。

(setq mu4e-contexts
      `( ,(make-mu4e-context
           :name "home"
           :match-func (lambda (_) (string-equal "home" (mu4e-context-name mu4e~context-current)))
           :enter-func '()
           :leave-func (lambda () (mu4e-clear-caches))
           :vars '((mu4e-maildir . "~/.maildir-home")
                   (mu4e-mu-home . "~/.mu-home")
                   (mu4e-get-mail-command . "offlineimap -a Home")
                    ...))
         ,(make-mu4e-context
           :name "work"
           :match-func (lambda (_) (string-equal "work" (mu4e-context-name mu4e~context-current)))
           :enter-func '()
           :leave-func (lambda () (mu4e-clear-caches))
           :vars '((mu4e-maildir . "~/.maildir-work")
                   (mu4e-mu-home . "~/.mu-work")
                   (mu4e-get-mail-command . "offlineimap -a Work")
                   ...))))

私はMagnusに非常によく似たセットアップを使用して(mu4e-quit)おり、それを追加したかっただけで、再起動せずにアカウントをクリーンアップするのにうまく機能します。実際のメカニズム：

(defun mail-gmail ()
  (interactive)
  (setenv "MAILDIR" "/Users/foo/Maildir/gmail")
  (setenv "MU_HOME" "/Users/foo/.mu/gmail")
  (setq mu4e-maildir "/Users/foo/Maildir/gmail")
  (setq user-mail-address "...")
  (mu4e-quit))