チャレンジ

あなたのタスクは、入力なしで以下を出力するプログラムまたは関数を作成することです。

a
bb
ccc
dddd
eeeee
ffffff
ggggggg
hhhhhhhh
iiiiiiiii
jjjjjjjjjj
kkkkkkkkkkk
llllllllllll
mmmmmmmmmmmmm
nnnnnnnnnnnnnn
ooooooooooooooo
pppppppppppppppp
qqqqqqqqqqqqqqqqq
rrrrrrrrrrrrrrrrrr
sssssssssssssssssss
tttttttttttttttttttt
uuuuuuuuuuuuuuuuuuuuu
vvvvvvvvvvvvvvvvvvvvvv
wwwwwwwwwwwwwwwwwwwwwww
xxxxxxxxxxxxxxxxxxxxxxxx
yyyyyyyyyyyyyyyyyyyyyyyyy
zzzzzzzzzzzzzzzzzzzzzzzzzz

得点

これはcode-golfであるため、各言語で最も短い回答が優先されます。

05AB1E、2バイト

Aƶ

オンラインでお試しください！

OPが明示的に許可しているため、これは行のリストとして出力することに注意してください。リンクでは、プリティプリント（改行で結合）されたバージョンが使用されます。

使い方

• A 小文字のアルファベットを生成します。
• ƶ アルファベットを持ち上げます（各要素にインデックスを乗算します）。
• » 改行で結合します。

Python 2、36バイト

i=1
exec'print chr(i+96)*i;i+=1;'*26

オンラインでお試しください！

APL（Dyalog）、12 8 5バイト^SBCS

@ngnのおかげで3バイト節約

@Adámのおかげで4バイト節約

⍴⍨⌸⎕A

OPで明確にされた大文字は有効であり、文字列の配列として出力されます。

オンラインでお試しください！

どうやって？

⌸⎕Aインデックスを含むlphabet 内のすべての文字を提供⍴⍨し、文字を左引数として、インデックスesを右引数として関数に渡します。

⍴⍨reshaは、右引数を左引数で指定された長さに変換します。⍨左右を切り替えます（したがって、この説明を読んでいる人の顔のように見えるそのシンボル）。

Haskell、27バイト

[c<$['a'..c]|c<-['a'..'z']]

オンラインでお試しください！行のリストを返します。（これが現在許可されていることを指摘してくれた@totallyhumanに感謝します）

説明：

             c<-['a'..'z']  -- for each character c from 'a' to 'z'
[           |c<-['a'..'z']] -- build the list of
[   ['a'..c]|c<-['a'..'z']] -- the lists from 'a' to c, e.g. "abcd" for c='d'
[c<$['a'..c]|c<-['a'..'z']] -- with each element replaced by c itself, e.g. "dddd"

brainfuck、74バイト

++++++++[>+>+++>++++++++++++<<<-]>++>++>+>+<<[->>[->+<<.>]>[-<+>]<+<+<<.>]

オンラインでお試しください！

説明

++++++++[>+>+++>++++++++++++<<<-]>++>++>+>+
TAPE:
  000
  010   C_NEWLINE
  026   V_ITERCOUNT
  097   V_ALPHA
 >001<  V_PRINTCOUNT
  000   T_PRINTCOUNT

V_ITERCOUNT TIMES:      <<[-   

  V_PRINTCOUNT TIMES:     >>[-
    INC T_PRINTCOUNT        >+
    OUTPUT V_ALPHA          <<.
                          >]

  RESTORE V_PRINTCOUNT    >[-<+>]
  INC V_PRINTCOUNT        <+
  INC V_ALPHA             <+
  OUTPUT C_NEWLINE        <<.
                        >]

オンラインでお試しください！

Befunge-98（FBBI）、27バイト

1+:0\::'`j'@+\k:$$>:#,_$a,

where は置換文字（ASCII 26）です

オンラインでお試しください！

大文字を使用し、末尾に改行があります。

説明

コードは、カウンター（最初は0）を格納することで、すべてのループで機能します。

• 1+ -1ずつ増加
• :0\:: -スタックが次のようになるようにプッシュします： bottom [N, 0, N, N, N] top
• '`j'@ -カウンターが26より大きいかどうかを確認します
  • j'@-もしそうなら、ジャンプして'終了して@
  • j'@ -そうでない場合は、実行します '、ASCII値を@スタックにプッシュします

スタックは次のようになります。 bottom [N, 0, N, N, 64] top

• +\-追加してからトップ2に切り替えます：bottom [N, 0, (N+64), N] top 初回通過時、これはASCII 65、またはA
• k:-上から2番目を複製します(N+1)- スタック上に(N+2)値が(N+64)あります（プラスNと0以前から）
• $$ -上位2つの値を捨てます-現在は N値ます(N+64)
• >:#,_-各上位の値をaに達するまで出力します0-これは、N(N+64)印刷します、getのコピーが印刷されるます
• $ -捨てる 0 -スタックはちょうどN
• a, -エンターを印刷します

そして繰り返す

@プログラムの終了とカウンターへの追加の両方を使用した方法が気に入っています。

ルビー、32 30バイト

@EricDuminilのおかげで-2バイト。

27.times{|n|puts (n+96).chr*n}

オンラインでお試しください！

JavaScript（ES6）、54バイト

f=(n=9)=>++n<36?n.toString(36).repeat(n-9)+`
`+f(n):''

O.innerText = f()

<pre id=O></pre>

Excel VBA、38バイト

イミディエイトウィンドウを使用します。:)

[A1:A26]="=REPT(CHAR(96+ROW()),ROW())"

BASH、59 54 40バイト

for l in {a..z};{
a+=a
echo ${a//a/$l}
}

オンラインでお試しください！

THX。@Justin Marinerへの5バイト

ルビー、38バイト

文字列の配列を返します

->{(a=*?a..?z).map{|x|x*-~a.index(x)}}

完全に人間のおかげで-5バイト

*ジョーダンによる素晴らしいゴルフのおかげで、-11バイト。

V、9バイト

¬az\ÓÎÛäl

オンラインでお試しください！

Hexdump：

00000000: ac61 7a5c d3ce dbe4 6c                   .az\....l

MATL、9バイト

2Y2"@X@Y"

オンラインでお試しください！

説明

2Y2     % Push string 'abc...z'
"       % For char in that string each
  @     %   Push current char
  X@    %   Push iteration index (1-based)
  Y"    %   Run-length decoding: repeat char that many times
        % Implicit end. Implicit display

Python 3、37バイト

for k in range(27):print(chr(k+96)*k)

先頭の改行を印刷します（許可されています）。

オンラインでお試しください！

ゼリー、 5  4 バイト

^{卑劣なPython実装の悪用}

Adámのおかげで-1バイト（行のリストの出力が許可されました。現在、プログラムではなく関数を記述しています）

Øa×J

文字列、行のリストを返すニラディックリンク
（改行で完全なプログラムとして印刷するには、単に追加Yしてください）。

オンラインでお試しください！（フッターはリンクをnilad（¢）として呼び出し、結果のPython表現（）を取得しŒṘて、デフォルトのフルプログラム動作が結果を一緒に破壊するので、明確にしますabbccc...）

どうやって？

Øa×J - main link: no arguments
Øa   - yield the alphabet = ['a','b','c',...,'z']
   J - range of length    = [1,2,3,...,26]
  ×  - multiplication     = ["a","bb","ccc",...,"zzzzzzzzzzzzzzzzzzzzzzzzzz"]
     - (Python multiplication lengthens chars to strings - not usually a Jelly thing)

MATL、11バイト

2Y2t!g*!YRc

オンラインでお試しください！

ブロードキャスト乗算に1を使用して、目的の文字の大きな正方形26x26マトリックスを取得します。次に、下の三角形の部分が取得され、暗黙的に印刷されます。

また11バイト：

2Y2!t~!+YRc  % Using broadcast addition with zeroes
2Y2!l26X"YR  % Using 'repmat'

Javascript、87バイト、72バイト（@steenberghに感謝）

私の最初の答えも：

for(i=1,j=97;j<123;){console.log(String.fromCharCode(j++).repeat(i++))};

ジャプト、9 7バイト

行の配列を出力します

;C¬Ëp°E

それを試してみてください

説明

¬小文字のアルファベット（;C）を文字の配列に分割（）し、配列（Ë）にマッピングしp、現在の要素を現在のインデックスE（°）回インクリメント（）回繰り返します（）。

ピップ、9バイト

FczPcX++i

オンラインでお試しください！

擬似コードでは、これは

For-each c in z
    Print (c string-multiply ++i)

どこz小文字のアルファベットに事前設定されており、i0に設定されています。

マップベースのソリューションは-n、複数行に表示するフラグが必要なため、1バイト余分に必要です。

{aX++i}Mz
B X_+1MEz

Acc !! 、66バイト

Count i while 26-i {
Count j while i+1-j {
Write 97+i
}
Write 10
}

オンラインでお試しください！

コメント付き

# Loop i from 0 to 25
Count i while 26-i {
    # Loop j from 0 to i (inclusive)
    Count j while i+1-j {
        # Print a letter
        Write 97+i
    }
    # Print a newline
    Write 10
}

Haskell、31バイト

nimiのおかげで-12バイト。

zipWith replicate[1..26]['a'..]

オンラインでお試しください！

これはスニペットではなく、このメタコンセンサスのために許可される行のリストを出力するヌル関数（引数をとらない関数）です。

R、38バイト

比較的面白くない答え。i1から26まで反復しi、アルファベットi時間の文字を印刷します（暗黙的な改行付き）。

for(i in 1:26)print(rep(letters[i],i))

オンラインでお試しください！

より興味深いアプローチは、次のようなものを使用することです。

cat(letters[(1:351*2)^.5+.5])

これにより、適切な量のすべての文字が得られますが、改行はありません。おそらく私よりも賢い人なら、それを使ってゴルファーの答えを出す方法を見つけられるでしょう。

Perl 5、19バイト

say$_ x++$"for a..z

オンラインでお試しください！

さび、82バイト

||for i in 1..27u8{println!("{}",((i+96) as char).to_string().repeat(i as usize))}

私はそれがもっと短くなることを望んでいましたが、型の間で明示的に変換/キャストするには多くのバイトがかかります:(

オンラインでお試しください！

PHP、47 46バイト

for($c=a;$i<26;)echo"
",str_pad($c,++$i,$c++);

または

for($c=a;$i<26;)echo str_pad("
",++$i+1,$c++);

で実行する-nrか、オンラインで試してください。

J、18 17バイト

a.{~(#"0+&96)i.27

説明：

              i.27      - list of integers 0 - 26
     (   +&96)          - adds 96 to the above list (starting offset of 'a')
      #"0               - copies the right argument left argument times  
  {~                    - select items from a list (arguments reversed)
a.                      - the whole alphabet


#"0 +&96 is a hook, which means that at first +96 is applied to the list i.27,
resulting in a list 96, 97, 98... 122, then #"0 is applied to this result. 
So it is evaluated as ((i.27)#"0(96+i.27)){a:

オンラインでお試しください！

Perl 6の、 24の  23バイト

.say for 'a'..'z'Zx 1..*

それを試してみてください

.say for 'a'..*Zx 1..26

それを試してみてください

オクターブ、25 24バイト

['',tril((x=65:90)'+~x)]

オンラインでお試しください！

OPが大文字を許可することを通知してくれたGiuseppeに感謝します。

説明：

x大文字のアルファベットのASCII値でベクトルを作成し、転置します。x（のASCII値）でグリッドを作成するために、否定（行ベクトルで26個のゼロ）を追加します。

AAAA
BBBB
CCCC

下三角行列を取得し、空の文字列と連結して文字に変換します。

C（gcc）、48バイト 50バイト

以下のコメントのcleblancおよびSteadyboxによると、再実行可能なバージョン。

s[9];main(i){for(;i<27;)puts(memset(s,i+95,i++));}

オンラインでお試しください！

ジャプト、17 16 11バイト

_{Oliverのおかげで-5バイト}

ISO-8859-1で

;26ÆCgX pXÄ

最高のスコアではありませんが、私はまだ初心者です。どんな提案も大歓迎です。

OPが許可するように、行のリストを出力します。リンクには、改行用にさらに3バイトが含まれます。

オンラインでお試しください！

;                      - Use string variables
 26                    - Literal 26
   Æ                   - For range 0..26
    C                  - Alphabet
     gX                -         . character at index X
        pXÄ            - Duplicate X+1 times
                       - End function (implicit)