x86-64マシンコード、44バイト
（同じマシンコードは32ビットモードでも機能します。）
@Daniel Scheplerの答えは、このための開始点だったが、これは少なくとも一つの新しいアルゴリズムの考え方（同じ考えのより良いゴルフだけではなく）がありますのためのASCIIコード'B'（1000010）をし、'X'（1011000）でマスキングした後、16と2を与えます0b0010010。
したがって、10進数（先頭のゼロ以外の数字）と8進数（後の文字'0'がより小さい）を除外した後'B'、base = c & 0b0010010を設定して数字ループにジャンプするだけです。
x86-64 System Vで呼び出し可能としてunsigned __int128 parse_cxx14_int(int dummy, const char*rsi); 、unsigned __int128結果の上位半分からEDX戻り値を抽出しtmp>>64ます。
.globl parse_cxx14_int
## Input: pointer to 0-terminated string in RSI
## output: integer in EDX
## clobbers: RAX, RCX (base), RSI (points to terminator on return)
parse_cxx14_int:
xor %eax,%eax # initialize high bits of digit reader
cdq # also initialize result accumulator edx to 0
lea 10(%rax), %ecx # base 10 default
lodsb # fetch first character
cmp $'0', %al
jne .Lentry2
# leading zero. Legal 2nd characters are b/B (base 2), x/X (base 16)
# Or NUL terminator = 0 in base 10
# or any digit or ' separator (octal). These have ASCII codes below the alphabetic ranges
lodsb
mov $8, %cl # after '0' have either digit, apostrophe, or terminator,
cmp $'B', %al # or 'b'/'B' or 'x'/'X' (set a new base)
jb .Lentry2 # enter the parse loop with base=8 and an already-loaded character
# else hex or binary. The bit patterns for those letters are very convenient
and $0b0010010, %al # b/B -> 2, x/X -> 16
xchg %eax, %ecx
jmp .Lentry
.Lprocessdigit:
sub $'0' & (~32), %al
jb .Lentry # chars below '0' are treated as a separator, including '
cmp $10, %al
jb .Lnum
add $('0'&~32) - 'A' + 10, %al # digit value = c-'A' + 10. we have al = c - '0'&~32.
# c = al + '0'&~32. val = m+'0'&~32 - 'A' + 10
.Lnum:
imul %ecx, %edx
add %eax, %edx # accum = accum * base + newdigit
.Lentry:
lodsb # fetch next character
.Lentry2:
and $~32, %al # uppercase letters (and as side effect,
# digits are translated to N+16)
jnz .Lprocessdigit # space also counts as a terminator
.Lend:
ret
変更されたブロックとダニエルのバージョンは、（ほとんど）他の命令よりもインデントが少なくなっています。また、メインループの下部には条件分岐があります。どちらのパスもそのトップに落ちないため、これはニュートラルな変更であることdec ecx / loop .Lentryが判明し、ループに入るためのアイデアは、8進数を異なる方法で処理した後は勝てないことが判明しました。しかし、ループ内のイディオム形式のループdo {} while構造を使用すると、ループ内の命令が少なくなるため、そのままにしました。
ダニエルのC ++テストハーネスは、32ビットの回答と同じ呼び出し規約を使用するこのコードを使用して、64ビットモードで変更せずに動作します。
g++ -Og parse-cxx14.cpp parse-cxx14.s &&
./a.out < tests | diff -u -w - tests.good
実際の答えであるマシンコードバイトを含む逆アセンブリ
0000000000000000 <parse_cxx14_int>:
0: 31 c0 xor %eax,%eax
2: 99 cltd
3: 8d 48 0a lea 0xa(%rax),%ecx
6: ac lods %ds:(%rsi),%al
7: 3c 30 cmp $0x30,%al
9: 75 1c jne 27 <parse_cxx14_int+0x27>
b: ac lods %ds:(%rsi),%al
c: b1 08 mov $0x8,%cl
e: 3c 42 cmp $0x42,%al
10: 72 15 jb 27 <parse_cxx14_int+0x27>
12: 24 12 and $0x12,%al
14: 91 xchg %eax,%ecx
15: eb 0f jmp 26 <parse_cxx14_int+0x26>
17: 2c 10 sub $0x10,%al
19: 72 0b jb 26 <parse_cxx14_int+0x26>
1b: 3c 0a cmp $0xa,%al
1d: 72 02 jb 21 <parse_cxx14_int+0x21>
1f: 04 d9 add $0xd9,%al
21: 0f af d1 imul %ecx,%edx
24: 01 c2 add %eax,%edx
26: ac lods %ds:(%rsi),%al
27: 24 df and $0xdf,%al
29: 75 ec jne 17 <parse_cxx14_int+0x17>
2b: c3 retq
ダニエルのバージョンからのその他の変更には、区切り文字の検出の一部としての代わりにsub $16, %almoreを使用することによる数字ループ内からの保存、および数字とアルファベット文字が含まれます。subtest
ダニエルのすべての文字とは異なり、以下のすべての文字'0'は、単なる区切り記号ではなく区切り記号として扱われ'\''ます。（例外' '：：両方のループでand $~32, %al/ jnzはスペースをターミネータとして扱います。これは、行の先頭で整数を使用してテストする場合に便利です。）
%alループ内で変更するすべての操作には、結果によって設定されるフラグを消費するブランチがあり、各ブランチは異なる場所に移動します（またはフォールスルーします）。
