すべてのテーブルからすべての制約を削除するにはどうすればよいですか？

SQL Serverデータベース内のすべてのテーブルから、すべての既定の制約、チェック制約、一意の制約、主キー、および外部キーをすべて削除したい。からすべての制約名を取得する方法を知っていますsys.objectsが、どのようにALTER TABLE部品に入力しますか？

sys.tables.object_id = sys.objects.parent_object_idこれらのオブジェクトタイプに参加することにより、この情報を簡単に導出できます。

DECLARE @sql NVARCHAR(MAX);
SET @sql = N'';

SELECT @sql = @sql + N'
  ALTER TABLE ' + QUOTENAME(s.name) + N'.'
  + QUOTENAME(t.name) + N' DROP CONSTRAINT '
  + QUOTENAME(c.name) + ';'
FROM sys.objects AS c
INNER JOIN sys.tables AS t
ON c.parent_object_id = t.[object_id]
INNER JOIN sys.schemas AS s 
ON t.[schema_id] = s.[schema_id]
WHERE c.[type] IN ('D','C','F','PK','UQ')
ORDER BY c.[type];

PRINT @sql;
--EXEC sys.sp_executesql @sql;

PRINT目を光らせるためだけにあります- 多くの制約がある場合、8Kに制限されているため、スクリプト全体が表示されない場合があります。そのような場合、実行前にスクリプトを検証する他の方法については、このヒントを参照してください。

出力に満足したら、のコメントを外しますEXEC。

受け入れられた答えから始め、動的SQLで完全なSQLステートメントを構築するのではなく、whileループを使用するように構造を変更しました。これにはいくつかの理由があります。

クエリは、大きな@sql変数には格納されません。この実装により、出力のロギング目的でドロップされる各制約の印刷が可能になります。私の単体テストでは、実行が少し速くなったようです。

Set NoCount ON

Declare @schemaName varchar(200)
set @schemaName=''
Declare @constraintName varchar(200)
set @constraintName=''
Declare @tableName varchar(200)
set @tableName=''

While exists
(   
    SELECT c.name
    FROM sys.objects AS c
    INNER JOIN sys.tables AS t
    ON c.parent_object_id = t.[object_id]
    INNER JOIN sys.schemas AS s 
    ON t.[schema_id] = s.[schema_id]
    WHERE c.[type] IN ('D','C','F','PK','UQ')
    and t.[name] NOT IN ('__RefactorLog', 'sysdiagrams')
    and c.name > @constraintName
)

Begin   
    -- First get the Constraint
    SELECT 
        @constraintName=min(c.name)
    FROM sys.objects AS c
    INNER JOIN sys.tables AS t
    ON c.parent_object_id = t.[object_id]
    INNER JOIN sys.schemas AS s 
    ON t.[schema_id] = s.[schema_id]
    WHERE c.[type] IN ('D','C','F','PK','UQ')
    and t.[name] NOT IN ('__RefactorLog', 'sysdiagrams')
    and c.name > @constraintName

    -- Then select the Table and Schema associated to the current constraint
    SELECT 
        @tableName = t.name,
        @schemaName = s.name
    FROM sys.objects AS c
    INNER JOIN sys.tables AS t
    ON c.parent_object_id = t.[object_id]
    INNER JOIN sys.schemas AS s 
    ON t.[schema_id] = s.[schema_id]
    WHERE c.name = @constraintName

    -- Then Print to the output and drop the constraint
    Print 'Dropping constraint ' + @constraintName + '...'
    Exec('ALTER TABLE [' + @schemaName + N'].[' + @tableName + N'] DROP CONSTRAINT [' + @constraintName + ']')
End

Set NoCount OFF