ステップ1：通知を受け取るサービスとそのキューを作成します。
use msdb;
go
create queue dbm_notifications_queue;
create service dbm_notification_service
on queue dbm_notifications_queue
([http://schemas.microsoft.com/SQL/Notifications/PostEventNotification]);
go
create event notification dbm_notifications
on server
for database_mirroring_state_change
to service N'dbm_notification_service', N'current database';
go
私がを使用していることに注意してくださいmsdb。これは偶然ではありません。サーバーレベルのイベント通知はそこから送信されるmsdbため、でも反対側の会話エンドポイント（ターゲット）を作成msdbすると、宛先サービスとキューもにデプロイする必要があることを意味しますmsdb。
ステップ2：イベント通知処理手順を作成します。
use msdb;
go
create table dbm_notifications_errors (
incident_time datetime not null,
session_id int not null,
has_rolled_back bit not null,
[error_number] int not null,
[error_message] nvarchar(4000) not null,
[message_body] varbinary(max));
create clustered index cdx_dbm_notifications_errors
on dbm_notifications_errors (incident_time);
go
create table mirroring_alerts (
alert_time datetime not null,
start_time datetime not null,
processing_time datetime not null,
database_id smallint not null,
database_name sysname not null,
[state] tinyint not null,
[text_data] nvarchar(max),
event_data xml not null);
create clustered index cdx_mirroring_alerts
on mirroring_alerts (alert_time);
go
create procedure dbm_notifications_procedure
as
begin
declare @dh uniqueidentifier, @mt sysname, @raw_body varbinary(max), @xml_body xml;
begin transaction;
begin try;
receive top(1)
@dh = conversation_handle,
@mt = message_type_name,
@raw_body = message_body
from dbm_notifications_queue;
if N'http://schemas.microsoft.com/SQL/Notifications/EventNotification' = @mt
begin
set @xml_body = cast(@raw_body as xml);
-- shred the XML and process it accordingly
-- IMPORTANT! IMPORTANT!
-- DO NOT LOOK AT sys.database_mirroring
-- The view represents the **CURRENT** state
-- This message reffers to an **EVENT** that had occured
-- the current state may or may no be relevant for this **PAST** event
declare @alert_time datetime
, @start_time datetime
, @processing_time datetime = getutcdate()
, @database_id smallint
, @database_name sysname
, @state tinyint
, @text_data nvarchar(max);
set @alert_time = @xml_body.value (N'(//EVENT_INSTANCE/PostTime)[1]', 'DATETIME');
set @start_time = @xml_body.value (N'(//EVENT_INSTANCE/StartTime)[1]', 'DATETIME');
set @database_id = @xml_body.value (N'(//EVENT_INSTANCE/DatabaseID)[1]', 'SMALLINT');
set @database_name = @xml_body.value (N'(//EVENT_INSTANCE/DatabaseName)[1]', 'SYSNAME');
set @state = @xml_body.value (N'(//EVENT_INSTANCE/State)[1]', 'TINYINT');
set @text_data = @xml_body.value (N'(//EVENT_INSTANCE/TextData)[1]', 'NVARCHAR(MAX)');
insert into mirroring_alerts (
alert_time,
start_time,
processing_time,
database_id,
database_name,
[state],
text_data,
event_data)
values (
@alert_time,
@start_time,
@processing_time,
@database_id,
@database_name,
@state,
@text_data,
@xml_body);
end
else if N'http://schemas.microsoft.com/SQL/ServiceBroker/Error' = @mt
begin
set @xml_body = cast(@raw_body as xml);
DECLARE @error INT
, @description NVARCHAR(4000);
WITH XMLNAMESPACES ('http://schemas.microsoft.com/SQL/ServiceBroker/Error' AS ssb)
SELECT @error = CAST(@xml_body AS XML).value('(//ssb:Error/ssb:Code)[1]', 'INT'),
@description = CAST(@xml_body AS XML).value('(//ssb:Error/ssb:Description)[1]', 'NVARCHAR(4000)');
insert into dbm_notifications_errors(
incident_time,
session_id,
has_rolled_back,
[error_number],
[error_message],
[message_body])
values (
getutcdate(),
@@spid,
0,
@error,
@description,
@raw_body);
end conversation @dh;
end
else if N'http://schemas.microsoft.com/SQL/ServiceBroker/EndDialog' = @mt
begin
end conversation @dh;
end
commit;
end try
begin catch
declare @xact_state int = xact_state(),
@error_number int = error_number(),
@error_message nvarchar(4000) = error_message(),
@has_rolled_back bit = 0;
if @xact_state = -1
begin
-- Doomed transaction, it must rollback
rollback;
set @has_rolled_back = 1;
end
else if @xact_state = 0
begin
-- transaction was already rolled back (deadlock?)
set @has_rolled_back = 1;
end
insert into dbm_notifications_errors(
incident_time,
session_id,
has_rolled_back,
[error_number],
[error_message],
[message_body])
values (
getutcdate(),
@@spid,
@has_rolled_back,
@error_number,
@error_message,
@raw_body);
if (@has_rolled_back = 0)
begin
commit;
end
end catch
end
go
Service Brokerプロシージャの記述は、ありふれたコードではありません。特定の基準に従う必要があり、流砂地域に迷い込むのは非常に簡単です。このコードはいくつかの良い習慣を示しています：
- メッセージのデキューと処理をトランザクションでラップします。明らかです。
- 受信したメッセージタイプを必ず確認してください。適切なサービスブローカープロシージャは、ダイアログをその側から終了することによって適切に処理し
Error、EndDialogメッセージを送信する必要があります。そうしないと、ハンドルリーク（sys.conversation_endpoints増大）が発生します
- メッセージがRECEIVEによってデキューされたかどうかを常に確認してください。一部のサンプル
RECEIVEは、後でcheck @@ rowcountを実行します。このサンプルコードはメッセージ名チェックに依存し（メッセージがない場合はNULLメッセージタイプ名を意味します）、そのケースを暗黙的に処理します。
- 処理エラーテーブルを作成します。SSBがアクティブ化された手順のバックグラウンドの性質により、メッセージがトレースなしで単に消えてしまう場合、エラーのトラブルシューティングが非常に困難になります。
さらに、このコードは、当面のタスク（DBMの監視）に関して、いくつかの適切な実践コードも実行します。
post_time（通知がいつ送信されたか？）、start_time（通知をトリガーしたアクションがいつ開始されたか？）、processing_time（通知がいつ処理されたか？）を区別します。post_timeとstart_time同一または非常に近い可能性が高いですがprocessing_time、から数秒、数時間、数日離れることがありpost_timeます。監査のための興味深いものは通常post_timeです。- 以来
post_timeとprocessing_time異なっている、それも通知にタスクを監視DBM手順を活性化したことは明白であるべきで見て何のビジネスを持っていないsys.database_mirroringビュー。このビューには、処理の瞬間の現在の状態が表示されます。これは、イベントに関連する場合と関連しない場合があります。イベントがポストされてから長い時間（メンテナンスダウンタイムを考えて）処理が発生する場合、問題は明白ですが、DBMが状態を非常に速く変更し、2つ（またはそれ以上）のイベントを行（これは頻繁に発生します）：この状況では、投稿したコードのように、イベントが発生したときにイベントを監査しますが、現在の最終的な状態を記録します。そのような監査を読むと、後で非常に混乱する可能性があります。
- 常に元のXMLイベントを監査します。このようにして、監査テーブルの列に「細断」されなかった情報についてこのXMLを後でクエリできます。
手順3：プロシージャをキューにアタッチします。
alter queue dbm_notifications_queue
with activation (
status=on,
procedure_name = [dbm_notifications_procedure],
max_queue_readers = 1,
execute as owner);