宣言型パイプラインを使用して動的な並列アクションを適切に実現する方法は？

現在、ディレクトリ内のすべてのファイルを検索し、見つかったすべてのファイルに対して並列タスクを開始する必要がある実装が必要になります。

宣言的なパイプラインを使用してこれを達成することは可能ですか？

pipeline {
    agent any
    stages {
        stage("test") {
            steps {
                dir ("file_path") {
                    // find all files with complete path
                    parallel (
                        // execute parallel tasks for each file found.
                        // this must be dynamic
                        }
                    }
                }
            }
        }
    }
}

次のコードでそれを解決できました：

pipeline {
    agent { label "master"}
    stages {
        stage('1') {
            steps {
                script {
                    def tests = [:]
                    for (f in findFiles(glob: '**/html/*.html')) {
                        tests["${f}"] = {
                            node {
                                stage("${f}") {
                                    echo '${f}'
                                }
                            }
                        }
                    }
                    parallel tests
                }
            }
        }       
    }
}

Declarative Pipelineスペース内に滞在したい場合にもこれは機能します

// declare our vars outside the pipeline
def tests = [:]
def files

pipeline {
    agent any
    stages {
        stage('1') {
            steps {
                script {
                    // we've declared the variable, now we give it the values
                    files = findFiles(glob: '**/html/*.html')
                    // Loop through them
                    files.each { f ->
                        // add each object from the 'files' loop to the 'tests' array
                        tests[f] = {
                            // we're already in the script{} block, so do our advanced stuff here
                            echo f.toString()
                        }
                    }
                    // Still within the 'Script' block, run the parallel array object
                    parallel tests
                }
            }
        }       
    }
}

任意のGroovyを使用できるため、スクリプト化されたパイプラインを使用する方がはるかに簡単ですが、findFilesステップを使用して宣言的パイプラインでこれを行うことができるはずです。

動的なビルドステップは、他のジョブを呼び出すときなど、一部のビルドステップで問題を引き起こす可能性があることに注意してください。

pipeline {
    stages {
        stage('Test') {
            steps {
                script {
                    def tests = [:]
                    for (f in findFiles(glob: '**/html/*.html')) {
                        // Create temp variable, otherwise the name will be the last value of the for loop
                        def name = f
                        tests["${name}"] = {
                            build job: "${name}"
                        }
                    }
                    parallel tests
                }
            }
        }       
    }
}