SQL Server 2008 R2データベースをいくつかの展開されたプログラムで使用しています。
質問：データベース内のすべてのテーブルについて、各テーブルが消費する領域を表示し、論理領域とディスク領域を区別する簡単な方法はありますか？
SSMS（Management Studio）を使用している場合、データベースに表示されるストレージプロパティは167 MBであり、3 MBが「利用可能」です（約適切なサイズですが、3 MBが利用可能かどうか心配です-これは心配する限界です） 、十分なディスク容量があることを知っているとしたら？）
各テーブルにドリルダウンできますが、それを行うには永遠にかかります。
独自のクエリを記述してテストできることはわかっていますが、これを行う簡単な（組み込み？）方法が既にあるかどうかを知りたいです。
回答:
それはスタックオーバーフローで答えられました：
SELECT
t.NAME AS TableName,
s.Name AS SchemaName,
p.rows AS RowCounts,
SUM(a.total_pages) * 8 AS TotalSpaceKB,
SUM(a.used_pages) * 8 AS UsedSpaceKB,
(SUM(a.total_pages) - SUM(a.used_pages)) * 8 AS UnusedSpaceKB
FROM
sys.tables t
INNER JOIN
sys.indexes i ON t.OBJECT_ID = i.object_id
INNER JOIN
sys.partitions p ON i.object_id = p.OBJECT_ID AND i.index_id = p.index_id
INNER JOIN
sys.allocation_units a ON p.partition_id = a.container_id
LEFT OUTER JOIN
sys.schemas s ON t.schema_id = s.schema_id
WHERE
t.NAME NOT LIKE 'dt%'
AND t.is_ms_shipped = 0
AND i.OBJECT_ID > 255
GROUP BY
t.Name, s.Name, p.Rows
ORDER BY
t.Name
@Nelsonにリンクされ、コピーされたクエリは不正確です。インデックス付きビュー、フルテキストインデックス、XMLインデックスなどを無視します。
をsp_spaceused介して実行せずにすべてを含むクエリが必要な場合sp_MSForEachTableは、すでに2つのバリエーション（1つはDBA.StackExchangeに、もう1つはStackOverflowに）を投稿しているので、ここにはコピーしません。
各テーブル/インデックス付きビューごと：sp_spaceused-SQLのすべてのテーブルのサイズをGBで測定する方法
楽しみのために、ここにnateirvinの回答のレポートと同じデータを生成するクエリがあります
create table #disk_usage
(
name varchar(128)
,rows varchar(20)
,reserved varchar(20)
,data varchar(20)
,index_size varchar(20)
,unused varchar(20)
);
exec sp_msforeachtable 'insert into #disk_usage exec sp_spaceused [?]'
select SCHEMA_NAME(st.schema_id) + '.' + du.name 'Table Name'
,du.rows '# Records'
,du.reserved 'Reserved (KB)'
,du.data 'Data (KB)'
,du.index_size 'Indexes (KB)'
,du.unused 'Unused (KB)'
from #disk_usage du
left join sys.tables st
on du.name = st.name
order by cast(left(reserved, len(reserved) - 3) as bigint) desc;
drop table #disk_usage
私は本当に嫌いなので、レポートの結果を生成し、HTMLテーブルとしてフォーマットし、電子メールとして送信するクエリを作成しました。レポートの背景色を一致させることは、読者の練習問題として残しておきます。
declare @subject nvarchar(25) = 'Disk Usage by Top Tables';
declare @recipients nvarchar(25) = 'mailbox@example.com';
create table #disk_usage
(
name varchar(128)
,rows varchar(20)
,reserved varchar(20)
,data varchar(20)
,index_size varchar(20)
,unused varchar(20)
);
exec sp_msforeachtable 'insert into #disk_usage EXEC sp_spaceused [?]'
declare @body nvarchar(max) =
'<table cellspacing="0">
<thead>
<tr>
<th>Table Name</th>
<th># Rows</th>
<th>Reserved</th>
<th>Data</th>
<th>Indexes</th>
<th>Unused</th>
</tr>
</thead>
';
set @body = @body + cast (
(select '<td style="border: 1px solid black; padding: 2px">' + SCHEMA_NAME(s.schema_id) + '.' + t.name + '</td>'
,'<td style="border: 1px solid black; padding: 2px">' + rtrim(ltrim(t.rows)) + ' Rows </td>' -- for some reason this was generating a bunch of extra white space and I'm not going to bother to figure out why
,'<td style="border: 1px solid black; padding: 2px">' + t.reserved + '</td>'
,'<td style="border: 1px solid black; padding: 2px">' + t.data + '</td>'
,'<td style="border: 1px solid black; padding: 2px">' + t.index_size + '</td>'
,'<td style="border: 1px solid black; padding: 2px">' + t.unused + '</td>'
from #disk_usage t
left join sys.tables s
on t.name = s.name
order by cast(left(reserved, len(reserved) - 3) as bigint) desc
for xml path ('tr'))
as nvarchar(max));
set @body = replace(replace(@body, '<', '<'), '>', '>')
set @body = @body + '</table>'
exec msdb.dbo.sp_send_dbmail
@profile_name='A Database Mail Profile On The Target Server',
@recipients=@recipients,
@subject=@subject,
@body=@body,
@body_format='HTML'
drop table #disk_usage