SQL Serverの1つが最近次のエラーを報告しました：
DATE/TIME: 2/25/2013 9:15:14 PM
DESCRIPTION: No catalog entry found for partition ID 9079262474267394048
in database 2. The metadata is inconsistent. Run DBCC CHECKDB to check for
a metadata corruption.
15分以内にサーバーに接続して実行しました。
SELECT name
FROM sys.databases
WHERE database_id = 2;
これは「tempdb」を返しました。次に実行しました：
DBCC CHECKDB ('tempdb') WITH NO_INFOMSGS, TABLERESULTS;結果は返されず、影響を受けるデータベースに問題がないことを示しています。
データベースが破損すると、上記のエラーメッセージが表示されDBCC CHECKDB、問題が報告されないのはなぜですか。ページのチェックサム計算が失敗し、そのページを参照しているオブジェクトを削除できないと疑われるページがマークされた場合、私は推測しますが、私は間違っているはずです。
ページが「疑わしい」とマークされたら、疑わしいとマークしたり、修正したり、再利用したり、またはDBCC CHECKDB問題のページの問題を報告しないものにマークしたりするにはどうすればよいですか？
編集：2013-02-27 13:24
おもしろいことに、私は#tempテーブルが原因であると想定して、TempDBで破損を再現しようとしました。
ただし、SINGLE_USERTempDBでオプションを設定できないため、を使用DBCC WRITEPAGEしてページを破損することはできず、TempDBで破損を強制することはできません。
代わりにDBCC WRITEPAGE、データベースをオフラインに設定し、16進エディターを使用してdbファイル内のランダムなバイトを変更することができます。もちろん、データベースエンジンはTempDBをオフラインで実行できないため、TempDBでも機能しません。
インスタンスを停止すると、TempDBは次回の起動時に自動的に再作成されます。したがって、それでもうまくいきません。
誰かがこの腐敗を再現する方法を考えることができるなら、私はさらなる研究をしたいと思っています。
破損したページを修正できないという仮説をテストするためにDROP TABLE、テストデータベースを作成し、次のスクリプトを使用してページを破損させてから、影響を受けるテーブルを削除しようとしました。その結果、テーブルを削除できませんでした。RESTORE DATABASE Testdb PAGE = ''...影響を受けるページを回復するために私はしなければなりませんでした。問題のページの他の部分に変更を加えた場合、おそらくページはDROP TABLEまたはで修正された可能性がありますTRUNCATE table。
/* ********************************************* */
/* ********************************************* */
/* DO NOT USE THIS CODE ON A PRODUCTION SYSTEM!! */
/* ********************************************* */
/* ********************************************* */
USE Master;
GO
ALTER DATABASE test SET RECOVERY FULL;
BACKUP DATABASE Test
TO DISK = 'Test_db.bak'
WITH FORMAT
, INIT
, NAME = 'Test Database backup'
, SKIP
, NOREWIND
, NOUNLOAD
, COMPRESSION
, STATS = 1;
BACKUP LOG Test
TO DISK = 'Test_log.bak'
WITH FORMAT
, INIT
, NAME = 'Test Log backup'
, SKIP
, NOREWIND
, NOUNLOAD
, COMPRESSION
, STATS = 1;
GO
ALTER DATABASE test SET SINGLE_USER;
GO
USE Test;
GO
IF EXISTS (SELECT name FROM sys.key_constraints WHERE name = 'PK_temp')
ALTER TABLE temp DROP CONSTRAINT PK_temp;
IF EXISTS (SELECT name FROM sys.default_constraints
WHERE name = 'DF_temp_testdata')
ALTER TABLE temp DROP CONSTRAINT DF_temp_testdata;
IF EXISTS (SELECT name FROM sys.tables WHERE name = 'temp')
DROP TABLE temp;
GO
CREATE TABLE temp
(
tempID INT NOT NULL CONSTRAINT PK_temp PRIMARY KEY CLUSTERED IDENTITY(1,1)
, testdata uniqueidentifier CONSTRAINT DF_temp_testdata DEFAULT (NEWID())
);
GO
/* insert 10 rows into #temp */
INSERT INTO temp default values;
GO 10
/* get some necessary parameters */
DECLARE @partitionID bigint;
DECLARE @dbid smallint;
DECLARE @tblid int;
DECLARE @indexid int;
DECLARE @pageid bigint;
DECLARE @offset INT;
DECLARE @fileid INT;
SELECT @dbid = db_id('Test')
, @tblid = t.object_id
, @partitionID = p.partition_id
, @indexid = i.index_id
FROM sys.tables t
INNER JOIN sys.partitions p ON t.object_id = p.object_id
INNER JOIN sys.indexes i on t.object_id = i.object_id
WHERE t.name = 'temp';
SELECT TOP(1) @fileid = file_id
FROM sys.database_files;
SELECT TOP(1) @pageid = allocated_page_page_id
FROM sys.dm_db_database_page_allocations(@dbid, @tblid, null, @partitionID, 'LIMITED')
WHERE allocation_unit_type = 1;
/* get a random offset into the 8KB page */
SET @offset = FLOOR(rand() * 8192);
SELECT @offset;
/* 0x75 below is the letter 't' */
DBCC WRITEPAGE (@dbid, @fileid, @pageid, @offset, 1, 0x74, 1);
SELECT * FROM temp;
Msg 824, Level 24, State 2, Line 36
SQL Server detected a logical consistency-based I/O error: incorrect checksum
(expected: 0x298b2ce9; actual: 0x2ecb2ce9). It occurred during a read of page
(1:1054) in database ID 7 at offset 0x0000000083c000 in file 'C:\SQLServer
\MSSQL11.MSSQLSERVER\MSSQL\DATA\Test.mdf'. Additional messages in the SQL
Server error log or system event log may provide more detail. This is a
severe error condition that threatens database integrity and must be
corrected immediately. Complete a full database consistency check
(DBCC CHECKDB). This error can be caused by many factors; for more
information, see SQL Server Books Online.
この時点でデータベースエンジンから切断されるので、再接続して続行します。
USE Test;
DBCC CHECKDB WITH NO_INFOMSGS, TABLERESULTS;
破損はここで報告されます。
DROP TABLE temp;
Msg 824, Level 24, State 2, Line 36
SQL Server detected a logical consistency-based I/O error: incorrect checksum
(expected: 0x298b2ce9; actual: 0x2ecb2ce9). It occurred during a read of page
(1:1054) in database ID 7 at offset 0x0000000083c000 in file 'C:\SQLServer
\MSSQL11.MSSQLSERVER\MSSQL\DATA\Test.mdf'. Additional messages in the SQL
Server error log or system event log may provide more detail. This is a
severe error condition that threatens database integrity and must be
corrected immediately. Complete a full database consistency check
(DBCC CHECKDB). This error can be caused by many factors; for more
information, see SQL Server Books Online.
破損はここで報告され、DROP TABLE失敗します。
/* assuming ENTERPRISE or DEVELOPER edition of SQL Server,
I can use PAGE='' to restore a single page from backup */
USE Master;
RESTORE DATABASE Test PAGE = '1:1054' FROM DISK = 'Test_db.bak';
BACKUP LOG Test TO DISK = 'Test_log_1.bak';
RESTORE LOG Test FROM DISK = 'Test_log.bak';
RESTORE LOG Test FROM DISK = 'Test_log_1.bak';
＃2を編集して、要求された@@ VERSION情報を追加します。
SELECT @@VERSION;戻り値：
Microsoft SQL Server 2012 (SP1) - 11.0.3000.0 (X64)
Oct 19 2012 13:38:57
Copyright (c) Microsoft Corporation
Enterprise Evaluation Edition (64-bit) on Windows NT 6.2 <X64>
(Build 9200: )
これは評価版であることを知っています。EnterpriseEditionのキーがあり、まもなくエディションのアップグレードが行われます。
-T 3609は、開始時にtempdbを保持します（文書化されていませんが、既知です）